[gentoo-commits] gentoo-x86 commit in net-misc/owncloud-client: metadata.xml ChangeLog owncloud-client-1.7.0.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/owncloud-client: metadata.xml ChangeLog owncloud-client-1.7.0.ebuild

[Bernard Cafarelli (voyageur)]

voyageur    14/11/12 13:58:39

  Modified:             metadata.xml ChangeLog
  Added:                owncloud-client-1.7.0.ebuild
  Log:
  Version bump, with nautilus integration
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key C74525F2)

Revision  Changes    Path
1.3                  net-misc/owncloud-client/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/owncloud-client/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	24 Feb 2014 15:43:10 -0000	1.2
+++ metadata.xml	12 Nov 2014 13:58:39 -0000	1.3
@@ -6,6 +6,7 @@
 		<name>Bernard Cafarelli</name>
 	</maintainer>
 	<use>
+		<flag name="nautilus">Install the <pkg>gnome-base/nautilus</pkg> extension</flag>
 		<flag name="sftp">Enable sftp transfer support via <pkg>net-libs/libssh</pkg></flag>
 	</use>
 </pkgmetadata>



1.19                 net-misc/owncloud-client/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/owncloud-client/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	27 Oct 2014 09:07:41 -0000	1.18
+++ ChangeLog	12 Nov 2014 13:58:39 -0000	1.19
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/owncloud-client
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/owncloud-client/ChangeLog,v 1.18 2014/10/27 09:07:41 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/owncloud-client/ChangeLog,v 1.19 2014/11/12 13:58:39 voyageur Exp $
+
+*owncloud-client-1.7.0 (12 Nov 2014)
+
+  12 Nov 2014; Bernard Cafarelli <voyageur@gentoo.org>
+  +owncloud-client-1.7.0.ebuild, metadata.xml:
+  Version bump, with nautilus integration
 
 *owncloud-client-1.6.4 (27 Oct 2014)
 



1.1                  net-misc/owncloud-client/owncloud-client-1.7.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/owncloud-client-1.7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/owncloud-client-1.7.0.ebuild?rev=1.1&content-type=text/plain

Index: owncloud-client-1.7.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/owncloud-client/owncloud-client-1.7.0.ebuild,v 1.1 2014/11/12 13:58:39 voyageur Exp $

EAPI=5

inherit cmake-utils

MY_P="mirall-${PV/_/}"

DESCRIPTION="Synchronize files from ownCloud Server with your computer"
HOMEPAGE="http://owncloud.org/"
SRC_URI="http://download.owncloud.com/desktop/stable/${MY_P}.tar.bz2"

LICENSE="CC-BY-3.0 GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc nautilus samba +sftp test +qt4 qt5"

REQUIRED_USE="^^ ( qt4 qt5 )"

RDEPEND=">=dev-db/sqlite-3.4:3
	net-libs/neon[ssl]
	sys-fs/inotify-tools
	virtual/libiconv
	nautilus? ( dev-python/nautilus-python )
	qt4? (
		dev-libs/qtkeychain[qt4]
		dev-qt/qtcore:4
		dev-qt/qtdbus:4
		dev-qt/qtgui:4
		dev-qt/qtsql:4
		dev-qt/qttest:4
		dev-qt/qtwebkit:4
	)
	qt5? (
		dev-libs/qtkeychain[qt5]
		dev-qt/linguist-tools:5
		dev-qt/qtcore:5
		dev-qt/qtdbus:5
		dev-qt/qtgui:5
		dev-qt/qtsql:5
		dev-qt/qttest:5
		dev-qt/qtwebkit:5[printsupport]
	)
	samba? ( >=net-fs/samba-3.5 )
	sftp? ( >=net-libs/libssh-0.5 )
	!net-misc/ocsync"
DEPEND="${RDEPEND}
	doc? (
		dev-python/sphinx
		dev-texlive/texlive-latexextra
		virtual/latex-base
	)
	test? ( dev-util/cmocka )"

S=${WORKDIR}/${MY_P}

src_prepare() {
	# Keep tests in ${T}
	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.h || die "sed failed"

	use nautilus || sed -i -e "s/add_subdirectory(nautilus)//" \
		shell_integration/CMakeLists.txt || die "sed failed"
}

src_configure() {
	local mycmakeargs=(
		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
		-DWITH_ICONV=ON
		$(cmake-utils_use_with doc DOC)
		$(cmake-utils_use test UNIT_TESTING)
		$(cmake-utils_use_find_package samba Libsmbclient)
		$(cmake-utils_use_find_package sftp LibSSH)
		$(cmake-utils_use_build qt4 WITH_QT4)
	)

	cmake-utils_src_configure
}

src_test() {
	# 1 test needs an existing ${HOME}/.config directory
	mkdir "${T}"/.config
	export HOME="${T}"
	cmake-utils_src_test
}

pkg_postinst() {
	if ! use doc ; then
		elog "Documentation and man pages not installed"
		elog "Enable doc USE-flag to generate them"
	fi
	if use nautilus ; then
		elog "The XDG_RUNTIME_DIR environment variable must be set for the nautilus extension"
		elog "Check https://github.com/owncloud/mirall/issues/2477 for more information"
	fi
}