* [gentoo-commits] gentoo-x86 commit in net-misc/networkmanager: networkmanager-0.9.10.0-r1.ebuild ChangeLog
@ 2014-10-13 20:47 Pacho Ramos (pacho)
0 siblings, 0 replies; 5+ messages in thread
From: Pacho Ramos (pacho) @ 2014-10-13 20:47 UTC (permalink / raw
To: gentoo-commits
pacho 14/10/13 20:47:33
Modified: ChangeLog
Added: networkmanager-0.9.10.0-r1.ebuild
Log:
Ifnet plugin is now disabled because of it being unattended and unmaintained for a long time, leading to some unfixed bugs and new problems appearing (#443596, #458274, #493370, #498372, #523700). If some day somebody volunteers for fixing/maintaining that plugin and forwarding all that fixes to upstream it could be re-enabled of course. Append configure option regarding systemd unit files install path only when systemd support is enabled to prevent HAVE_SYSTEMD to be true (#524534 by Konstantin Ivanov). Ensure arping is found (#523632 by Kobboi).
(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)
Revision Changes Path
1.206 net-misc/networkmanager/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.206&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.206&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?r1=1.205&r2=1.206
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v
retrieving revision 1.205
retrieving revision 1.206
diff -u -r1.205 -r1.206
--- ChangeLog 11 Oct 2014 12:30:10 -0000 1.205
+++ ChangeLog 13 Oct 2014 20:47:33 -0000 1.206
@@ -1,6 +1,20 @@
# ChangeLog for net-misc/networkmanager
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.205 2014/10/11 12:30:10 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.206 2014/10/13 20:47:33 pacho Exp $
+
+*networkmanager-0.9.10.0-r1 (13 Oct 2014)
+
+ 13 Oct 2014; Pacho Ramos <pacho@gentoo.org>
+ +files/networkmanager-0.9.10.0-arpingpath.patch,
+ +networkmanager-0.9.10.0-r1.ebuild:
+ Ifnet plugin is now disabled because of it being unattended and unmaintained
+ for a long time, leading to some unfixed bugs and new problems appearing
+ (#443596, #458274, #493370, #498372, #523700). If some day somebody volunteers
+ for fixing/maintaining that plugin and forwarding all that fixes to upstream
+ it could be re-enabled of course. Append configure option regarding systemd
+ unit files install path only when systemd support is enabled to prevent
+ HAVE_SYSTEMD to be true (#524534 by Konstantin Ivanov). Ensure arping is found
+ (#523632 by Kobboi).
11 Oct 2014; Markus Meier <maekke@gentoo.org>
networkmanager-0.9.8.10-r1.ebuild:
1.1 net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild?rev=1.1&content-type=text/plain
Index: networkmanager-0.9.10.0-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild,v 1.1 2014/10/13 20:47:33 pacho Exp $
EAPI="5"
GCONF_DEBUG="no"
GNOME_ORG_MODULE="NetworkManager"
GNOME2_LA_PUNT="yes"
VALA_MIN_API_VERSION="0.18"
VALA_USE_DEPEND="vapigen"
inherit bash-completion-r1 eutils gnome2 linux-info multilib systemd user readme.gentoo toolchain-funcs vala versionator virtualx udev
DESCRIPTION="Universal network configuration daemon for laptops, desktops, servers and virtualization hosts"
HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
LICENSE="GPL-2+"
SLOT="0" # add subslot if libnm-util.so.2 or libnm-glib.so.4 bumps soname version
IUSE="avahi connection-sharing consolekit +dhclient dhcpcd gnutls +introspection \
kernel_linux +nss +modemmanager ncurses +ppp resolvconf selinux systemd teamd test \
vala +wext +wifi" # wimax
KEYWORDS="~amd64 ~x86"
REQUIRED_USE="
modemmanager? ( ppp )
^^ ( nss gnutls )
^^ ( dhclient dhcpcd )
"
# gobject-introspection-0.10.3 is needed due to gnome bug 642300
# wpa_supplicant-0.7.3-r3 is needed due to bug 359271
# TODO: Qt support?
#
# iputils version needed due path changes (#523632). Upstream fixed
# it with a major refactor committed to 'master' for handling different
# paths for arping and other tools and, then, the version requirement
# will be able to be dropped on next major NM version
COMMON_DEPEND="
>=sys-apps/dbus-1.2
>=dev-libs/dbus-glib-0.100
>=dev-libs/glib-2.32:2
>=dev-libs/libnl-3.2.8:3=
>=sys-auth/polkit-0.106
net-libs/libndp
>=net-libs/libsoup-2.26:2.4=
>=net-misc/iputils-20121221-r1
sys-libs/readline
>=virtual/libgudev-165:=
avahi? ( net-dns/avahi:=[autoipd] )
connection-sharing? (
net-dns/dnsmasq[dhcp]
net-firewall/iptables )
gnutls? (
dev-libs/libgcrypt:0=
net-libs/gnutls:= )
modemmanager? ( >=net-misc/modemmanager-0.7.991 )
ncurses? ( >=dev-libs/newt-0.52.15 )
nss? ( >=dev-libs/nss-3.11:= )
dhclient? ( =net-misc/dhcp-4*[client] )
dhcpcd? ( >=net-misc/dhcpcd-4.0.0_rc3 )
introspection? ( >=dev-libs/gobject-introspection-0.10.3 )
ppp? ( >=net-dialup/ppp-2.4.5:=[ipv6] )
resolvconf? ( net-dns/openresolv )
systemd? ( >=sys-apps/systemd-183:0= )
teamd? ( >=net-misc/libteam-1.9 )
|| ( sys-power/upower sys-power/upower-pm-utils >=sys-apps/systemd-183 )
"
RDEPEND="${COMMON_DEPEND}
consolekit? ( sys-auth/consolekit )
wifi? ( >=net-wireless/wpa_supplicant-0.7.3-r3[dbus] )
"
DEPEND="${COMMON_DEPEND}
dev-util/gtk-doc-am
>=dev-util/intltool-0.40
>=sys-devel/gettext-0.17
>=sys-kernel/linux-headers-2.6.29
virtual/pkgconfig
vala? ( $(vala_depend) )
test? (
dev-lang/python:2.7
dev-python/dbus-python[python_targets_python2_7]
dev-python/pygobject:2[python_targets_python2_7] )
"
sysfs_deprecated_check() {
ebegin "Checking for SYSFS_DEPRECATED support"
if { linux_chkconfig_present SYSFS_DEPRECATED_V2; }; then
eerror "Please disable SYSFS_DEPRECATED_V2 support in your kernel config and recompile your kernel"
eerror "or NetworkManager will not work correctly."
eerror "See http://bugs.gentoo.org/333639 for more info."
die "CONFIG_SYSFS_DEPRECATED_V2 support detected!"
fi
eend $?
}
pkg_pretend() {
if use kernel_linux; then
get_version
if linux_config_exists; then
sysfs_deprecated_check
else
ewarn "Was unable to determine your kernel .config"
ewarn "Please note that if CONFIG_SYSFS_DEPRECATED_V2 is set in your kernel .config, NetworkManager will not work correctly."
ewarn "See http://bugs.gentoo.org/333639 for more info."
fi
fi
}
pkg_setup() {
enewgroup plugdev
}
src_prepare() {
DOC_CONTENTS="To modify system network connections without needing to enter the
root password, add your user account to the 'plugdev' group."
# Find arping at proper place, bug #523632
epatch "${FILESDIR}/${PN}-0.9.10.0-arpingpath.patch"
# Use python2.7 shebangs for test scripts
sed -e 's@\(^#!.*python\)@\12.7@' \
-i */tests/*.py || die
# Force use of /run, avoid eautoreconf, upstream bug #737139
sed -e 's:$localstatedir/run/:/run/:' -i configure || die
use vala && vala_src_prepare
epatch_user # don't remove, users often want custom patches for NM
gnome2_src_prepare
}
src_configure() {
local myconf
# Same hack as net-dialup/pptpd to get proper plugin dir for ppp, bug #519986
if use ppp; then
local PPPD_VER=`best_version net-dialup/ppp`
PPPD_VER=${PPPD_VER#*/*-} #reduce it to ${PV}-${PR}
PPPD_VER=${PPPD_VER%%[_-]*} # main version without beta/pre/patch/revision
myconf="${myconf} --with-pppd-plugin-dir=/usr/$(get_libdir)/pppd/${PPPD_VER}"
fi
# unit files directory needs to be passed only when systemd is enabled,
# otherwise systemd support is not disabled completely, bug #524534
use systemd && myconf="${myconf} "$(systemd_with_unitdir)""
# TODO: enable wimax when we have a libnl:3 compatible revision of it
# wimax will be removed, bug #522822
# ifnet plugin always disabled until someone volunteers to actively
# maintain and fix it
gnome2_src_configure \
--disable-more-warnings \
--disable-static \
--localstatedir=/var \
--disable-ifnet \
--without-netconfig \
--with-dbus-sys-dir=/etc/dbus-1/system.d \
--with-udev-dir="$(get_udevdir)" \
--with-iptables=/sbin/iptables \
--enable-concheck \
--with-crypto=$(usex nss nss gnutls) \
--with-session-tracking=$(usex systemd systemd $(usex consolekit consolekit no)) \
--with-suspend-resume=$(usex systemd systemd upower) \
$(use_enable introspection) \
$(use_enable ppp) \
--disable-wimax \
$(use_with dhclient) \
$(use_with dhcpcd) \
$(use_with modemmanager modem-manager-1) \
$(use_with ncurses nmtui) \
$(use_with resolvconf) \
$(use_with selinux) \
$(use_enable teamd teamdctl) \
$(use_enable test tests) \
$(use_enable vala) \
--without-valgrind \
$(use_with wext) \
${myconf}
}
src_test() {
Xemake check
}
src_install() {
# Install completions at proper place, bug #465100
gnome2_src_install completiondir="$(get_bashcompdir)"
readme.gentoo_create_doc
newinitd "${FILESDIR}/init.d.NetworkManager" NetworkManager
newconfd "${FILESDIR}/conf.d.NetworkManager" NetworkManager
# /var/run/NetworkManager is used by some distros, but not by Gentoo
rmdir -v "${ED}/var/run/NetworkManager" || die "rmdir failed"
# Need to keep the /etc/NetworkManager/dispatched.d for dispatcher scripts
keepdir /etc/NetworkManager/dispatcher.d
# Provide openrc net dependency only when nm is connected
exeinto /etc/NetworkManager/dispatcher.d
newexe "${FILESDIR}/10-openrc-status-r4" 10-openrc-status
sed -e "s:@EPREFIX@:${EPREFIX}:g" \
-i "${ED}/etc/NetworkManager/dispatcher.d/10-openrc-status" || die
keepdir /etc/NetworkManager/system-connections
chmod 0600 "${ED}"/etc/NetworkManager/system-connections/.keep* # bug #383765
# Allow users in plugdev group to modify system connections
insinto /usr/share/polkit-1/rules.d/
doins "${FILESDIR}/01-org.freedesktop.NetworkManager.settings.modify.system.rules"
}
pkg_postinst() {
gnome2_pkg_postinst
readme.gentoo_print_elog
if [[ -e "${EROOT}etc/NetworkManager/nm-system-settings.conf" ]]; then
ewarn "The ${PN} system configuration file has moved to a new location."
ewarn "You must migrate your settings from ${EROOT}/etc/NetworkManager/nm-system-settings.conf"
ewarn "to ${EROOT}etc/NetworkManager/NetworkManager.conf"
ewarn
ewarn "After doing so, you can remove ${EROOT}etc/NetworkManager/nm-system-settings.conf"
fi
# The polkit rules file moved to /usr/share
old_rules="${EROOT}etc/polkit-1/rules.d/01-org.freedesktop.NetworkManager.settings.modify.system.rules"
if [[ -f "${old_rules}" ]]; then
case "$(md5sum ${old_rules})" in
574d0cfa7e911b1f7792077003060240* )
# Automatically delete the old rules.d file if the user did not change it
elog
elog "Removing old ${old_rules} ..."
rm -f "${old_rules}" || eerror "Failed, please remove ${old_rules} manually"
;;
* )
elog "The ${old_rules}"
elog "file moved to /usr/share/polkit-1/rules.d/ in >=networkmanager-0.9.4.0-r4"
elog "If you edited ${old_rules}"
elog "without changing its behavior, you may want to remove it."
;;
esac
fi
# ifnet plugin was disabled for systemd users with 0.9.8.6 version
# and for all people with 0.9.10.0-r1 (see ChangeLog for full explanations)
if use systemd; then
if ! version_is_at_least 0.9.8.6 ${REPLACING_VERSIONS}; then
ewarn "Ifnet plugin won't be used with systemd support enabled"
ewarn "as it is meant to be used with openRC and can cause collisions"
ewarn "(like bug #485658)."
ewarn "Because of this, you will likely need to reconfigure some of"
ewarn "your networks. To do this you can rely on Gnome control center,"
ewarn "nm-connection-editor or nmtui tools for example."
fi
else
if ! version_is_at_least 0.9.10.0-r1 ${REPLACING_VERSIONS}; then
ewarn "Ifnet plugin is now disabled because of it being unattended"
ewarn "and unmaintained for a long time, leading to some unfixed bugs"
ewarn "and new problems appearing. We will now use upstream 'keyfile'"
ewarn "plugin."
ewarn "Because of this, you will likely need to reconfigure some of"
ewarn "your networks. To do this you can rely on Gnome control center,"
ewarn "nm-connection-editor or nmtui tools for example."
fi
fi
if [[ -e "${EROOT}etc/NetworkManager/NetworkManager.conf" ]]; then
if grep -q plugins "${EROOT}etc/NetworkManager/NetworkManager.conf" | grep -q ifnet; then
ewarn
ewarn "You seem to use 'ifnet' plugin in ${EROOT}etc/NetworkManager/NetworkManager.conf"
ewarn "Since it won't be used when running under Systemd, you will need to stop setting"
ewarn "ifnet plugin there to allow NetworkManager to work."
ewarn
fi
fi
}
^ permalink raw reply [flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-misc/networkmanager: networkmanager-0.9.10.0-r1.ebuild ChangeLog
@ 2014-10-16 8:58 Pacho Ramos (pacho)
0 siblings, 0 replies; 5+ messages in thread
From: Pacho Ramos (pacho) @ 2014-10-16 8:58 UTC (permalink / raw
To: gentoo-commits
pacho 14/10/16 08:58:49
Modified: networkmanager-0.9.10.0-r1.ebuild ChangeLog
Log:
Add a comment with more information
(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)
Revision Changes Path
1.2 net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild?r1=1.1&r2=1.2
Index: networkmanager-0.9.10.0-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- networkmanager-0.9.10.0-r1.ebuild 13 Oct 2014 20:47:33 -0000 1.1
+++ networkmanager-0.9.10.0-r1.ebuild 16 Oct 2014 08:58:49 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild,v 1.1 2014/10/13 20:47:33 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild,v 1.2 2014/10/16 08:58:49 pacho Exp $
EAPI="5"
GCONF_DEBUG="no"
@@ -271,6 +271,7 @@
fi
fi
+ # NM doesn't fallback to the second listed plugin, upstream bug #738611
if [[ -e "${EROOT}etc/NetworkManager/NetworkManager.conf" ]]; then
if grep -q plugins "${EROOT}etc/NetworkManager/NetworkManager.conf" | grep -q ifnet; then
ewarn
1.207 net-misc/networkmanager/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.207&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.207&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?r1=1.206&r2=1.207
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v
retrieving revision 1.206
retrieving revision 1.207
diff -u -r1.206 -r1.207
--- ChangeLog 13 Oct 2014 20:47:33 -0000 1.206
+++ ChangeLog 16 Oct 2014 08:58:49 -0000 1.207
@@ -1,6 +1,9 @@
# ChangeLog for net-misc/networkmanager
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.206 2014/10/13 20:47:33 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.207 2014/10/16 08:58:49 pacho Exp $
+
+ 16 Oct 2014; Pacho Ramos <pacho@gentoo.org> networkmanager-0.9.10.0-r1.ebuild:
+ Add a comment with more information
*networkmanager-0.9.10.0-r1 (13 Oct 2014)
^ permalink raw reply [flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-misc/networkmanager: networkmanager-0.9.10.0-r1.ebuild ChangeLog
@ 2014-10-21 9:12 Pacho Ramos (pacho)
0 siblings, 0 replies; 5+ messages in thread
From: Pacho Ramos (pacho) @ 2014-10-21 9:12 UTC (permalink / raw
To: gentoo-commits
pacho 14/10/21 09:12:21
Modified: networkmanager-0.9.10.0-r1.ebuild ChangeLog
Log:
Fix the check for ifnet plugin in config
(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)
Revision Changes Path
1.3 net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild?r1=1.2&r2=1.3
Index: networkmanager-0.9.10.0-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- networkmanager-0.9.10.0-r1.ebuild 16 Oct 2014 08:58:49 -0000 1.2
+++ networkmanager-0.9.10.0-r1.ebuild 21 Oct 2014 09:12:21 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild,v 1.2 2014/10/16 08:58:49 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild,v 1.3 2014/10/21 09:12:21 pacho Exp $
EAPI="5"
GCONF_DEBUG="no"
@@ -273,7 +273,7 @@
# NM doesn't fallback to the second listed plugin, upstream bug #738611
if [[ -e "${EROOT}etc/NetworkManager/NetworkManager.conf" ]]; then
- if grep -q plugins "${EROOT}etc/NetworkManager/NetworkManager.conf" | grep -q ifnet; then
+ if grep plugins "${EROOT}etc/NetworkManager/NetworkManager.conf" | grep -q ifnet; then
ewarn
ewarn "You seem to use 'ifnet' plugin in ${EROOT}etc/NetworkManager/NetworkManager.conf"
ewarn "Since it won't be used when running under Systemd, you will need to stop setting"
1.208 net-misc/networkmanager/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.208&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.208&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?r1=1.207&r2=1.208
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v
retrieving revision 1.207
retrieving revision 1.208
diff -u -r1.207 -r1.208
--- ChangeLog 16 Oct 2014 08:58:49 -0000 1.207
+++ ChangeLog 21 Oct 2014 09:12:21 -0000 1.208
@@ -1,6 +1,9 @@
# ChangeLog for net-misc/networkmanager
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.207 2014/10/16 08:58:49 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.208 2014/10/21 09:12:21 pacho Exp $
+
+ 21 Oct 2014; Pacho Ramos <pacho@gentoo.org> networkmanager-0.9.10.0-r1.ebuild:
+ Fix the check for ifnet plugin in config
16 Oct 2014; Pacho Ramos <pacho@gentoo.org> networkmanager-0.9.10.0-r1.ebuild:
Add a comment with more information
^ permalink raw reply [flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-misc/networkmanager: networkmanager-0.9.10.0-r1.ebuild ChangeLog
@ 2014-10-23 19:38 Markus Meier (maekke)
0 siblings, 0 replies; 5+ messages in thread
From: Markus Meier (maekke) @ 2014-10-23 19:38 UTC (permalink / raw
To: gentoo-commits
maekke 14/10/23 19:38:00
Modified: networkmanager-0.9.10.0-r1.ebuild ChangeLog
Log:
add ~arm, bug #523468
(Portage version: 2.2.14_rc1/cvs/Linux x86_64, RepoMan options: --include-arches="arm", signed Manifest commit with key 072AD062)
Revision Changes Path
1.4 net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild?r1=1.3&r2=1.4
Index: networkmanager-0.9.10.0-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- networkmanager-0.9.10.0-r1.ebuild 21 Oct 2014 09:12:21 -0000 1.3
+++ networkmanager-0.9.10.0-r1.ebuild 23 Oct 2014 19:37:59 -0000 1.4
@@ -1,6 +1,6 @@
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild,v 1.3 2014/10/21 09:12:21 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild,v 1.4 2014/10/23 19:37:59 maekke Exp $
EAPI="5"
GCONF_DEBUG="no"
@@ -21,7 +21,7 @@
kernel_linux +nss +modemmanager ncurses +ppp resolvconf selinux systemd teamd test \
vala +wext +wifi" # wimax
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~arm ~x86"
REQUIRED_USE="
modemmanager? ( ppp )
1.209 net-misc/networkmanager/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.209&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.209&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?r1=1.208&r2=1.209
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v
retrieving revision 1.208
retrieving revision 1.209
diff -u -r1.208 -r1.209
--- ChangeLog 21 Oct 2014 09:12:21 -0000 1.208
+++ ChangeLog 23 Oct 2014 19:37:59 -0000 1.209
@@ -1,6 +1,10 @@
# ChangeLog for net-misc/networkmanager
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.208 2014/10/21 09:12:21 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.209 2014/10/23 19:37:59 maekke Exp $
+
+ 23 Oct 2014; Markus Meier <maekke@gentoo.org>
+ networkmanager-0.9.10.0-r1.ebuild:
+ add ~arm, bug #523468
21 Oct 2014; Pacho Ramos <pacho@gentoo.org> networkmanager-0.9.10.0-r1.ebuild:
Fix the check for ifnet plugin in config
^ permalink raw reply [flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-misc/networkmanager: networkmanager-0.9.10.0-r1.ebuild ChangeLog
@ 2014-10-31 21:05 Pacho Ramos (pacho)
0 siblings, 0 replies; 5+ messages in thread
From: Pacho Ramos (pacho) @ 2014-10-31 21:05 UTC (permalink / raw
To: gentoo-commits
pacho 14/10/31 21:05:46
Modified: networkmanager-0.9.10.0-r1.ebuild ChangeLog
Log:
Add reference to upstream bug report
(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)
Revision Changes Path
1.5 net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild?r1=1.4&r2=1.5
Index: networkmanager-0.9.10.0-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- networkmanager-0.9.10.0-r1.ebuild 23 Oct 2014 19:37:59 -0000 1.4
+++ networkmanager-0.9.10.0-r1.ebuild 31 Oct 2014 21:05:46 -0000 1.5
@@ -1,6 +1,6 @@
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild,v 1.4 2014/10/23 19:37:59 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.9.10.0-r1.ebuild,v 1.5 2014/10/31 21:05:46 pacho Exp $
EAPI="5"
GCONF_DEBUG="no"
@@ -121,7 +121,7 @@
# Find arping at proper place, bug #523632
epatch "${FILESDIR}/${PN}-0.9.10.0-arpingpath.patch"
- # Use python2.7 shebangs for test scripts
+ # Use python2.7 shebangs for test scripts, upstream bug #739448
sed -e 's@\(^#!.*python\)@\12.7@' \
-i */tests/*.py || die
1.210 net-misc/networkmanager/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.210&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.210&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?r1=1.209&r2=1.210
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v
retrieving revision 1.209
retrieving revision 1.210
diff -u -r1.209 -r1.210
--- ChangeLog 23 Oct 2014 19:37:59 -0000 1.209
+++ ChangeLog 31 Oct 2014 21:05:46 -0000 1.210
@@ -1,6 +1,9 @@
# ChangeLog for net-misc/networkmanager
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.209 2014/10/23 19:37:59 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.210 2014/10/31 21:05:46 pacho Exp $
+
+ 31 Oct 2014; Pacho Ramos <pacho@gentoo.org> networkmanager-0.9.10.0-r1.ebuild:
+ Add reference to upstream bug report
23 Oct 2014; Markus Meier <maekke@gentoo.org>
networkmanager-0.9.10.0-r1.ebuild:
^ permalink raw reply [flat|nested] 5+ messages in thread
end of thread, other threads:[~2014-10-31 21:05 UTC | newest]
Thread overview: 5+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-10-16 8:58 [gentoo-commits] gentoo-x86 commit in net-misc/networkmanager: networkmanager-0.9.10.0-r1.ebuild ChangeLog Pacho Ramos (pacho)
-- strict thread matches above, loose matches on Subject: below --
2014-10-31 21:05 Pacho Ramos (pacho)
2014-10-23 19:38 Markus Meier (maekke)
2014-10-21 9:12 Pacho Ramos (pacho)
2014-10-13 20:47 Pacho Ramos (pacho)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox