[gentoo-commits] gentoo-x86 commit in media-fonts/unifont: unifont-7.0.05.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in media-fonts/unifont: unifont-7.0.05.ebuild ChangeLog

[Mike Gilbert (floppym)]

floppym     14/10/18 03:59:33

  Modified:             ChangeLog
  Added:                unifont-7.0.05.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

Revision  Changes    Path
1.54                 media-fonts/unifont/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-fonts/unifont/ChangeLog?rev=1.54&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-fonts/unifont/ChangeLog?rev=1.54&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-fonts/unifont/ChangeLog?r1=1.53&r2=1.54

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-fonts/unifont/ChangeLog,v
retrieving revision 1.53
retrieving revision 1.54
diff -u -r1.53 -r1.54
--- ChangeLog	14 Oct 2014 11:11:47 -0000	1.53
+++ ChangeLog	18 Oct 2014 03:59:33 -0000	1.54
@@ -1,6 +1,11 @@
 # ChangeLog for media-fonts/unifont
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-fonts/unifont/ChangeLog,v 1.53 2014/10/14 11:11:47 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-fonts/unifont/ChangeLog,v 1.54 2014/10/18 03:59:33 floppym Exp $
+
+*unifont-7.0.05 (18 Oct 2014)
+
+  18 Oct 2014; Mike Gilbert <floppym@gentoo.org> +unifont-7.0.05.ebuild:
+  Version bump.
 
   14 Oct 2014; Tobias Klausmann <klausman@gentoo.org> unifont-7.0.03.ebuild:
   Keyworded on alpha, bug 500844



1.1                  media-fonts/unifont/unifont-7.0.05.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-fonts/unifont/unifont-7.0.05.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-fonts/unifont/unifont-7.0.05.ebuild?rev=1.1&content-type=text/plain

Index: unifont-7.0.05.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-fonts/unifont/unifont-7.0.05.ebuild,v 1.1 2014/10/18 03:59:33 floppym Exp $

EAPI=5

inherit eutils font toolchain-funcs

DESCRIPTION="GNU Unifont - a Pan-Unicode X11 bitmap iso10646 font"
HOMEPAGE="http://unifoundry.com/"
SRC_URI="mirror://gnu/${PN}/${P}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="fontforge utils"

DEPEND="
	fontforge? (
		app-text/bdf2psf
		dev-lang/perl
		dev-perl/GD[png(-)]
		media-gfx/fontforge
		x11-apps/bdftopcf
	)
"
RDEPEND="
	utils? (
		dev-lang/perl
		dev-perl/GD[png(-)]
	)
"

src_prepare() {
	sed -i -e 's/install -s/install/' src/Makefile || die
	epatch_user
}

src_compile() {
	if use fontforge || use utils; then
		tc-export CC
		makeargs=(
			CFLAGS="${CFLAGS}"
			BUILDFONT=$(usex fontforge 1 '')
		)
		emake -j1 "${makeargs[@]}"
	fi
}

src_install() {
	makeargs+=(
		DESTDIR="${ED%/}"
		PCFDEST="${ED%/}${FONTDIR}"
		TTFDEST="${ED%/}${FONTDIR}"
		USRDIR=usr
	)
	use utils || makeargs+=( -C font )
	emake -j1 "${makeargs[@]}" install
	font_xfont_config
	font_fontconfig
}