[gentoo-commits] gentoo-x86 commit in net-misc/youtube-dl: ChangeLog youtube-dl-2014.10.15.ebuild youtube-dl-2014.10.05.2.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/youtube-dl: ChangeLog youtube-dl-2014.10.15.ebuild youtube-dl-2014.10.05.2.ebuild

[Jeroen Roovers (jer)]

jer         14/10/15 12:28:18

  Modified:             ChangeLog
  Added:                youtube-dl-2014.10.15.ebuild
  Removed:              youtube-dl-2014.10.05.2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.402                net-misc/youtube-dl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/youtube-dl/ChangeLog?rev=1.402&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/youtube-dl/ChangeLog?rev=1.402&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/youtube-dl/ChangeLog?r1=1.401&r2=1.402

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/youtube-dl/ChangeLog,v
retrieving revision 1.401
retrieving revision 1.402
diff -u -r1.401 -r1.402
--- ChangeLog	13 Oct 2014 18:50:38 -0000	1.401
+++ ChangeLog	15 Oct 2014 12:28:18 -0000	1.402
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/youtube-dl
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/youtube-dl/ChangeLog,v 1.401 2014/10/13 18:50:38 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/youtube-dl/ChangeLog,v 1.402 2014/10/15 12:28:18 jer Exp $
+
+*youtube-dl-2014.10.15 (15 Oct 2014)
+
+  15 Oct 2014; Jeroen Roovers <jer@gentoo.org> -youtube-dl-2014.10.05.2.ebuild,
+  +youtube-dl-2014.10.15.ebuild:
+  Version bump.
 
 *youtube-dl-2014.10.13 (13 Oct 2014)
 



1.1                  net-misc/youtube-dl/youtube-dl-2014.10.15.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/youtube-dl/youtube-dl-2014.10.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/youtube-dl/youtube-dl-2014.10.15.ebuild?rev=1.1&content-type=text/plain

Index: youtube-dl-2014.10.15.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/youtube-dl/youtube-dl-2014.10.15.ebuild,v 1.1 2014/10/15 12:28:18 jer Exp $

EAPI=5

PYTHON_COMPAT=(python{2_6,2_7,3_3,3_4})
DISTUTILS_SINGLE_IMPL=true
inherit bash-completion-r1 distutils-r1 eutils

DESCRIPTION="Download videos from YouTube.com (and more sites...)"
HOMEPAGE="http://rg3.github.com/youtube-dl/"
SRC_URI="http://youtube-dl.org/downloads/${PV}/${P}.tar.gz"

LICENSE="public-domain"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
IUSE="offensive test"

DEPEND="
	dev-python/setuptools[${PYTHON_USEDEP}]
	test? ( dev-python/nose[coverage(+)] )
"

S="${WORKDIR}/${PN}"

src_prepare() {
	if ! use offensive; then
		sed -i -e "/__version__/s|'$|-gentoo_no_offensive_sites'|g" \
			youtube_dl/version.py || die
		local xxx=(
			anysex behindkink drtuber eporner extremetube fourtube goshgay
			hentaistigma hornbunny mofosex pornhd pornhub pornotube pornoxo
			redtube sunporno slutload spankwire thisav trutube tube8 vporn xbef
			xhamster xnxx xtube xvideos youjizz youporn
		)
		sed -i -e $( printf '/%s/d;' ${xxx[@]} ) youtube_dl/extractor/__init__.py || die
		rm $( printf 'youtube_dl/extractor/%s.py ' ${xxx[@]} ) \
			test/test_age_restriction.py || die
	fi
}

src_compile() {
	distutils-r1_src_compile
}

src_test() {
	emake test
}

src_install() {
	python_domodule youtube_dl
	dobin bin/${PN}
	dodoc README.txt
	doman ${PN}.1
	newbashcomp ${PN}.bash-completion ${PN}
	python_fix_shebang "${ED}"
}