[gentoo-commits] gentoo-x86 commit in sys-kernel/linux-headers: linux-headers-3.17.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in sys-kernel/linux-headers: linux-headers-3.17.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      14/10/17 01:11:14

  Modified:             ChangeLog
  Added:                linux-headers-3.17.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.417                sys-kernel/linux-headers/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/linux-headers/ChangeLog?rev=1.417&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/linux-headers/ChangeLog?rev=1.417&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/linux-headers/ChangeLog?r1=1.416&r2=1.417

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-kernel/linux-headers/ChangeLog,v
retrieving revision 1.416
retrieving revision 1.417
diff -u -r1.416 -r1.417
--- ChangeLog	4 Aug 2014 09:39:49 -0000	1.416
+++ ChangeLog	17 Oct 2014 01:11:14 -0000	1.417
@@ -1,6 +1,11 @@
 # ChangeLog for sys-kernel/linux-headers
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/linux-headers/ChangeLog,v 1.416 2014/08/04 09:39:49 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/linux-headers/ChangeLog,v 1.417 2014/10/17 01:11:14 vapier Exp $
+
+*linux-headers-3.17 (17 Oct 2014)
+
+  17 Oct 2014; Mike Frysinger <vapier@gentoo.org> +linux-headers-3.17.ebuild:
+  Version bump.
 
 *linux-headers-3.16 (04 Aug 2014)
 



1.1                  sys-kernel/linux-headers/linux-headers-3.17.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/linux-headers/linux-headers-3.17.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/linux-headers/linux-headers-3.17.ebuild?rev=1.1&content-type=text/plain

Index: linux-headers-3.17.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-kernel/linux-headers/linux-headers-3.17.ebuild,v 1.1 2014/10/17 01:11:14 vapier Exp $

EAPI="4"

ETYPE="headers"
H_SUPPORTEDARCH="alpha amd64 arc arm arm64 avr32 bfin cris frv hexagon hppa ia64 m32r m68k metag microblaze mips mn10300 openrisc ppc ppc64 s390 score sh sparc tile x86 xtensa"
inherit kernel-2
detect_version

PATCH_VER="1"
SRC_URI="mirror://gentoo/gentoo-headers-base-${PV}.tar.xz
	${PATCH_VER:+mirror://gentoo/gentoo-headers-${PV}-${PATCH_VER}.tar.xz}"

KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux"

DEPEND="app-arch/xz-utils
	dev-lang/perl"
RDEPEND="!!media-sound/alsa-headers"

S=${WORKDIR}/gentoo-headers-base-${PV}

src_unpack() {
	unpack ${A}
}

src_prepare() {
	[[ -n ${PATCH_VER} ]] && EPATCH_SUFFIX="patch" epatch "${WORKDIR}"/${PV}
}

src_install() {
	kernel-2_src_install

	# hrm, build system sucks
	find "${ED}" '(' -name '.install' -o -name '*.cmd' ')' -delete
	find "${ED}" -depth -type d -delete 2>/dev/null

	# provided by libdrm (for now?)
	rm -rf "${ED}"/$(kernel_header_destdir)/drm
}

src_test() {
	einfo "Possible unescaped attribute/type usage"
	egrep -r \
		-e '(^|[[:space:](])(asm|volatile|inline)[[:space:](]' \
		-e '\<([us](8|16|32|64))\>' \
		.

	einfo "Missing linux/types.h include"
	egrep -l -r -e '__[us](8|16|32|64)' "${ED}" | xargs grep -L linux/types.h

	emake ARCH=$(tc-arch-kernel) headers_check
}