[gentoo-commits] gentoo-x86 commit in dev-util/scons: ChangeLog scons-2.3.4.ebuild

[gentoo-commits] gentoo-x86 commit in dev-util/scons: ChangeLog scons-2.3.4.ebuild

[Ian Delaney (idella4)]

idella4     14/10/11 16:10:05

  Modified:             ChangeLog
  Added:                scons-2.3.4.ebuild
  Log:
  edit Changelog to final changes
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.154                dev-util/scons/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/scons/ChangeLog?rev=1.154&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/scons/ChangeLog?rev=1.154&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/scons/ChangeLog?r1=1.153&r2=1.154

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/scons/ChangeLog,v
retrieving revision 1.153
retrieving revision 1.154
diff -u -r1.153 -r1.154
--- ChangeLog	11 Oct 2014 15:50:57 -0000	1.153
+++ ChangeLog	11 Oct 2014 16:10:05 -0000	1.154
@@ -1,9 +1,12 @@
 # ChangeLog for dev-util/scons
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/scons/ChangeLog,v 1.153 2014/10/11 15:50:57 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/scons/ChangeLog,v 1.154 2014/10/11 16:10:05 idella4 Exp $
 
-  11 Oct 2014; Ian Delaney <idella4@gentoo.org> scons-2.3.2.ebuild:
-  bump
+*scons-2.3.4 (11 Oct 2014)
+
+  11 Oct 2014; Ian Delaney <idella4@gentoo.org> +scons-2.3.4.ebuild,
+  scons-2.3.2.ebuild:
+  drop py2.4 add pypy, bump
 
 *scons-2.3.2 (09 Jul 2014)
 



1.1                  dev-util/scons/scons-2.3.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/scons/scons-2.3.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/scons/scons-2.3.4.ebuild?rev=1.1&content-type=text/plain

Index: scons-2.3.4.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/scons/scons-2.3.4.ebuild,v 1.1 2014/10/11 16:10:05 idella4 Exp $

EAPI=5
PYTHON_COMPAT=( python2_7 pypy )
PYTHON_REQ_USE="threads(+)"

inherit distutils-r1

DESCRIPTION="Extensible Python-based build utility"
HOMEPAGE="http://www.scons.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
	doc? ( http://www.scons.org/doc/${PV}/PDF/${PN}-user.pdf -> ${P}-user.pdf
	       http://www.scons.org/doc/${PV}/HTML/${PN}-user.html -> ${P}-user.html )"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="doc"

PATCHES=( "${FILESDIR}/${PN}-2.1.0-jython.patch" )

python_prepare_all() {
	# https://bugs.gentoo.org/show_bug.cgi?id=361061
	sed -i -e "s|/usr/local/bin:/opt/bin:/bin:/usr/bin|${EPREFIX}/usr/local/bin:${EPREFIX}/opt/bin:${EPREFIX}/bin:${EPREFIX}/usr/bin:/usr/local/bin:/opt/bin:/bin:/usr/bin|g" engine/SCons/Platform/posix.py || die
	# and make sure the build system doesn't "force" /usr/local/ :(
	sed -i -e "s/'darwin'/'NOWAYdarwinWAYNO'/" setup.py || die

	distutils-r1_python_prepare_all
}

python_install() {
	distutils-r1_python_install \
		--standard-lib \
		--no-version-script \
		--install-data "${EPREFIX}"/usr/share
}

python_install_all() {
	local DOCS=( {CHANGES,README,RELEASE}.txt )
	distutils-r1_python_install_all

	use doc && dodoc "${DISTDIR}"/${P}-user.{pdf,html}
}

src_install() {
	distutils-r1_src_install

	# Build system does not use build_scripts properly.
	# http://scons.tigris.org/issues/show_bug.cgi?id=2891
	python_replicate_script "${ED}"usr/bin/scons{,ign,-time}
}