[gentoo-commits] gentoo-x86 commit in kde-base/kmail: kmail-4.14.3.ebuild ChangeLog

["Alexey Shvetsov (alexxy)" <alexxy@gentoo.org>]

alexxy      14/11/16 12:21:27

  Modified:             ChangeLog
  Added:                kmail-4.14.3.ebuild
  Log:
  [kde-base] Add KDE SC 4.14.3
  
  (Portage version: 2.2.14/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key F82F92E6)

Revision  Changes    Path
1.429                kde-base/kmail/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kmail/ChangeLog?rev=1.429&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kmail/ChangeLog?rev=1.429&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kmail/ChangeLog?r1=1.428&r2=1.429

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kmail/ChangeLog,v
retrieving revision 1.428
retrieving revision 1.429
diff -u -r1.428 -r1.429
--- ChangeLog	14 Nov 2014 19:33:08 -0000	1.428
+++ ChangeLog	16 Nov 2014 12:21:27 -0000	1.429
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kmail
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kmail/ChangeLog,v 1.428 2014/11/14 19:33:08 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kmail/ChangeLog,v 1.429 2014/11/16 12:21:27 alexxy Exp $
+
+*kmail-4.14.3 (16 Nov 2014)
+
+  16 Nov 2014; Alexey Shvetsov <alexxy@gentoo.org> +kmail-4.14.3.ebuild:
+  Version bump KDE SC 4.14.3
 
   14 Nov 2014; Manuel Rüger <mrueg@gentoo.org> -kmail-4.13.3.ebuild,
   -kmail-4.14.1.ebuild:



1.1                  kde-base/kmail/kmail-4.14.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kmail/kmail-4.14.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kmail/kmail-4.14.3.ebuild?rev=1.1&content-type=text/plain

Index: kmail-4.14.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kmail/kmail-4.14.3.ebuild,v 1.1 2014/11/16 12:21:27 alexxy Exp $

EAPI=5

KDE_HANDBOOK="optional"
KMNAME="kdepim"
VIRTUALX_REQUIRED=test
inherit flag-o-matic kde4-meta

DESCRIPTION="KMail is the email component of Kontact, the integrated personal information manager of KDE"
HOMEPAGE="http://www.kde.org/applications/internet/kmail/"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug"

DEPEND="
	$(add_kdebase_dep kdepimlibs)
	$(add_kdebase_dep korganizer)
	$(add_kdebase_dep kdepim-common-libs "" 4.12.1-r2)
"
RDEPEND="
	${DEPEND}
	!=kde-base/kdepim-common-libs-4.12.1-r1
"

RESTRICT="test"
# bug 393147

KMEXTRACTONLY="
	agents/folderarchiveagent.desktop
	agents/sendlateragent/
	akonadi_next/
	calendarsupport/
	calendarviews/
	grantleeeditor/grantleethemeeditor/
	korganizer/
	kresources/
	libkleo/
	libkpgp/
	libkdepimdbusinterfaces/
	kdgantt2/
"
KMCOMPILEONLY="
	grantleetheme/
	kaddressbookgrantlee/
	messagecomposer/
	messagecore/
	messagelist/
	messageviewer/
	pimcommon/
	templateparser/
	incidenceeditor-ng/
	calendarsupport/
	noteshared/
"
KMEXTRA="
	agents/archivemailagent/
	agents/followupreminderagent/
	agents/mailfilteragent/
	grantleeeditor/headerthemeeditor/
	kmailcvt/
	ksendemail/
	importwizard/
	libksieve/
	mailcommon/
	mailimporter/
	mboximporter/
	pimsettingexporter/
	plugins/messageviewer/
"

KMLOADLIBS="kdepim-common-libs"

src_configure() {
	# Bug 308903
	use ppc64 && append-flags -mminimal-toc

	kde4-meta_src_configure
}

src_compile() {
	kde4-meta_src_compile kmail_xml
	kde4-meta_src_compile
}

pkg_postinst() {
	kde4-meta_pkg_postinst

	if ! has_version kde-base/kdepim-kresources:${SLOT}; then
		echo
		elog "For groupware functionality, please install kde-base/kdepim-kresources:${SLOT}"
		echo
	fi
	if ! has_version kde-base/kleopatra:${SLOT}; then
		echo
		elog "For certificate management and the gnupg log viewer, please install kde-base/kleopatra:${SLOT}"
		echo
	fi

	if has_version "app-office/akonadi-server[sqlite]"; then
		ewarn
		ewarn "We strongly recommend you set your Akonadi database backend to QMYSQL in your"
		ewarn "user configuration. This is the backend recommended by KDE upstream."
		ewarn "Reports indicate that kde-base/kmail-4.10 does not work properly with the sqlite"
		ewarn "backend anymore."
		if has_version "app-office/akonadi-server[-mysql]"; then
			ewarn "FOR THAT, YOU WILL HAVE TO RE-BUILD app-office/akonadi-server WITH mysql USEFLAG ENABLED."
		fi
		ewarn "You can select the backend in your ~/.config/akonadi/akonadiserverrc."
		ewarn
	fi
}