[gentoo-commits] gentoo-x86 commit in dev-libs/hidapi: hidapi-0.8.0_rc1_p20140201.ebuild ChangeLog

["Diego Petteno (flameeyes)" <flameeyes@gentoo.org>]

flameeyes    14/11/12 21:49:26

  Modified:             ChangeLog
  Added:                hidapi-0.8.0_rc1_p20140201.ebuild
  Log:
  Bump using the Debian snapshot/packaging, and add support for multilib. Migrated to use virtual/libudev which was the correct dependency.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 1CD13C8AD4301342)

Revision  Changes    Path
1.9                  dev-libs/hidapi/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/hidapi/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/hidapi/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/hidapi/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/hidapi/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	25 Oct 2014 11:36:57 -0000	1.8
+++ ChangeLog	12 Nov 2014 21:49:26 -0000	1.9
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/hidapi
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/hidapi/ChangeLog,v 1.8 2014/10/25 11:36:57 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/hidapi/ChangeLog,v 1.9 2014/11/12 21:49:26 flameeyes Exp $
+
+*hidapi-0.8.0_rc1_p20140201 (12 Nov 2014)
+
+  12 Nov 2014; Diego E. Pettenò <flameeyes@gentoo.org>
+  +hidapi-0.8.0_rc1_p20140201.ebuild:
+  Bump using the Debian snapshot/packaging, and add support for multilib.
+  Migrated to use virtual/libudev which was the correct dependency.
 
   25 Oct 2014; Diego E. Pettenò <flameeyes@gentoo.org>
   hidapi-0.8.0_pre20130121-r1.ebuild:



1.1                  dev-libs/hidapi/hidapi-0.8.0_rc1_p20140201.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/hidapi/hidapi-0.8.0_rc1_p20140201.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/hidapi/hidapi-0.8.0_rc1_p20140201.ebuild?rev=1.1&content-type=text/plain

Index: hidapi-0.8.0_rc1_p20140201.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/hidapi/hidapi-0.8.0_rc1_p20140201.ebuild,v 1.1 2014/11/12 21:49:26 flameeyes Exp $

EAPI=5

AUTOTOOLS_AUTORECONF=yes

inherit eutils versionator autotools-multilib #git-2

# If github is desired, the following may be used.
#EGIT_REPO_URI="git://github.com/signal11/hidapi.git"
#EGIT_BRANCH="master"
#EGIT_COMMIT="119135b8ce0e8db668ec171723d6e56d4394166a"

BASE_PV=$(get_version_component_range 1-3)
RC_PV=$(get_version_component_range 4)
GIT_PV=$(get_version_component_range 5)
GIT_PV=${GIT_PV/p/git}.3a66d4e

DEBIAN_PV=${BASE_PV}~${RC_PV}+${GIT_PV}+dfsg

# S is only needed for the debian_package
S=${WORKDIR}/${PN}-${DEBIAN_PV}

DESCRIPTION="A multi-platform library for USB and Bluetooth HID-Class devices"
HOMEPAGE="http://www.signal11.us/oss/hidapi/"
SRC_URI="mirror://debian/pool/main/h/${PN}/${PN}_${DEBIAN_PV}.orig.tar.bz2"
# When 0.8.0 is officially available the following link should be used.
#SRC_URI="mirror://github/signal11/${PN}/${P}.zip"

LICENSE="|| ( BSD GPL-3 HIDAPI )"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
IUSE="doc static-libs X"

RDEPEND="virtual/libusb:1[${MULTILIB_USEDEP}]
	virtual/libudev:0[${MULTILIB_USEDEP}]"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )
	virtual/pkgconfig
	X? ( x11-libs/fox )"

src_prepare() {
	if use X && has_version x11-libs/fox:1.7 ; then
		sed -i -e 's:PKG_CHECK_MODULES(\[fox\], \[fox\]):PKG_CHECK_MODULES(\[fox\], \[fox17\]):' \
			configure.ac || die
	fi

	# Fix bashisms in the configure.ac file.
	sed -i -e 's:\([A-Z_]\+\)+="\(.*\)":\1="${\1}\2":g' \
		-e 's:\([A-Z_]\+\)+=`\(.*\)`:\1="${\1}\2":g' configure.ac || die

	autotools-multilib_src_prepare
}

src_configure() {
	local myeconfargs=(
		$(use_enable X testgui)
	)

	autotools-multilib_src_configure
}

src_compile() {
	autotools-multilib_src_compile

	if use doc; then
		doxygen doxygen/Doxyfile || die
	fi
}

src_install() {
	autotools-multilib_src_install

	if use doc; then
		dohtml -r html/*
	fi
}