[gentoo-commits] gentoo-x86 commit in kde-base/gwenview: gwenview-4.14.3.ebuild ChangeLog

["Alexey Shvetsov (alexxy)" <alexxy@gentoo.org>]

alexxy      14/11/16 12:21:31

  Modified:             ChangeLog
  Added:                gwenview-4.14.3.ebuild
  Log:
  [kde-base] Add KDE SC 4.14.3
  
  (Portage version: 2.2.14/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key F82F92E6)

Revision  Changes    Path
1.247                kde-base/gwenview/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/ChangeLog?rev=1.247&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/ChangeLog?rev=1.247&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/ChangeLog?r1=1.246&r2=1.247

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/gwenview/ChangeLog,v
retrieving revision 1.246
retrieving revision 1.247
diff -u -r1.246 -r1.247
--- ChangeLog	14 Nov 2014 19:33:02 -0000	1.246
+++ ChangeLog	16 Nov 2014 12:21:31 -0000	1.247
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/gwenview
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/gwenview/ChangeLog,v 1.246 2014/11/14 19:33:02 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/gwenview/ChangeLog,v 1.247 2014/11/16 12:21:31 alexxy Exp $
+
+*gwenview-4.14.3 (16 Nov 2014)
+
+  16 Nov 2014; Alexey Shvetsov <alexxy@gentoo.org> +gwenview-4.14.3.ebuild:
+  Version bump KDE SC 4.14.3
 
   14 Nov 2014; Manuel Rüger <mrueg@gentoo.org> -gwenview-4.13.3.ebuild,
   -gwenview-4.14.1.ebuild:



1.1                  kde-base/gwenview/gwenview-4.14.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/gwenview-4.14.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/gwenview-4.14.3.ebuild?rev=1.1&content-type=text/plain

Index: gwenview-4.14.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/gwenview/gwenview-4.14.3.ebuild,v 1.1 2014/11/16 12:21:31 alexxy Exp $

EAPI=5

KDE_HANDBOOK="optional"
OPENGL_REQUIRED="always"
inherit kde4-base

DESCRIPTION="KDE image viewer"
HOMEPAGE="
	http://www.kde.org/applications/graphics/gwenview/
	http://gwenview.sourceforge.net/
"
KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug kipi semantic-desktop"

# tests fail, last checked 4.11.0
RESTRICT="test"

DEPEND="
	$(add_kdebase_dep libkdcraw)
	$(add_kdebase_dep libkonq)
	$(add_kdebase_dep kactivities '' 4.13)
	media-gfx/exiv2:=
	media-libs/lcms:2
	media-libs/libpng:0=
	virtual/jpeg:0
	x11-libs/libX11
	kipi? ( $(add_kdebase_dep libkipi) )
	semantic-desktop? ( $(add_kdebase_dep baloo) )
"
RDEPEND="${DEPEND}"

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_with kipi)
	)
	# Workaround for bug #479510
	if [[ -e ${EPREFIX}/usr/include/${CHOST}/jconfig.h ]]; then
		mycmakeargs+=( -DJCONFIG_H="${EPREFIX}/usr/include/${CHOST}/jconfig.h" )
	fi

	if use semantic-desktop; then
		mycmakeargs+=(-DGWENVIEW_SEMANTICINFO_BACKEND=Baloo)
	else
		mycmakeargs+=(-DGWENVIEW_SEMANTICINFO_BACKEND=None)
	fi

	kde4-base_src_configure
}

pkg_postinst() {
	kde4-base_pkg_postinst

	if ! has_version kde-base/svgpart:${SLOT} ; then
		elog "For SVG support, install kde-base/svgpart:${SLOT}"
	fi

	if use kipi && ! has_version media-plugins/kipi-plugins ; then
		elog "The plugins for the KIPI inteface can be found in media-plugins/kipi-plugins"
	fi
}