* [gentoo-commits] gentoo-x86 commit in net-misc/suite3270: suite3270-3.3.15_p4.ebuild ChangeLog
@ 2014-10-18 17:41 Mike Frysinger (vapier)
0 siblings, 0 replies; only message in thread
From: Mike Frysinger (vapier) @ 2014-10-18 17:41 UTC (permalink / raw
To: gentoo-commits
vapier 14/10/18 17:41:47
Modified: ChangeLog
Added: suite3270-3.3.15_p4.ebuild
Log:
Version bump.
(Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key D2E96200)
Revision Changes Path
1.62 net-misc/suite3270/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/suite3270/ChangeLog?rev=1.62&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/suite3270/ChangeLog?rev=1.62&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/suite3270/ChangeLog?r1=1.61&r2=1.62
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/suite3270/ChangeLog,v
retrieving revision 1.61
retrieving revision 1.62
diff -u -r1.61 -r1.62
--- ChangeLog 18 Oct 2014 17:41:23 -0000 1.61
+++ ChangeLog 18 Oct 2014 17:41:47 -0000 1.62
@@ -1,6 +1,11 @@
# ChangeLog for net-misc/suite3270
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/suite3270/ChangeLog,v 1.61 2014/10/18 17:41:23 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/suite3270/ChangeLog,v 1.62 2014/10/18 17:41:47 vapier Exp $
+
+*suite3270-3.3.15_p4 (18 Oct 2014)
+
+ 18 Oct 2014; Mike Frysinger <vapier@gentoo.org> +suite3270-3.3.15_p4.ebuild:
+ Version bump.
18 Oct 2014; Mike Frysinger <vapier@gentoo.org> suite3270-3.3.14_p11.ebuild:
Stabilize for all.
1.1 net-misc/suite3270/suite3270-3.3.15_p4.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/suite3270/suite3270-3.3.15_p4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/suite3270/suite3270-3.3.15_p4.ebuild?rev=1.1&content-type=text/plain
Index: suite3270-3.3.15_p4.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/suite3270/suite3270-3.3.15_p4.ebuild,v 1.1 2014/10/18 17:41:47 vapier Exp $
EAPI="4"
MY_PV=${PV/_p/ga}
MY_P=${PN}-${MY_PV}
SUB_PV=${PV:0:3}
S=${WORKDIR}
# only the x3270 package installs fonts
FONT_PN="x3270"
FONT_S=${WORKDIR}/${FONT_PN}-${SUB_PV}
inherit eutils font multiprocessing
DESCRIPTION="Complete 3270 access package"
HOMEPAGE="http://x3270.bgp.nu/"
SRC_URI="mirror://sourceforge/x3270/${MY_P}-src.tgz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~s390 ~sparc ~x86"
IUSE="cjk doc ncurses ssl tcl X"
RDEPEND="ssl? ( dev-libs/openssl )
X? (
x11-libs/libX11
x11-libs/libXaw
x11-libs/libXmu
x11-libs/libXt
)
ncurses? ( sys-libs/ncurses sys-libs/readline )
tcl? ( dev-lang/tcl )"
DEPEND="${RDEPEND}
X? (
x11-misc/xbitmaps
x11-proto/xproto
app-text/rman
x11-apps/mkfontdir
x11-apps/bdftopcf
)"
suite3270_makelist() {
echo pr3287 s3270 \
$(usex ncurses c3270 '') \
$(usex tcl tcl3270 '') \
$(usex X x3270 '')
}
src_prepare() {
# Some subdirs (like c3270/x3270/s3270) install the same set of data files
# (they have the same contents). Wrap that in a retry to avoid errors.
cat <<-EOF > _install
#!/bin/sh
for n in {1..5}; do
install "\$@" && exit
echo "retrying ..."
done
EOF
chmod a+rx _install
sed -i \
-e "s:@INSTALL@:${S}/_install:" \
*/Makefile.in
sed -i \
-e 's:CPPFunction:rl_completion_func_t:' \
c3270-*/c3270.c || die #503364
}
src_configure() {
local p myconf
# Run configures in parallel!
multijob_init
for p in $(suite3270_makelist) ; do
cd "${S}/${p}-${SUB_PV}"
if [[ ${p} == "x3270" ]] ; then
myconf=(
--without-xmkmf
$(use_with X x)
$(use_with X fontdir "${FONTDIR}")
)
else
myconf=()
fi
multijob_child_init econf \
--cache-file="${S}"/config.cache \
$(use_enable cjk dbcs) \
$(use_enable ssl) \
"${myconf[@]}"
done
sed \
-e "s:@SUBDIRS@:$(suite3270_makelist):" \
-e "s:@VER@:${SUB_PV}:" \
"${FILESDIR}"/Makefile.in > "${S}"/Makefile || die
multijob_finish
}
src_install() {
use X && dodir "${FONTDIR}"
EXTRA_TARGETS='install.man' default
local p
for p in $(suite3270_makelist) ; do
cd "${S}/${p}-${SUB_PV}"
docinto ${p}
local d=$(echo README*)
[[ -n ${d} ]] && dodoc ${d}
use doc && dohtml html/*
done
find "${ED}"/usr/share/man/ -type f -perm /1 -exec chmod a-x {} +
use X && font_src_install
}
pkg_postinst() { use X && font_pkg_postinst ; }
pkg_postrm() { use X && font_pkg_postrm ; }
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-10-18 17:41 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-10-18 17:41 [gentoo-commits] gentoo-x86 commit in net-misc/suite3270: suite3270-3.3.15_p4.ebuild ChangeLog Mike Frysinger (vapier)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox