[gentoo-commits] gentoo-x86 commit in app-emacs/auctex: ChangeLog auctex-11.88.ebuild

[gentoo-commits] gentoo-x86 commit in app-emacs/auctex: ChangeLog auctex-11.88.ebuild

[Ulrich Mueller (ulm)]

ulm         14/11/01 16:45:58

  Modified:             ChangeLog
  Added:                auctex-11.88.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 9433907D693FB5B8!)

Revision  Changes    Path
1.128                app-emacs/auctex/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/auctex/ChangeLog?rev=1.128&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/auctex/ChangeLog?rev=1.128&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/auctex/ChangeLog?r1=1.127&r2=1.128

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emacs/auctex/ChangeLog,v
retrieving revision 1.127
retrieving revision 1.128
diff -u -r1.127 -r1.128
--- ChangeLog	1 Nov 2014 16:33:18 -0000	1.127
+++ ChangeLog	1 Nov 2014 16:45:58 -0000	1.128
@@ -1,6 +1,11 @@
 # ChangeLog for app-emacs/auctex
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emacs/auctex/ChangeLog,v 1.127 2014/11/01 16:33:18 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emacs/auctex/ChangeLog,v 1.128 2014/11/01 16:45:58 ulm Exp $
+
+*auctex-11.88 (01 Nov 2014)
+
+  01 Nov 2014; Ulrich Müller <ulm@gentoo.org> +auctex-11.88.ebuild:
+  Version bump.
 
   01 Nov 2014; Ulrich Müller <ulm@gentoo.org> auctex-11.87-r1.ebuild:
   Fix typo in src_configure, EMACS_FLAVOR instead of EMACS_FLAVOUR.



1.1                  app-emacs/auctex/auctex-11.88.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/auctex/auctex-11.88.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/auctex/auctex-11.88.ebuild?rev=1.1&content-type=text/plain

Index: auctex-11.88.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emacs/auctex/auctex-11.88.ebuild,v 1.1 2014/11/01 16:45:58 ulm Exp $

EAPI=5

inherit elisp latex-package

DESCRIPTION="Extended support for writing, formatting and using (La)TeX, Texinfo and BibTeX files"
HOMEPAGE="http://www.gnu.org/software/auctex/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"

LICENSE="GPL-3+ FDL-1.3+"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris"
IUSE="preview-latex"

DEPEND="virtual/latex-base
	preview-latex? (
		app-text/dvipng
		app-text/ghostscript-gpl
	)"
RDEPEND="${DEPEND}"

TEXMF="/usr/share/texmf-site"

src_prepare() {
	elisp_src_prepare
}

src_configure() {
	EMACS_NAME=emacs EMACS_FLAVOR=emacs econf --disable-build-dir-test \
		--with-auto-dir="${EPREFIX}/var/lib/auctex" \
		--with-lispdir="${EPREFIX}${SITELISP}/${PN}" \
		--with-packagelispdir="${EPREFIX}${SITELISP}/${PN}" \
		--with-packagedatadir="${EPREFIX}${SITEETC}/${PN}" \
		--with-texmf-dir="${EPREFIX}${TEXMF}" \
		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
		$(use_enable preview-latex preview)
}

src_compile() {
	export VARTEXFONTS="${T}"/fonts
	emake
}

src_install() {
	emake -j1 DESTDIR="${D}" install
	elisp-site-file-install "${FILESDIR}/50${PN}-gentoo.el"
	if use preview-latex; then
		elisp-site-file-install "${FILESDIR}/60${PN}-gentoo.el"
	fi
	dodoc ChangeLog CHANGES FAQ INSTALL PROBLEMS.preview README RELEASE TODO
}

pkg_postinst() {
	# rebuild TeX-inputfiles-database
	use preview-latex && latex-package_pkg_postinst
	elisp-site-regen
}

pkg_postrm(){
	use preview-latex && latex-package_pkg_postrm
	elisp-site-regen
}