[gentoo-commits] gentoo-x86 commit in sys-libs/libapparmor: libapparmor-2.8.4.ebuild ChangeLog libapparmor-2.8.2.ebuild

[gentoo-commits] gentoo-x86 commit in sys-libs/libapparmor: libapparmor-2.8.4.ebuild ChangeLog libapparmor-2.8.2.ebuild

[Michael Palimaka (kensington)]

kensington    14/10/15 15:33:29

  Modified:             ChangeLog
  Added:                libapparmor-2.8.4.ebuild
  Removed:              libapparmor-2.8.2.ebuild
  Log:
  Version bump. Remove old.
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

Revision  Changes    Path
1.5                  sys-libs/libapparmor/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/libapparmor/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/libapparmor/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/libapparmor/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/libapparmor/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	14 Jul 2014 03:49:09 -0000	1.4
+++ ChangeLog	15 Oct 2014 15:33:29 -0000	1.5
@@ -1,6 +1,12 @@
 # ChangeLog for sys-libs/libapparmor
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/libapparmor/ChangeLog,v 1.4 2014/07/14 03:49:09 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/libapparmor/ChangeLog,v 1.5 2014/10/15 15:33:29 kensington Exp $
+
+*libapparmor-2.8.4 (15 Oct 2014)
+
+  15 Oct 2014; Michael Palimaka <kensington@gentoo.org>
+  +libapparmor-2.8.4.ebuild, -libapparmor-2.8.2.ebuild:
+  Version bump. Remove old.
 
   14 Jul 2014; Patrick Lauer <patrick@gentoo.org> libapparmor-2.8.3.ebuild:
   Add ~x86 keyword



1.1                  sys-libs/libapparmor/libapparmor-2.8.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/libapparmor/libapparmor-2.8.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/libapparmor/libapparmor-2.8.4.ebuild?rev=1.1&content-type=text/plain

Index: libapparmor-2.8.4.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/libapparmor/libapparmor-2.8.4.ebuild,v 1.1 2014/10/15 15:33:29 kensington Exp $

EAPI=5

AUTOTOOLS_AUTORECONF=1
DISTUTILS_OPTIONAL=1
PYTHON_COMPAT=( python{2_7,3_3,3_4} )
GENTOO_DEPEND_ON_PERL="no"

inherit autotools-utils distutils-r1 perl-module versionator

DESCRIPTION="Library to support AppArmor userspace utilities"
HOMEPAGE="http://apparmor.net/"
SRC_URI="http://launchpad.net/apparmor/$(get_version_component_range 1-2)/${PV}/+download/apparmor-${PV}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc +perl python static-libs"

REQUIRED_USE="${PYTHON_REQUIRED_USE}"

RDEPEND="perl? ( dev-lang/perl:= )
	python? ( ${PYTHON_DEPS} )"

DEPEND="${RDEPEND}
	sys-devel/autoconf-archive
	sys-devel/bison
	sys-devel/flex
	doc? ( dev-lang/perl )
	perl? ( dev-lang/swig )
	python? ( dev-lang/swig	)"

S=${WORKDIR}/apparmor-${PV}/libraries/${PN}

src_prepare() {
	rm -r m4 || die "failed to remove bundled macros"

	autotools-utils_src_prepare
	use python && distutils-r1_src_prepare
}

src_configure() {
	local myeconfargs=(
		$(use_with perl) \
		$(use_with python)
	)

	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile -C src

	use doc && autotools-utils_src_compile -C doc
	use perl && autotools-utils_src_compile -C swig/perl

	if use python ; then
		pushd "${BUILD_DIR}"/swig/python > /dev/null
		emake libapparmor_wrap.c
		distutils-r1_src_compile
		popd > /dev/null
	fi
}

src_install() {
	autotools-utils_src_install -C src
	use doc && autotools-utils_src_install -C doc

	if use perl ; then
		autotools-utils_src_install -C swig/perl
		perlinfo
		insinto "${VENDOR_ARCH}"
		doins "${BUILD_DIR}"/swig/perl/LibAppArmor.pm
	fi

	if use python ; then
		pushd "${BUILD_DIR}"/swig/python > /dev/null
		distutils-r1_src_install
		popd > /dev/null
	fi
}