* [gentoo-commits] gentoo-x86 commit in sys-auth/keystone: keystone-2014.1.3.ebuild keystone-2014.1.9999.ebuild ChangeLog keystone-2014.1.2.1.ebuild
@ 2014-10-11 22:07 Matt Thode (prometheanfire)
0 siblings, 0 replies; only message in thread
From: Matt Thode (prometheanfire) @ 2014-10-11 22:07 UTC (permalink / raw
To: gentoo-commits
prometheanfire 14/10/11 22:07:23
Modified: keystone-2014.1.9999.ebuild ChangeLog
Added: keystone-2014.1.3.ebuild
Removed: keystone-2014.1.2.1.ebuild
Log:
bup
(Portage version: 2.2.8-r2/cvs/Linux x86_64, signed Manifest commit with key 0x2471eb3e40ac5ac3)
Revision Changes Path
1.6 sys-auth/keystone/keystone-2014.1.9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/keystone/keystone-2014.1.9999.ebuild?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/keystone/keystone-2014.1.9999.ebuild?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/keystone/keystone-2014.1.9999.ebuild?r1=1.5&r2=1.6
Index: keystone-2014.1.9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/keystone/keystone-2014.1.9999.ebuild,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- keystone-2014.1.9999.ebuild 10 Aug 2014 20:21:57 -0000 1.5
+++ keystone-2014.1.9999.ebuild 11 Oct 2014 22:07:23 -0000 1.6
@@ -1,6 +1,6 @@
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/keystone/keystone-2014.1.9999.ebuild,v 1.5 2014/08/10 20:21:57 slyfox Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/keystone/keystone-2014.1.9999.ebuild,v 1.6 2014/10/11 22:07:23 prometheanfire Exp $
EAPI=5
@@ -29,13 +29,13 @@
dev-lang/python[sqlite]
>=dev-python/python-memcached-1.48[${PYTHON_USEDEP}]
>=dev-python/pymongo-2.4[${PYTHON_USEDEP}]
- ldap? ( ~dev-python/python-ldap-2.3.13 )
+ ldap? ( dev-python/python-ldap )
>=dev-python/coverage-3.6[${PYTHON_USEDEP}]
>=dev-python/fixtures-0.3.14[${PYTHON_USEDEP}]
>=dev-python/mock-1.0[${PYTHON_USEDEP}]
>=dev-python/mox-0.5.3[${PYTHON_USEDEP}]
>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
- <dev-python/sphinx-1.2[${PYTHON_USEDEP}]
+ <dev-python/sphinx-1.1.9999[${PYTHON_USEDEP}]
>=dev-python/webtest-2.0[${PYTHON_USEDEP}]
>=dev-python/subunit-0.0.18[${PYTHON_USEDEP}]
>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
@@ -56,6 +56,7 @@
>=dev-python/pastedeploy-1.5.0[${PYTHON_USEDEP}]
dev-python/paste[${PYTHON_USEDEP}]
>=dev-python/routes-1.12.3[${PYTHON_USEDEP}]
+ !~dev-python/routes-2.0[${PYTHON_USEDEP}]
>=dev-python/six-1.6.0[${PYTHON_USEDEP}]
sqlite? (
>=dev-python/sqlalchemy-0.8.0[sqlite,${PYTHON_USEDEP}]
@@ -75,6 +76,7 @@
<=dev-python/sqlalchemy-0.9.99[${PYTHON_USEDEP}]
)
>=dev-python/sqlalchemy-migrate-0.9[${PYTHON_USEDEP}]
+ !~dev-python/sqlalchemy-migrate-0.9.2[${PYTHON_USEDEP}]
dev-python/passlib[${PYTHON_USEDEP}]
>=dev-python/lxml-2.3[${PYTHON_USEDEP}]
>=dev-python/iso8601-0.1.9[${PYTHON_USEDEP}]
1.80 sys-auth/keystone/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/keystone/ChangeLog?rev=1.80&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/keystone/ChangeLog?rev=1.80&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/keystone/ChangeLog?r1=1.79&r2=1.80
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/keystone/ChangeLog,v
retrieving revision 1.79
retrieving revision 1.80
diff -u -r1.79 -r1.80
--- ChangeLog 19 Aug 2014 02:41:45 -0000 1.79
+++ ChangeLog 11 Oct 2014 22:07:23 -0000 1.80
@@ -1,6 +1,13 @@
# ChangeLog for sys-auth/keystone
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/keystone/ChangeLog,v 1.79 2014/08/19 02:41:45 prometheanfire Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/keystone/ChangeLog,v 1.80 2014/10/11 22:07:23 prometheanfire Exp $
+
+*keystone-2014.1.3 (11 Oct 2014)
+
+ 11 Oct 2014; Matthew Thode <prometheanfire@gentoo.org>
+ +keystone-2014.1.3.ebuild, -keystone-2014.1.2.1.ebuild,
+ keystone-2014.1.9999.ebuild:
+ bup
19 Aug 2014; Matthew Thode <prometheanfire@gentoo.org>
-keystone-2014.1.1-r2.ebuild:
1.1 sys-auth/keystone/keystone-2014.1.3.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/keystone/keystone-2014.1.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/keystone/keystone-2014.1.3.ebuild?rev=1.1&content-type=text/plain
Index: keystone-2014.1.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-auth/keystone/keystone-2014.1.3.ebuild,v 1.1 2014/10/11 22:07:23 prometheanfire Exp $
EAPI=5
PYTHON_COMPAT=( python2_7 )
inherit distutils-r1 user
DESCRIPTION="The Openstack authentication, authorization, and service catalog written in Python"
HOMEPAGE="https://launchpad.net/keystone"
#SRC_URI="http://launchpad.net/${PN}/icehouse/${PV}/+download/${P}.tar.gz"
SRC_URI="http://launchpad.net/${PN}/icehouse/${PV}/+download/${P}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+sqlite mysql postgres ldap test"
REQUIRED_USE="|| ( mysql postgres sqlite )"
#todo, seperate out rdepend via use flags
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
>=dev-python/pbr-0.6[${PYTHON_USEDEP}]
<dev-python/pbr-1.0[${PYTHON_USEDEP}]
test? ( ${RDEPEND}
>=dev-python/hacking-0.8[${PYTHON_USEDEP}]
<dev-python/hacking-0.9[${PYTHON_USEDEP}]
dev-lang/python[sqlite]
>=dev-python/python-memcached-1.48[${PYTHON_USEDEP}]
>=dev-python/pymongo-2.4[${PYTHON_USEDEP}]
ldap? ( dev-python/python-ldap )
>=dev-python/coverage-3.6[${PYTHON_USEDEP}]
>=dev-python/fixtures-0.3.14[${PYTHON_USEDEP}]
>=dev-python/mock-1.0[${PYTHON_USEDEP}]
>=dev-python/mox-0.5.3[${PYTHON_USEDEP}]
>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
<dev-python/sphinx-1.1.9999[${PYTHON_USEDEP}]
>=dev-python/webtest-2.0[${PYTHON_USEDEP}]
>=dev-python/subunit-0.0.18[${PYTHON_USEDEP}]
>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
>=dev-python/testtools-0.9.34[${PYTHON_USEDEP}]
>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
>=dev-python/httplib2-0.7.5[${PYTHON_USEDEP}]
>=dev-python/requests-1.1[${PYTHON_USEDEP}]
>=dev-python/keyring-2.1[${PYTHON_USEDEP}]
dev-python/oslo-sphinx[${PYTHON_USEDEP}]
>=dev-python/kombu-2.4.8[${PYTHON_USEDEP}]
>=dev-python/lockfile-0.8[${PYTHON_USEDEP}]
>=dev-python/stevedore-0.14[${PYTHON_USEDEP}]
)"
RDEPEND=">=dev-python/webob-1.2.3-r1[${PYTHON_USEDEP}]
>=dev-python/eventlet-0.13.0[${PYTHON_USEDEP}]
>=dev-python/greenlet-0.3.2[${PYTHON_USEDEP}]
>=dev-python/netaddr-0.7.6[${PYTHON_USEDEP}]
>=dev-python/pastedeploy-1.5.0[${PYTHON_USEDEP}]
dev-python/paste[${PYTHON_USEDEP}]
>=dev-python/routes-1.12.3[${PYTHON_USEDEP}]
!~dev-python/routes-2.0[${PYTHON_USEDEP}]
>=dev-python/six-1.6.0[${PYTHON_USEDEP}]
sqlite? (
>=dev-python/sqlalchemy-0.8.0[sqlite,${PYTHON_USEDEP}]
!~dev-python/sqlalchemy-0.9.5[sqlite,${PYTHON_USEDEP}]
<=dev-python/sqlalchemy-0.9.99[sqlite,${PYTHON_USEDEP}]
)
mysql? (
dev-python/mysql-python
>=dev-python/sqlalchemy-0.8.0[${PYTHON_USEDEP}]
!~dev-python/sqlalchemy-0.9.5[${PYTHON_USEDEP}]
<=dev-python/sqlalchemy-0.9.99[${PYTHON_USEDEP}]
)
postgres? (
dev-python/psycopg:2
>=dev-python/sqlalchemy-0.8.0[${PYTHON_USEDEP}]
!~dev-python/sqlalchemy-0.9.5[${PYTHON_USEDEP}]
<=dev-python/sqlalchemy-0.9.99[${PYTHON_USEDEP}]
)
>=dev-python/sqlalchemy-migrate-0.9[${PYTHON_USEDEP}]
!~dev-python/sqlalchemy-migrate-0.9.2[${PYTHON_USEDEP}]
dev-python/passlib[${PYTHON_USEDEP}]
>=dev-python/lxml-2.3[${PYTHON_USEDEP}]
>=dev-python/iso8601-0.1.9[${PYTHON_USEDEP}]
>=dev-python/python-keystoneclient-0.7.0[${PYTHON_USEDEP}]
>=dev-python/oslo-config-1.2.0[${PYTHON_USEDEP}]
>=dev-python/oslo-messaging-1.3.0[${PYTHON_USEDEP}]
>=dev-python/Babel-1.3[${PYTHON_USEDEP}]
>=dev-python/oauthlib-0.6.0[${PYTHON_USEDEP}]
>=dev-python/dogpile-cache-0.5.0[${PYTHON_USEDEP}]
>=dev-python/jsonschema-2.0.0[${PYTHON_USEDEP}]
<dev-python/jsonschema-3.0.0[${PYTHON_USEDEP}]
>=dev-python/pycadf-0.4.1[${PYTHON_USEDEP}]
ldap? ( dev-python/python-ldap[${PYTHON_USEDEP}] )"
PATCHES=(
)
pkg_setup() {
enewgroup keystone
enewuser keystone -1 -1 /var/lib/keystone keystone
}
python_prepare_all() {
# it's in git, but not in the tarball.....
mkdir -p ${PN}/tests/tmp/ || die
cp etc/keystone-paste.ini ${PN}/tests/tmp/ || die
distutils-r1_python_prepare_all
}
# Ignore (naughty) test_.py files & 1 test that connect to the network
#-I 'test_keystoneclient*' \
python_test() {
nosetests -I 'test_keystoneclient*' \
-e test_static_translated_string_is_Message \
-e test_get_token_id_error_handling \
-e test_provider_token_expiration_validation \
-e test_import --process-restartworker --process-timeout=60 || die "testsuite failed under python2.7"
}
python_install() {
distutils-r1_python_install
newconfd "${FILESDIR}/keystone.confd" keystone
newinitd "${FILESDIR}/keystone.initd" keystone
diropts -m 0750
keepdir /etc/keystone /var/log/keystone
insinto /etc/keystone
doins etc/keystone.conf.sample etc/logging.conf.sample
doins etc/default_catalog.templates etc/policy.json
doins etc/policy.v3cloudsample.json etc/keystone-paste.ini
fowners keystone:keystone /etc/keystone /var/log/keystone
}
pkg_postinst() {
elog "You might want to run:"
elog "emerge --config =${CATEGORY}/${PF}"
elog "if this is a new install."
elog "If you have not already configured your openssl installation"
elog "please do it by modifying /etc/ssl/openssl.cnf"
elog "BEFORE issuing the configuration command."
elog "Otherwise default values will be used."
}
pkg_config() {
if [ ! -d "${ROOT}"/etc/keystone/ssl ] ; then
einfo "Press ENTER to configure the keystone PKI, or Control-C to abort now..."
read
"${ROOT}"/usr/bin/keystone-manage pki_setup --keystone-user keystone --keystone-group keystone
else
einfo "keystone PKI certificates directory already present, skipping configuration"
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-10-11 22:07 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-10-11 22:07 [gentoo-commits] gentoo-x86 commit in sys-auth/keystone: keystone-2014.1.3.ebuild keystone-2014.1.9999.ebuild ChangeLog keystone-2014.1.2.1.ebuild Matt Thode (prometheanfire)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox