* [gentoo-commits] gentoo-x86 commit in net-analyzer/nmap: nmap-6.25-r1.ebuild nmap-6.47.ebuild ChangeLog
@ 2014-11-11 22:23 Mike Gilbert (floppym)
0 siblings, 0 replies; only message in thread
From: Mike Gilbert (floppym) @ 2014-11-11 22:23 UTC (permalink / raw
To: gentoo-commits
floppym 14/11/11 22:23:20
Modified: nmap-6.47.ebuild ChangeLog
Added: nmap-6.25-r1.ebuild
Log:
Call python_optimize in src_install, and backport python changes to nmap-6.25-r1. Bug 498726 by Nikoli.
(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)
Revision Changes Path
1.4 net-analyzer/nmap/nmap-6.47.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/nmap-6.47.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/nmap-6.47.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/nmap-6.47.ebuild?r1=1.3&r2=1.4
Index: nmap-6.47.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/nmap/nmap-6.47.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- nmap-6.47.ebuild 11 Nov 2014 21:58:32 -0000 1.3
+++ nmap-6.47.ebuild 11 Nov 2014 22:23:20 -0000 1.4
@@ -1,6 +1,6 @@
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nmap/nmap-6.47.ebuild,v 1.3 2014/11/11 21:58:32 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nmap/nmap-6.47.ebuild,v 1.4 2014/11/11 22:23:20 floppym Exp $
EAPI=5
@@ -27,7 +27,7 @@
REQUIRED_USE="
ndiff? ( ${PYTHON_REQUIRED_USE} )
- zenmap ( ${PYTHON_REQUIRED_USE} )
+ zenmap? ( ${PYTHON_REQUIRED_USE} )
"
RDEPEND="
@@ -147,5 +147,8 @@
dodoc CHANGELOG HACKING docs/README docs/*.txt
- use zenmap && doicon "${DISTDIR}/nmap-logo-64.png"
+ if use zenmap; then
+ doicon "${DISTDIR}/nmap-logo-64.png"
+ python_optimize
+ fi
}
1.313 net-analyzer/nmap/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/ChangeLog?rev=1.313&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/ChangeLog?rev=1.313&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/ChangeLog?r1=1.312&r2=1.313
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/nmap/ChangeLog,v
retrieving revision 1.312
retrieving revision 1.313
diff -u -r1.312 -r1.313
--- ChangeLog 11 Nov 2014 21:58:32 -0000 1.312
+++ ChangeLog 11 Nov 2014 22:23:20 -0000 1.313
@@ -1,6 +1,13 @@
# ChangeLog for net-analyzer/nmap
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nmap/ChangeLog,v 1.312 2014/11/11 21:58:32 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nmap/ChangeLog,v 1.313 2014/11/11 22:23:20 floppym Exp $
+
+*nmap-6.25-r1 (11 Nov 2014)
+
+ 11 Nov 2014; Mike Gilbert <floppym@gentoo.org> +nmap-6.25-r1.ebuild,
+ nmap-6.47.ebuild:
+ Call python_optimize in src_install, and backport python changes to
+ nmap-6.25-r1. Bug 498726 by Nikoli.
11 Nov 2014; Mike Gilbert <floppym@gentoo.org> nmap-6.47.ebuild:
Don't call python-single-r1_pkg_setup if python is not used.
1.1 net-analyzer/nmap/nmap-6.25-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/nmap-6.25-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/nmap/nmap-6.25-r1.ebuild?rev=1.1&content-type=text/plain
Index: nmap-6.25-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nmap/nmap-6.25-r1.ebuild,v 1.1 2014/11/11 22:23:20 floppym Exp $
EAPI="5"
PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="sqlite,xml"
inherit eutils flag-o-matic python-single-r1 toolchain-funcs
MY_P=${P/_beta/BETA}
DESCRIPTION="A utility for network exploration or security auditing"
HOMEPAGE="http://nmap.org/"
SRC_URI="
http://nmap.org/dist/${MY_P}.tar.bz2
http://dev.gentoo.org/~jer/nmap-logo-64.png
"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="gtk ipv6 +lua ncat ndiff nls nmap-update nping ssl"
NMAP_LINGUAS="de es fr hr hu id it ja pl pt_BR pt_PT ro ru sk zh"
for lingua in ${NMAP_LINGUAS}; do
IUSE+=" linguas_${lingua}"
done
REQUIRED_USE="
gtk? ( ${PYTHON_REQUIRED_USE} )
ndiff? ( ${PYTHON_REQUIRED_USE} )
"
RDEPEND="
dev-libs/apr
dev-libs/libpcre
net-libs/libpcap[ipv6?]
gtk? (
>=x11-libs/gtk+-2.6:2
>=dev-python/pygtk-2.6
${PYTHON_DEPS}
)
lua? ( >=dev-lang/lua-5.1.4-r1[deprecated] )
ndiff? ( ${PYTHON_DEPS} )
nls? ( virtual/libintl )
nmap-update? ( dev-libs/apr dev-vcs/subversion )
ssl? ( dev-libs/openssl )
"
DEPEND="
${RDEPEND}
nls? ( sys-devel/gettext )
"
S="${WORKDIR}/${MY_P}"
pkg_setup() {
if use gtk || use ndiff; then
python-single-r1_pkg_setup
fi
}
src_unpack() {
unpack ${MY_P}.tar.bz2
}
src_prepare() {
epatch \
"${FILESDIR}"/${PN}-4.75-nolua.patch \
"${FILESDIR}"/${PN}-5.10_beta1-string.patch \
"${FILESDIR}"/${PN}-5.21-python.patch \
"${FILESDIR}"/${PN}-6.01-make.patch \
"${FILESDIR}"/${PN}-6.25-lua.patch \
"${FILESDIR}"/${PN}-6.25-liblua-ar.patch
sed -i \
-e 's/-m 755 -s ncat/-m 755 ncat/' \
ncat/Makefile.in || die
mv docs/man-xlate/${PN}-j{p,a}.1 || die
if use nls; then
local lingua=''
for lingua in ${NMAP_LINGUAS}; do
if ! use linguas_${lingua}; then
rm -rf zenmap/share/zenmap/locale/${lingua}
rm -f zenmap/share/zenmap/locale/${lingua}.po
fi
done
else
# configure/make ignores --disable-nls
for lingua in ${NMAP_LINGUAS}; do
rm -rf zenmap/share/zenmap/locale/${lingua}
rm -f zenmap/share/zenmap/locale/${lingua}.po
done
fi
sed -i \
-e '/^ALL_LINGUAS =/{s|$| id|g;s|jp|ja|g}' \
Makefile.in || die
# Fix desktop files wrt bug #432714
sed -i \
-e '/^Encoding/d' \
-e 's|^Categories=.*|Categories=Network;System;Security;|g' \
zenmap/install_scripts/unix/zenmap-root.desktop \
zenmap/install_scripts/unix/zenmap.desktop || die
epatch_user
}
src_configure() {
# The bundled libdnet is incompatible with the version available in the
# tree, so we cannot use the system library here.
econf \
$(use_enable ipv6) \
$(use_enable nls) \
$(use_with gtk zenmap) \
$(use_with lua liblua) \
$(use_with ncat) \
$(use_with ndiff) \
$(use_with nmap-update) \
$(use_with nping) \
$(use_with ssl openssl) \
--with-libdnet=included
}
src_compile() {
emake \
AR=$(tc-getAR) \
RANLIB=$(tc-getRANLIB )
}
src_install() {
LC_ALL=C emake -j1 \
DESTDIR="${D}" \
STRIP=: \
nmapdatadir="${EPREFIX}"/usr/share/nmap \
install
if use nmap-update;then
LC_ALL=C emake -j1 \
-C nmap-update \
DESTDIR="${D}" \
STRIP=: \
nmapdatadir="${EPREFIX}"/usr/share/nmap \
install
fi
dodoc CHANGELOG HACKING docs/README docs/*.txt
if use gtk; then
doicon "${DISTDIR}/nmap-logo-64.png"
python_optimize
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-11-11 22:23 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-11-11 22:23 [gentoo-commits] gentoo-x86 commit in net-analyzer/nmap: nmap-6.25-r1.ebuild nmap-6.47.ebuild ChangeLog Mike Gilbert (floppym)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox