[gentoo-commits] gentoo-x86 commit in app-office/texstudio: ChangeLog texstudio-2.8.6.ebuild

["Justin Lecher (jlec)" <jlec@gentoo.org>]

jlec        14/11/03 10:43:24

  Modified:             ChangeLog
  Added:                texstudio-2.8.6.ebuild
  Log:
  app-office/texstudio: Version Bump, #528030
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.29                 app-office/texstudio/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texstudio/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texstudio/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texstudio/ChangeLog?r1=1.28&r2=1.29

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/texstudio/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog	16 Sep 2014 11:51:32 -0000	1.28
+++ ChangeLog	3 Nov 2014 10:43:24 -0000	1.29
@@ -1,6 +1,11 @@
 # ChangeLog for app-office/texstudio
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/texstudio/ChangeLog,v 1.28 2014/09/16 11:51:32 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/texstudio/ChangeLog,v 1.29 2014/11/03 10:43:24 jlec Exp $
+
+*texstudio-2.8.6 (03 Nov 2014)
+
+  03 Nov 2014; Justin Lecher <jlec@gentoo.org> +texstudio-2.8.6.ebuild:
+  Version Bump, #528030
 
 *texstudio-2.8.4 (16 Sep 2014)
 



1.1                  app-office/texstudio/texstudio-2.8.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texstudio/texstudio-2.8.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texstudio/texstudio-2.8.6.ebuild?rev=1.1&content-type=text/plain

Index: texstudio-2.8.6.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/texstudio/texstudio-2.8.6.ebuild,v 1.1 2014/11/03 10:43:24 jlec Exp $

EAPI=5

inherit base fdo-mime prefix qt4-r2

DESCRIPTION="Free cross-platform LaTeX editor (fork from texmakerX)"
HOMEPAGE="http://texstudio.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${PN}/TeXstudio%20${PV}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-fbsd"
IUSE="video"

COMMON_DEPEND="
	app-text/hunspell
	app-text/poppler:=[qt4]
	dev-libs/quazip
	x11-libs/libX11
	x11-libs/libXext
	dev-qt/designer:4
	>=dev-qt/qtgui-4.8.5:4
	>=dev-qt/qtcore-4.6.1:4
	>=dev-qt/qtscript-4.6.1:4
	dev-qt/qtsingleapplication
	>=dev-qt/qtsvg-4.6.1:4
	>=dev-qt/qttest-4.6.1:4
	video? ( media-libs/phonon )"
RDEPEND="${COMMON_DEPEND}
	virtual/latex-base
	app-text/psutils
	app-text/ghostscript-gpl
	media-libs/netpbm"
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig"

S="${WORKDIR}"/${P/-/}

PATCHES=(
	"${FILESDIR}"/${PN}-2.6.4-hunspell-quazip.patch
	"${FILESDIR}"/${PN}-2.8.2-desktop.patch
# Get it from fedora
	"${FILESDIR}"/${PN}-2.5-viewers-use-xdg-open.patch
	)

src_prepare() {
	find hunspell quazip utilities/poppler-data qtsingleapplication -delete || die

	if use video; then
		sed "/^PHONON/s:$:true:g" -i ${PN}.pro || die
	fi

	sed \
		-e '/hunspell.pri/d' \
		-e '/quazip.pri/d' \
		-e '/qtsingleapplication.pri/d' \
		-e '/QUAZIP_STATIC/d' \
		-i ${PN}.pro || die

#	cat >> ${PN}.pro <<- EOF
#	exists(texmakerx_my.pri):include(texmakerx_my.pri)
#	EOF

	cp "${FILESDIR}"/texmakerx_my.pri ${PN}.pri || die
	eprefixify ${PN}.pri

	qt4-r2_src_prepare
}

src_install() {
	local i
	for i in 16x16 22x22 32x32 48x48 64x64 128x128; do
		insinto /usr/share/icons/hicolor/${i}
		newins utilities/${PN}${i}.png ${PN}.png
	done
	qt4-r2_src_install
}

pkg_postinst() {
	fdo-mime_desktop_database_update
}