[gentoo-commits] gentoo-x86 commit in app-editors/vim-qt: vim-qt-20140827.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in app-editors/vim-qt: vim-qt-20140827.ebuild ChangeLog

[Ben de Groot (yngwin)]

yngwin      14/10/25 02:10:14

  Modified:             ChangeLog
  Added:                vim-qt-20140827.ebuild
  Log:
  version bump, bug #525820
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0x0F9C590B7FF324F6!)

Revision  Changes    Path
1.7                  app-editors/vim-qt/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/vim-qt/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/vim-qt/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/vim-qt/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/vim-qt/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	25 Oct 2013 16:34:26 -0000	1.6
+++ ChangeLog	25 Oct 2014 02:10:14 -0000	1.7
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/vim-qt
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/vim-qt/ChangeLog,v 1.6 2013/10/25 16:34:26 yngwin Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/vim-qt/ChangeLog,v 1.7 2014/10/25 02:10:14 yngwin Exp $
+
+*vim-qt-20140827 (25 Oct 2014)
+
+  25 Oct 2014; Ben de Groot <yngwin@gentoo.org> +vim-qt-20140827.ebuild:
+  version bump, bug #525820
 
 *vim-qt-20131004 (25 Oct 2013)
 



1.1                  app-editors/vim-qt/vim-qt-20140827.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/vim-qt/vim-qt-20140827.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/vim-qt/vim-qt-20140827.ebuild?rev=1.1&content-type=text/plain

Index: vim-qt-20140827.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/vim-qt/vim-qt-20140827.ebuild,v 1.1 2014/10/25 02:10:14 yngwin Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7} )
PYTHON_REQ_USE="threads"
inherit eutils fdo-mime flag-o-matic python-single-r1

DESCRIPTION="Qt GUI version of the Vim text editor"
HOMEPAGE="https://bitbucket.org/equalsraf/vim-qt/wiki/Home"

if [[ ${PV} == *9999* ]]; then
	inherit git-2
	EGIT_REPO_URI="https://bitbucket.org/equalsraf/${PN}.git
		git://github.com/equalsraf/${PN}.git
		git://gitorious.org/${PN}/${PN}.git"
	KEYWORDS=""
else
	SRC_URI="https://github.com/equalsraf/${PN}/archive/package-${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64 ~x86"
	S="${WORKDIR}/${PN}-package-${PV}"
fi

LICENSE="vim"
SLOT="0"
IUSE="acl cscope debug gpm lua luajit nls perl python ruby"

RDEPEND="app-admin/eselect-vi
	>=app-editors/vim-core-7.4.417[acl?]
	sys-libs/ncurses
	>=dev-qt/qtcore-4.7.0:4
	>=dev-qt/qtgui-4.7.0:4
	acl? ( kernel_linux? ( sys-apps/acl ) )
	cscope? ( dev-util/cscope )
	gpm? ( sys-libs/gpm )
	lua? ( luajit? ( dev-lang/luajit )
		!luajit? ( dev-lang/lua ) )
	nls? ( virtual/libintl )
	perl? ( dev-lang/perl )
	python? ( ${PYTHON_DEPS} )
	ruby? ( || ( dev-lang/ruby:2.0 dev-lang/ruby:1.9 ) )"
DEPEND="${RDEPEND}
	dev-util/ctags
	sys-devel/autoconf
	virtual/pkgconfig
	nls? ( sys-devel/gettext )"

REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

pkg_setup() {
	export LC_COLLATE="C" # prevent locale brokenness bug #82186
	use python && python-single-r1_pkg_setup
}

src_configure() {
	use debug && append-flags "-DDEBUG"

	local myconf="--with-features=huge --enable-multibyte"
	myconf+=" $(use_enable acl)"
	myconf+=" $(use_enable gpm)"
	myconf+=" $(use_enable nls)"
	myconf+=" $(use_enable lua luainterp)"
	myconf+=" $(use_with luajit)"
	myconf+=" $(use_enable perl perlinterp)"
	myconf+=" $(use_enable python pythoninterp)"
	myconf+=" $(use_enable ruby rubyinterp)"
	myconf+=" --enable-gui=qt --with-vim-name=qvim --with-x"

	if ! use cscope ; then
		sed -i -e '/# define FEAT_CSCOPE/d' src/feature.h || die 'sed failed'
	fi
	econf ${myconf}
}

src_install() {
	dobin src/qvim
	doicon -s 64 src/qt/icons/vim-qt.png
	make_desktop_entry qvim Vim-qt vim-qt "Qt;TextEditor;Development;"
}

pkg_postinst() {
	fdo-mime_mime_database_update
}

pkg_postrm() {
	fdo-mime_mime_database_update
}