[gentoo-commits] gentoo-x86 commit in dev-libs/libgdata: libgdata-0.16.0.ebuild ChangeLog libgdata-0.14.1.ebuild

[gentoo-commits] gentoo-x86 commit in dev-libs/libgdata: libgdata-0.16.0.ebuild ChangeLog libgdata-0.14.1.ebuild

[Pacho Ramos (pacho)]

pacho       14/09/25 10:23:37

  Modified:             ChangeLog
  Added:                libgdata-0.16.0.ebuild
  Removed:              libgdata-0.14.1.ebuild
  Log:
  Version bump needed for updating compatibility with Google calendars (#516494)
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.78                 dev-libs/libgdata/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgdata/ChangeLog?rev=1.78&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgdata/ChangeLog?rev=1.78&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgdata/ChangeLog?r1=1.77&r2=1.78

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libgdata/ChangeLog,v
retrieving revision 1.77
retrieving revision 1.78
diff -u -r1.77 -r1.78
--- ChangeLog	23 Jul 2014 15:14:29 -0000	1.77
+++ ChangeLog	25 Sep 2014 10:23:37 -0000	1.78
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/libgdata
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/ChangeLog,v 1.77 2014/07/23 15:14:29 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/ChangeLog,v 1.78 2014/09/25 10:23:37 pacho Exp $
+
+*libgdata-0.16.0 (25 Sep 2014)
+
+  25 Sep 2014; Pacho Ramos <pacho@gentoo.org> +libgdata-0.16.0.ebuild,
+  -libgdata-0.14.1.ebuild:
+  Version bump needed for updating compatibility with Google calendars (#516494)
 
   23 Jul 2014; Agostino Sarubbo <ago@gentoo.org> libgdata-0.14.3.ebuild:
   Stable for x86, wrt bug #512012



1.1                  dev-libs/libgdata/libgdata-0.16.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgdata/libgdata-0.16.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgdata/libgdata-0.16.0.ebuild?rev=1.1&content-type=text/plain

Index: libgdata-0.16.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/libgdata-0.16.0.ebuild,v 1.1 2014/09/25 10:23:37 pacho Exp $

EAPI="5"
GCONF_DEBUG="yes"
VALA_MIN_API_VERSION="0.20"
VALA_USE_DEPEND="vapigen"

inherit gnome2 vala

DESCRIPTION="GLib-based library for accessing online service APIs using the GData protocol"
HOMEPAGE="https://wiki.gnome.org/Projects/libgdata"

LICENSE="LGPL-2.1+"
SLOT="0/19" # subslot = libgdata soname version
IUSE="gnome +introspection static-libs vala"
KEYWORDS=" ~amd64 ~x86"
REQUIRED_IUSE="vala? ( introspection )"

# gtk+ is needed for gdk
# configure checks for gtk:3, but only uses it for demos which are not installed
RDEPEND="
	>=dev-libs/glib-2.32:2
	>=dev-libs/json-glib-0.15
	>=dev-libs/libxml2-2:2
	>=net-libs/liboauth-0.9.4
	>=net-libs/libsoup-2.42.0:2.4[introspection?]
	net-libs/uhttpmock
	>=x11-libs/gdk-pixbuf-2.14:2
	gnome? (
		app-crypt/gcr:=
		>=net-libs/gnome-online-accounts-3.8 )
	introspection? ( >=dev-libs/gobject-introspection-0.9.7 )
"
DEPEND="${RDEPEND}
	>=dev-util/gtk-doc-am-1.14
	>=dev-util/intltool-0.40
	>=gnome-base/gnome-common-3.6
	virtual/pkgconfig
	vala? ( $(vala_depend) )
"

src_prepare() {
	# Disable tests requiring network access, bug #307725
	sed -e '/^TEST_PROGS = / s:\(.*\):TEST_PROGS = general perf calendar client-login-authorizer contacts documents oauth1-authorizer picasaweb youtube \nOLD_\1:' \
		-i gdata/tests/Makefile.in || die "network test disable failed"

	vala_src_prepare
	gnome2_src_prepare
}

src_configure() {
	DOCS="AUTHORS ChangeLog HACKING NEWS README"
	gnome2_src_configure \
		$(use_enable gnome) \
		$(use_enable gnome goa) \
		$(use_enable introspection) \
		$(use_enable vala) \
		$(use_enable static-libs static)
}

src_test() {
	unset ORBIT_SOCKETDIR
	unset DBUS_SESSION_BUS_ADDRESS
	export GSETTINGS_BACKEND="memory" #486412
	dbus-launch emake check
}