[gentoo-commits] gentoo-x86 commit in net-libs/polarssl: ChangeLog polarssl-1.3.9.ebuild

[gentoo-commits] gentoo-x86 commit in net-libs/polarssl: ChangeLog polarssl-1.3.9.ebuild

[Julian Ospald (hasufell)]

hasufell    14/10/25 17:21:50

  Modified:             ChangeLog
  Added:                polarssl-1.3.9.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key BDEED020)

Revision  Changes    Path
1.93                 net-libs/polarssl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/polarssl/ChangeLog?rev=1.93&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/polarssl/ChangeLog?rev=1.93&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/polarssl/ChangeLog?r1=1.92&r2=1.93

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/polarssl/ChangeLog,v
retrieving revision 1.92
retrieving revision 1.93
diff -u -r1.92 -r1.93
--- ChangeLog	20 Aug 2014 12:14:46 -0000	1.92
+++ ChangeLog	25 Oct 2014 17:21:50 -0000	1.93
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/polarssl
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/polarssl/ChangeLog,v 1.92 2014/08/20 12:14:46 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/polarssl/ChangeLog,v 1.93 2014/10/25 17:21:50 hasufell Exp $
+
+*polarssl-1.3.9 (25 Oct 2014)
+
+  25 Oct 2014; Julian Ospald <hasufell@gentoo.org> +polarssl-1.3.9.ebuild,
+  +files/polarssl-1.3.9-respect-cflags.patch:
+  version bump
 
   20 Aug 2014; Raúl Porcel <armin76@gentoo.org> polarssl-1.3.8.ebuild:
   Add ~ia64 wrt #468362 and mark alpha stable



1.1                  net-libs/polarssl/polarssl-1.3.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/polarssl/polarssl-1.3.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/polarssl/polarssl-1.3.9.ebuild?rev=1.1&content-type=text/plain

Index: polarssl-1.3.9.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/polarssl/polarssl-1.3.9.ebuild,v 1.1 2014/10/25 17:21:50 hasufell Exp $

EAPI=5

inherit eutils multilib cmake-utils multilib-minimal

DESCRIPTION="Cryptographic library for embedded systems"
HOMEPAGE="http://polarssl.org/"
SRC_URI="http://polarssl.org/download/${P}-gpl.tgz"

LICENSE="GPL-2"
SLOT="0/7"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE="doc havege programs sse2 static-libs test threads zlib"

RDEPEND="
	programs? ( dev-libs/openssl:0 )
	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen media-gfx/graphviz )
	test? ( dev-lang/perl )"

enable_polarssl_option() {
	local myopt="$@"
	# check that config.h syntax is the same at version bump
	sed -i \
		-e "s://#define ${myopt}:#define ${myopt}:" \
		include/polarssl/config.h || die
}

src_prepare() {
	use sse2 && enable_polarssl_option POLARSSL_HAVE_SSE2
	use zlib && enable_polarssl_option POLARSSL_ZLIB_SUPPORT
	use havege && enable_polarssl_option POLARSSL_HAVEGE_C
	use threads && enable_polarssl_option POLARSSL_THREADING_C
	use threads && enable_polarssl_option POLARSSL_THREADING_PTHREAD

	epatch "${FILESDIR}"/${PN}-1.3.9-respect-cflags.patch
}

multilib_src_configure() {
	local mycmakeargs=(
		$(multilib_is_native_abi && cmake-utils_use_enable programs PROGRAMS \
			|| echo -DENABLE_PROGRAMS=OFF)
		$(cmake-utils_use_enable zlib ZLIB_SUPPORT)
		$(cmake-utils_use_use static-libs STATIC_POLARSSL_LIBRARY)
		$(cmake-utils_use_enable test TESTING)
		-DUSE_SHARED_POLARSSL_LIBRARY=ON
		-DINSTALL_POLARSSL_HEADERS=ON
		-DLIB_INSTALL_DIR="/usr/$(get_libdir)"
	)

	cmake-utils_src_configure
}

multilib_src_compile() {
	cmake-utils_src_compile
	use doc && multilib_is_native_abi && emake apidoc
}

multilib_src_test() {
	LD_LIBRARY_PATH="${LD_LIBRARY_PATH}:${BUILD_DIR}/library" \
		cmake-utils_src_test
}

multilib_src_install() {
	cmake-utils_src_install
}

multilib_src_install_all() {
	einstalldocs

	use doc && dohtml -r apidoc

	if use programs ; then
		# avoid file collisions with sys-apps/coreutils
		local p e
		for p in "${ED%/}"/usr/bin/* ; do
			if [[ -x "${p}" && ! -d "${p}" ]] ; then
				mv "${p}" "${ED%/}"/usr/bin/polarssl_${p##*/} || die
			fi
		done
		for e in aes hash pkey ssl test ; do
			docinto "${e}"
			dodoc programs/"${e}"/*.c
			dodoc programs/"${e}"/*.txt
		done
	fi
}