[gentoo-commits] gentoo-x86 commit in dev-python/m2crypto: m2crypto-0.22.3-r2.ebuild ChangeLog m2crypto-0.22.3-r1.ebuild

[gentoo-commits] gentoo-x86 commit in dev-python/m2crypto: m2crypto-0.22.3-r2.ebuild ChangeLog m2crypto-0.22.3-r1.ebuild

[Mike Gilbert (floppym)]

floppym     14/10/17 16:50:53

  Modified:             ChangeLog
  Added:                m2crypto-0.22.3-r2.ebuild
  Removed:              m2crypto-0.22.3-r1.ebuild
  Log:
  Fix include path on prefix, bug 525660 by Jean-Michel Smith. Add slots to openssl and swig dependencies.
  
  (Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

Revision  Changes    Path
1.81                 dev-python/m2crypto/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/m2crypto/ChangeLog?rev=1.81&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/m2crypto/ChangeLog?rev=1.81&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/m2crypto/ChangeLog?r1=1.80&r2=1.81

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/m2crypto/ChangeLog,v
retrieving revision 1.80
retrieving revision 1.81
diff -u -r1.80 -r1.81
--- ChangeLog	23 Jul 2014 16:38:25 -0000	1.80
+++ ChangeLog	17 Oct 2014 16:50:52 -0000	1.81
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/m2crypto
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/m2crypto/ChangeLog,v 1.80 2014/07/23 16:38:25 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/m2crypto/ChangeLog,v 1.81 2014/10/17 16:50:52 floppym Exp $
+
+*m2crypto-0.22.3-r2 (17 Oct 2014)
+
+  17 Oct 2014; Mike Gilbert <floppym@gentoo.org> +m2crypto-0.22.3-r2.ebuild,
+  -m2crypto-0.22.3-r1.ebuild:
+  Fix include path on prefix, bug 525660 by Jean-Michel Smith. Add slots to
+  openssl and swig dependencies.
 
 *m2crypto-0.22.3-r1 (23 Jul 2014)
 *m2crypto-0.21.1-r2 (23 Jul 2014)



1.1                  dev-python/m2crypto/m2crypto-0.22.3-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/m2crypto/m2crypto-0.22.3-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/m2crypto/m2crypto-0.22.3-r2.ebuild?rev=1.1&content-type=text/plain

Index: m2crypto-0.22.3-r2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/m2crypto/m2crypto-0.22.3-r2.ebuild,v 1.1 2014/10/17 16:50:52 floppym Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )
PYTHON_REQ_USE="threads(+)"

inherit distutils-r1

MY_PN="M2Crypto"

DESCRIPTION="M2Crypto: A Python crypto and SSL toolkit"
HOMEPAGE="http://chandlerproject.org/bin/view/Projects/MeTooCrypto http://pypi.python.org/pypi/M2Crypto"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE=""

RDEPEND=">=dev-libs/openssl-0.9.8:0="
DEPEND="${RDEPEND}
	>=dev-lang/swig-1.3.28:0
	dev-python/setuptools[${PYTHON_USEDEP}]
"

S="${WORKDIR}/${MY_PN}-${PV}"

# Tests access network, and fail randomly. Bug #431458.
RESTRICT=test

python_prepare_all() {
	# use pre-swigged sources
	sed -i -e '/sources/s:\.i:_wrap.c:' setup.py || die

	distutils-r1_python_prepare_all
}

python_configure_all() {
	set -- swig -python -includeall -I"${EPREFIX}"/usr/include \
		-o SWIG/_m2crypto_wrap.c SWIG/_m2crypto.i

	echo "${@}"
	"${@}" || die 'swig failed'
}

python_test() {
	esetup.py test
}