* [gentoo-commits] gentoo-x86 commit in mail-filter/opendkim: opendkim-2.9.2-r1.ebuild ChangeLog
@ 2014-05-02 10:46 Pacho Ramos (pacho)
0 siblings, 0 replies; 3+ messages in thread
From: Pacho Ramos (pacho) @ 2014-05-02 10:46 UTC (permalink / raw
To: gentoo-commits
pacho 14/05/02 10:46:14
Modified: ChangeLog
Added: opendkim-2.9.2-r1.ebuild
Log:
Add unit file (#502054 by Andrius Stikonas)
(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)
Revision Changes Path
1.78 mail-filter/opendkim/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/ChangeLog?rev=1.78&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/ChangeLog?rev=1.78&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/ChangeLog?r1=1.77&r2=1.78
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v
retrieving revision 1.77
retrieving revision 1.78
diff -u -r1.77 -r1.78
--- ChangeLog 15 Apr 2014 06:41:38 -0000 1.77
+++ ChangeLog 2 May 2014 10:46:14 -0000 1.78
@@ -1,6 +1,12 @@
# ChangeLog for mail-filter/opendkim
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v 1.77 2014/04/15 06:41:38 eras Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v 1.78 2014/05/02 10:46:14 pacho Exp $
+
+*opendkim-2.9.2-r1 (02 May 2014)
+
+ 02 May 2014; Pacho Ramos <pacho@gentoo.org> +files/opendkim.service,
+ +opendkim-2.9.2-r1.ebuild:
+ Add unit file (#502054 by Andrius Stikonas)
*opendkim-2.9.2 (15 Apr 2014)
1.1 mail-filter/opendkim/opendkim-2.9.2-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/opendkim-2.9.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/opendkim-2.9.2-r1.ebuild?rev=1.1&content-type=text/plain
Index: opendkim-2.9.2-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/opendkim-2.9.2-r1.ebuild,v 1.1 2014/05/02 10:46:14 pacho Exp $
EAPI=5
inherit autotools db-use eutils systemd user
# for betas
#MY_P=${P/_b/.B}
#S=${WORKDIR}/${PN}-2.8.0
#SRC_URI="mirror://sourceforge/opendkim/${MY_P}.tar.gz"
DESCRIPTION="A milter-based application to provide DKIM signing and verification"
HOMEPAGE="http://opendkim.org"
SRC_URI="mirror://sourceforge/opendkim/${P}.tar.gz"
LICENSE="Sendmail-Open-Source BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+berkdb gnutls ldap lmdb lua memcached opendbx poll sasl selinux +ssl static-libs unbound"
DEPEND="|| ( mail-filter/libmilter mail-mta/sendmail )
dev-libs/libbsd
ssl? ( >=dev-libs/openssl-0.9.8 )
berkdb? ( >=sys-libs/db-3.2 )
opendbx? ( >=dev-db/opendbx-1.4.0 )
lua? ( dev-lang/lua )
ldap? ( net-nds/openldap )
lmdb? ( dev-db/lmdb )
memcached? ( dev-libs/libmemcached )
sasl? ( dev-libs/cyrus-sasl )
selinux? ( sec-policy/selinux-dkim )
unbound? ( >=net-dns/unbound-1.4.1 net-dns/dnssec-root )
!unbound? ( net-libs/ldns )
gnutls? ( >=net-libs/gnutls-2.11.7 )"
RDEPEND="${DEPEND}
sys-process/psmisc"
REQUIRED_USE="sasl? ( ldap )"
pkg_setup() {
enewgroup milter
# mail-milter/spamass-milter creates milter user with this home directory
# For consistency reasons, milter user must be created here with this home directory
# even though this package doesn't need a home directory for this user (#280571)
enewuser milter -1 -1 /var/lib/milter milter
}
src_prepare() {
sed -i -e 's:/var/db/dkim:/etc/opendkim:g' \
-e 's:/var/db/opendkim:/var/lib/opendkim:g' \
-e 's:/etc/mail:/etc/opendkim:g' \
-e 's:mailnull:milter:g' \
-e 's:^#[[:space:]]*PidFile.*:PidFile /var/run/opendkim/opendkim.pid:' \
opendkim/opendkim.conf.sample opendkim/opendkim.conf.simple.in \
stats/opendkim-reportstats{,.in} || die
sed -i -e 's:dist_doc_DATA:dist_html_DATA:' libopendkim/docs/Makefile.am \
|| die
#sed -i -e '/sock.*mt.getcwd/s:mt.getcwd():"/tmp":' opendkim/tests/*.lua
sed -i -e '/sock.*mt.getcwd/s:mt.getcwd():"/proc/self/cwd":' opendkim/tests/*.lua
eautoreconf
}
src_configure() {
local myconf
if use berkdb ; then
myconf=$(db_includedir)
myconf="--with-db-incdir=${myconf#-I}"
myconf+=" --enable-popauth"
myconf+=" --enable-query_cache"
myconf+=" --enable-stats"
fi
if use unbound; then
myconf+=" --with-unbound"
else
myconf+=" --with-ldns"
fi
if use ldap; then
myconf+=" $(use_with sasl)"
fi
econf \
$(use_with berkdb db) \
$(use_with opendbx odbx) \
$(use_with lua) \
$(use_enable lua rbl) \
$(use_with ldap openldap) \
$(use_with lmdb) \
$(use_enable poll) \
$(use_enable static-libs static) \
$(use_with gnutls) \
$(use_with memcached libmemcached) \
${myconf} \
--docdir=/usr/share/doc/${PF} \
--htmldir=/usr/share/doc/${PF}/html \
--enable-filter \
--enable-adsp_lists \
--enable-atps \
--enable-identity_header \
--enable-rate_limit \
--enable-resign \
--enable-replace_rules \
--enable-default_sender \
--enable-sender_macro \
--enable-vbr \
--disable-live-testing
#--disable-rpath \
#--with-test-socket=/tmp/opendkim-$(echo ${RANDOM})-S
}
src_install() {
emake DESTDIR="${D}" install
dosbin stats/opendkim-reportstats
newinitd "${FILESDIR}/opendkim.init.r3" opendkim
systemd_dounit "${FILESDIR}/opendkim.service"
dodir /etc/opendkim /var/lib/opendkim
fowners milter:milter /var/lib/opendkim
# default configuration
if [ ! -f "${ROOT}"/etc/opendkim/opendkim.conf ]; then
grep ^[^#] "${S}"/opendkim/opendkim.conf.simple \
> "${D}"/etc/opendkim/opendkim.conf
if use unbound; then
echo TrustAnchorFile /etc/dnssec/root-anchors.txt >> "${D}"/etc/opendkim/opendkim.conf
fi
echo UserID milter >> "${D}"/etc/opendkim/opendkim.conf
if use berkdb; then
echo Statistics /var/lib/opendkim/stats.dat >> \
"${D}"/etc/opendkim/opendkim.conf
fi
fi
use static-libs || find "${D}" -name "*.la" -delete
}
pkg_postinst() {
if [[ -z ${REPLACING_VERSION} ]]; then
elog "If you want to sign your mail messages and need some help"
elog "please run:"
elog " emerge --config ${CATEGORY}/${PN}"
elog "It will help you create your key and give you hints on how"
elog "to configure your DNS and MTA."
ewarn "Make sure your MTA has r/w access to the socket file."
ewarn "This can be done either by setting UMask to 002 and adding MTA's user"
ewarn "to milter group or you can simply set UMask to 000."
fi
}
pkg_config() {
local selector keysize pubkey
read -p "Enter the selector name (default ${HOSTNAME}): " selector
[[ -n "${selector}" ]] || selector=${HOSTNAME}
if [[ -z "${selector}" ]]; then
eerror "Oddly enough, you don't have a HOSTNAME."
return 1
fi
if [[ -f "${ROOT}"etc/opendkim/${selector}.private ]]; then
ewarn "The private key for this selector already exists."
else
keysize=1024
# generate the private and public keys
opendkim-genkey -b ${keysize} -D "${ROOT}"etc/opendkim/ \
-s ${selector} -d '(your domain)' && \
chown milter:milter \
"${ROOT}"etc/opendkim/"${selector}".private || \
{ eerror "Failed to create private and public keys." ; return 1; }
chmod go-r "${ROOT}"etc/opendkim/"${selector}".private
fi
# opendkim selector configuration
echo
einfo "Make sure you have the following settings in your /etc/opendkim/opendkim.conf:"
einfo " Keyfile /etc/opendkim/${selector}.private"
einfo " Selector ${selector}"
# MTA configuration
echo
einfo "If you are using Postfix, add following lines to your main.cf:"
einfo " smtpd_milters = unix:/var/run/opendkim/opendkim.sock"
einfo " non_smtpd_milters = unix:/var/run/opendkim/opendkim.sock"
einfo " and read http://www.postfix.org/MILTER_README.html"
# DNS configuration
einfo "After you configured your MTA, publish your key by adding this TXT record to your domain:"
cat "${ROOT}"etc/opendkim/${selector}.txt
einfo "t=y signifies you only test the DKIM on your domain. See following page for the complete list of tags:"
einfo " http://www.dkim.org/specs/rfc4871-dkimbase.html#key-text"
einfo
einfo "Also look at the ADSP http://tools.ietf.org/html/rfc5617"
}
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in mail-filter/opendkim: opendkim-2.9.2-r1.ebuild ChangeLog
@ 2014-07-31 6:24 Eray Aslan (eras)
0 siblings, 0 replies; 3+ messages in thread
From: Eray Aslan (eras) @ 2014-07-31 6:24 UTC (permalink / raw
To: gentoo-commits
eras 14/07/31 06:24:14
Modified: opendkim-2.9.2-r1.ebuild ChangeLog
Log:
Remove einfo for ADSP
(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x77F1F175586A3B1F)
Revision Changes Path
1.3 mail-filter/opendkim/opendkim-2.9.2-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/opendkim-2.9.2-r1.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/opendkim-2.9.2-r1.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/opendkim-2.9.2-r1.ebuild?r1=1.2&r2=1.3
Index: opendkim-2.9.2-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-filter/opendkim/opendkim-2.9.2-r1.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- opendkim-2.9.2-r1.ebuild 4 May 2014 16:11:57 -0000 1.2
+++ opendkim-2.9.2-r1.ebuild 31 Jul 2014 06:24:14 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/opendkim-2.9.2-r1.ebuild,v 1.2 2014/05/04 16:11:57 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/opendkim-2.9.2-r1.ebuild,v 1.3 2014/07/31 06:24:14 eras Exp $
EAPI=5
inherit autotools db-use eutils systemd user
@@ -193,6 +193,4 @@
cat "${ROOT}"etc/opendkim/${selector}.txt
einfo "t=y signifies you only test the DKIM on your domain. See following page for the complete list of tags:"
einfo " http://www.dkim.org/specs/rfc4871-dkimbase.html#key-text"
- einfo
- einfo "Also look at the ADSP http://tools.ietf.org/html/rfc5617"
}
1.80 mail-filter/opendkim/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/ChangeLog?rev=1.80&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/ChangeLog?rev=1.80&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/ChangeLog?r1=1.79&r2=1.80
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v
retrieving revision 1.79
retrieving revision 1.80
diff -u -r1.79 -r1.80
--- ChangeLog 4 May 2014 16:11:57 -0000 1.79
+++ ChangeLog 31 Jul 2014 06:24:14 -0000 1.80
@@ -1,6 +1,9 @@
# ChangeLog for mail-filter/opendkim
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v 1.79 2014/05/04 16:11:57 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v 1.80 2014/07/31 06:24:14 eras Exp $
+
+ 31 Jul 2014; Eray Aslan <eras@gentoo.org> opendkim-2.9.2-r1.ebuild:
+ Remove einfo for ADSP
04 May 2014; Markus Meier <maekke@gentoo.org> opendkim-2.9.2-r1.ebuild:
add ~arm, bug #509082
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in mail-filter/opendkim: opendkim-2.9.2-r1.ebuild ChangeLog
@ 2014-11-02 8:36 Sven Vermeulen (swift)
0 siblings, 0 replies; 3+ messages in thread
From: Sven Vermeulen (swift) @ 2014-11-02 8:36 UTC (permalink / raw
To: gentoo-commits
swift 14/11/02 08:36:29
Modified: opendkim-2.9.2-r1.ebuild ChangeLog
Log:
Remove sec-policy/selinux-* dependency from DEPEND but keep in RDEPEND (bug #527698)
(Portage version: 2.2.8-r2/cvs/Linux x86_64, signed Manifest commit with key 0x2EDD52403B68AF47)
Revision Changes Path
1.6 mail-filter/opendkim/opendkim-2.9.2-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/opendkim-2.9.2-r1.ebuild?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/opendkim-2.9.2-r1.ebuild?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/opendkim-2.9.2-r1.ebuild?r1=1.5&r2=1.6
Index: opendkim-2.9.2-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-filter/opendkim/opendkim-2.9.2-r1.ebuild,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- opendkim-2.9.2-r1.ebuild 14 Aug 2014 16:17:22 -0000 1.5
+++ opendkim-2.9.2-r1.ebuild 2 Nov 2014 08:36:29 -0000 1.6
@@ -1,6 +1,6 @@
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/opendkim-2.9.2-r1.ebuild,v 1.5 2014/08/14 16:17:22 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/opendkim-2.9.2-r1.ebuild,v 1.6 2014/11/02 08:36:29 swift Exp $
EAPI=5
inherit autotools db-use eutils systemd user
@@ -29,13 +29,14 @@
lmdb? ( dev-db/lmdb )
memcached? ( dev-libs/libmemcached )
sasl? ( dev-libs/cyrus-sasl )
- selinux? ( sec-policy/selinux-dkim )
unbound? ( >=net-dns/unbound-1.4.1 net-dns/dnssec-root )
!unbound? ( net-libs/ldns )
gnutls? ( >=net-libs/gnutls-2.11.7 )"
RDEPEND="${DEPEND}
- sys-process/psmisc"
+ sys-process/psmisc
+ selinux? ( sec-policy/selinux-dkim )
+"
REQUIRED_USE="sasl? ( ldap )"
1.83 mail-filter/opendkim/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/ChangeLog?rev=1.83&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/ChangeLog?rev=1.83&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/ChangeLog?r1=1.82&r2=1.83
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v
retrieving revision 1.82
retrieving revision 1.83
diff -u -r1.82 -r1.83
--- ChangeLog 14 Aug 2014 16:17:22 -0000 1.82
+++ ChangeLog 2 Nov 2014 08:36:29 -0000 1.83
@@ -1,6 +1,10 @@
# ChangeLog for mail-filter/opendkim
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v 1.82 2014/08/14 16:17:22 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v 1.83 2014/11/02 08:36:29 swift Exp $
+
+ 02 Nov 2014; Sven Vermeulen <swift@gentoo.org> opendkim-2.9.2-r1.ebuild:
+ Remove sec-policy/selinux-* dependency from DEPEND but keep in RDEPEND (bug
+ #527698)
14 Aug 2014; Pawel Hajdan jr <phajdan.jr@gentoo.org>
opendkim-2.9.2-r1.ebuild:
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2014-11-02 8:36 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-11-02 8:36 [gentoo-commits] gentoo-x86 commit in mail-filter/opendkim: opendkim-2.9.2-r1.ebuild ChangeLog Sven Vermeulen (swift)
-- strict thread matches above, loose matches on Subject: below --
2014-07-31 6:24 Eray Aslan (eras)
2014-05-02 10:46 Pacho Ramos (pacho)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox