From: "Thomas Beierlein (tomjbe)" <tomjbe@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] gentoo-x86 commit in media-radio/xastir: xastir-2.0.6.ebuild ChangeLog
Date: Sat, 27 Sep 2014 14:51:00 +0000 (UTC) [thread overview]
Message-ID: <20140927145100.650E466C8@oystercatcher.gentoo.org> (raw)
tomjbe 14/09/27 14:51:00
Modified: ChangeLog
Added: xastir-2.0.6.ebuild
Log:
Version bump
(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 0x762053D5)
Revision Changes Path
1.39 media-radio/xastir/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/xastir/ChangeLog?rev=1.39&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/xastir/ChangeLog?rev=1.39&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/xastir/ChangeLog?r1=1.38&r2=1.39
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-radio/xastir/ChangeLog,v
retrieving revision 1.38
retrieving revision 1.39
diff -u -r1.38 -r1.39
--- ChangeLog 27 Sep 2014 12:01:19 -0000 1.38
+++ ChangeLog 27 Sep 2014 14:51:00 -0000 1.39
@@ -1,6 +1,11 @@
# ChangeLog for media-radio/xastir
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-radio/xastir/ChangeLog,v 1.38 2014/09/27 12:01:19 tomjbe Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-radio/xastir/ChangeLog,v 1.39 2014/09/27 14:51:00 tomjbe Exp $
+
+*xastir-2.0.6 (27 Sep 2014)
+
+ 27 Sep 2014; Thomas Beierlein <tomjbe@gentoo.org> +xastir-2.0.6.ebuild:
+ Version bump
27 Sep 2014; Thomas Beierlein <tomjbe@gentoo.org> xastir-2.0.4.ebuild:
Fix search path for GraphicsMagick during econf
1.1 media-radio/xastir/xastir-2.0.6.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/xastir/xastir-2.0.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/xastir/xastir-2.0.6.ebuild?rev=1.1&content-type=text/plain
Index: xastir-2.0.6.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-radio/xastir/xastir-2.0.6.ebuild,v 1.1 2014/09/27 14:51:00 tomjbe Exp $
EAPI=5
inherit autotools eutils flag-o-matic toolchain-funcs
DESCRIPTION="X Amateur Station Tracking and Information Reporting"
HOMEPAGE="http://xastir.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="festival gdal geotiff graphicsmagick"
DEPEND=">=x11-libs/motif-2.3:0
x11-libs/libXt
x11-libs/libX11
x11-libs/libXpm
x11-apps/xfontsel
dev-libs/libpcre
net-misc/curl
sys-libs/db
sci-libs/shapelib
!graphicsmagick? ( media-gfx/imagemagick[-hdri,-q32] )
graphicsmagick? ( media-gfx/graphicsmagick[-q32] )
geotiff? ( sci-libs/proj
sci-libs/libgeotiff
media-libs/tiff )
gdal? ( sci-libs/gdal )
festival? ( app-accessibility/festival )"
RDEPEND="${DEPEND}"
src_prepare() {
# fix script location (bug #407185)
epatch "${FILESDIR}"/${PN}-2.0.4-scripts.diff
# fix __FORTIFY_SOURCE warning (bug #337365)
epatch "${FILESDIR}"/${PN}-2.0.4-fortify.diff
# do not use builtin shapelib if sci-libs/shapelib is not installed
# instead build without shapelib support (bug #430704)
epatch "${FILESDIR}"/${PN}-2.0.4-no-builtin-shapelib.diff
# do not filter duplicate flags (see bug 411095)
epatch "${FILESDIR}"/${PN}-2.0.0-dont-filter-flags.diff
eautoreconf
}
src_configure() {
# provide include path to GraphicsMagic for configure stage
use graphicsmagick && append-cflags -I/usr/include/GraphicsMagick
econf --with-pcre \
--with-shapelib \
--with-dbfawk \
--without-ax25 \
--without-gpsman \
$(use_with !graphicsmagick imagemagick) \
$(use_with graphicsmagick) \
$(use_with geotiff libproj) \
$(use_with geotiff) \
$(use_with gdal) \
$(use_with festival)
}
src_compile() {
emake AR="$(tc-getAR)"
}
src_install() {
emake DESTDIR="${D}" install
rm -rf "${D}"/usr/share/doc/${PN}
dodoc AUTHORS ChangeLog FAQ README README.Contributing \
README.Getting-Started README.MAPS
}
pkg_postinst() {
elog "Kernel mode AX.25 and GPSman library not supported."
elog
elog "Remember you have to be root to add addditional scripts,"
elog "maps and other configuration data under /usr/share/xastir."
}
next reply other threads:[~2014-09-27 14:51 UTC|newest]
Thread overview: 4+ messages / expand[flat|nested] mbox.gz Atom feed top
2014-09-27 14:51 Thomas Beierlein (tomjbe) [this message]
-- strict thread matches above, loose matches on Subject: below --
2015-02-21 17:42 [gentoo-commits] gentoo-x86 commit in media-radio/xastir: xastir-2.0.6.ebuild ChangeLog Thomas Beierlein (tomjbe)
2015-04-26 16:24 Pacho Ramos (pacho)
2015-06-27 17:47 Agostino Sarubbo (ago)
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20140927145100.650E466C8@oystercatcher.gentoo.org \
--to=tomjbe@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox