[gentoo-commits] gentoo-x86 commit in net-analyzer/flow-tools: flow-tools-0.68.5.1-r5.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-analyzer/flow-tools: flow-tools-0.68.5.1-r5.ebuild ChangeLog

[Robin H. Johnson (robbat2)]

robbat2     14/10/27 00:19:51

  Modified:             ChangeLog
  Added:                flow-tools-0.68.5.1-r5.ebuild
  Log:
  Revbump for daemon tweak to init script.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.72                 net-analyzer/flow-tools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/flow-tools/ChangeLog?rev=1.72&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/flow-tools/ChangeLog?rev=1.72&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/flow-tools/ChangeLog?r1=1.71&r2=1.72

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/flow-tools/ChangeLog,v
retrieving revision 1.71
retrieving revision 1.72
diff -u -r1.71 -r1.72
--- ChangeLog	23 Aug 2014 09:35:02 -0000	1.71
+++ ChangeLog	27 Oct 2014 00:19:51 -0000	1.72
@@ -1,6 +1,12 @@
 # ChangeLog for net-analyzer/flow-tools
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/flow-tools/ChangeLog,v 1.71 2014/08/23 09:35:02 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/flow-tools/ChangeLog,v 1.72 2014/10/27 00:19:51 robbat2 Exp $
+
+*flow-tools-0.68.5.1-r5 (27 Oct 2014)
+
+  27 Oct 2014; Robin H. Johnson <robbat2@gentoo.org>
+  +flow-tools-0.68.5.1-r5.ebuild, files/flowcapture.initd:
+  Revbump for daemon tweak to init script.
 
 *flow-tools-0.68.5.1-r4 (23 Aug 2014)
 



1.1                  net-analyzer/flow-tools/flow-tools-0.68.5.1-r5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/flow-tools/flow-tools-0.68.5.1-r5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/flow-tools/flow-tools-0.68.5.1-r5.ebuild?rev=1.1&content-type=text/plain

Index: flow-tools-0.68.5.1-r5.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/flow-tools/flow-tools-0.68.5.1-r5.ebuild,v 1.1 2014/10/27 00:19:51 robbat2 Exp $

EAPI=5
inherit eutils user

DESCRIPTION="library and programs to collect, send, process, and generate reports from NetFlow data"
HOMEPAGE="http://code.google.com/p/flow-tools/"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.bz2"

LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug mysql postgres ssl static-libs"

RDEPEND="sys-apps/tcp-wrappers
	sys-libs/zlib
	mysql? ( virtual/mysql )
	postgres? ( dev-db/postgresql-base )
	ssl? ( dev-libs/openssl )"

DEPEND="${RDEPEND}
	sys-devel/flex
	sys-devel/bison"

DOCS=( ChangeLog README SECURITY TODO )

pkg_setup() {
	enewgroup flows
	enewuser flows -1 -1 /var/lib/flows flows
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-run.patch
	epatch "${FILESDIR}"/${P}-syslog.patch
}

src_configure() {
	econf \
		$(use_enable static-libs static) \
		$(usex mysql --with-mysql '') \
		$(usex postgres --with-postgresql=yes --with-postgresql=no) \
		$(usex ssl --with-openssl '') \
		--sysconfdir=/etc/flow-tools
}

src_install() {
	default

	prune_libtool_files

	exeinto /var/lib/flows/bin
	doexe "${FILESDIR}"/linkme

	keepdir /var/lib/flows/ft

	newinitd "${FILESDIR}/flowcapture.initd" flowcapture
	newconfd "${FILESDIR}/flowcapture.confd" flowcapture

	fowners flows:flows /var/lib/flows
	fowners flows:flows /var/lib/flows/bin
	fowners flows:flows /var/lib/flows/ft

	fperms 0755 /var/lib/flows
	fperms 0755 /var/lib/flows/bin
}

pkg_preinst() {
	enewgroup flows
	enewuser flows -1 -1 /var/lib/flows flows
}