[gentoo-commits] gentoo-x86 commit in media-sound/kid3: kid3-3.1.2.ebuild ChangeLog

["Manuel Rueger (mrueg)" <mrueg@gentoo.org>]

mrueg       14/11/14 18:16:18

  Modified:             ChangeLog
  Added:                kid3-3.1.2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key )

Revision  Changes    Path
1.86                 media-sound/kid3/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/kid3/ChangeLog?rev=1.86&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/kid3/ChangeLog?rev=1.86&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/kid3/ChangeLog?r1=1.85&r2=1.86

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/kid3/ChangeLog,v
retrieving revision 1.85
retrieving revision 1.86
diff -u -r1.85 -r1.86
--- ChangeLog	13 Aug 2014 14:30:29 -0000	1.85
+++ ChangeLog	14 Nov 2014 18:16:18 -0000	1.86
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/kid3
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/kid3/ChangeLog,v 1.85 2014/08/13 14:30:29 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/kid3/ChangeLog,v 1.86 2014/11/14 18:16:18 mrueg Exp $
+
+*kid3-3.1.2 (14 Nov 2014)
+
+  14 Nov 2014; Manuel Rüger <mrueg@gentoo.org> +kid3-3.1.2.ebuild:
+  Version bump.
 
   13 Aug 2014; Johannes Huber <johu@gentoo.org> kid3-3.1.ebuild:
   Pin dev-qt/qtphonon to SLOT 4.



1.1                  media-sound/kid3/kid3-3.1.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/kid3/kid3-3.1.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/kid3/kid3-3.1.2.ebuild?rev=1.1&content-type=text/plain

Index: kid3-3.1.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/kid3/kid3-3.1.2.ebuild,v 1.1 2014/11/14 18:16:18 mrueg Exp $

EAPI=5

KDE_LINGUAS="cs de es et fi fr it nl pl ru sr sr@ijekavian sr@ijekavianlatin
sr@Latn tr zh_CN zh_TW"
KDE_REQUIRED="optional"
KDE_HANDBOOK="optional"
inherit kde4-base

DESCRIPTION="A simple tag editor for KDE"
HOMEPAGE="http://kid3.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2+"
SLOT="4"
KEYWORDS="~amd64 ~x86"
IUSE="acoustid flac kde mp3 mp4 +phonon +taglib vorbis"

REQUIRED_USE="flac? ( vorbis )"

RDEPEND="
	dev-qt/qtcore:4
	dev-qt/qtdbus:4
	dev-qt/qtgui:4
	sys-libs/readline:0
	acoustid? (
		media-libs/chromaprint
		virtual/ffmpeg
	)
	flac? (
		media-libs/flac[cxx]
		media-libs/libvorbis
	)
	mp3? ( media-libs/id3lib )
	mp4? ( media-libs/libmp4v2:0 )
	phonon? ( || (
		media-libs/phonon
		dev-qt/qtphonon:4
	) )
	taglib? ( media-libs/taglib )
	vorbis? (
		media-libs/libogg
		media-libs/libvorbis
	)
"
DEPEND="${RDEPEND}"

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_with acoustid CHROMAPRINT)
		$(cmake-utils_use_with flac)
		$(cmake-utils_use_with mp3 ID3LIB)
		$(cmake-utils_use_with mp4 MP4V2)
		$(cmake-utils_use_with phonon)
		$(cmake-utils_use_with taglib)
		$(cmake-utils_use_with vorbis)
		"-DWITH_QT5=OFF"
	)

	if use kde; then
		mycmakeargs+=("-DWITH_APPS=KDE;CLI")
	else
		mycmakeargs+=("-DWITH_APPS=Qt;CLI")
	fi

	kde4-base_src_configure
}