* [gentoo-commits] gentoo-x86 commit in media-video/smplayer: smplayer-14.9.0.ebuild ChangeLog
@ 2014-09-24 7:33 Ben de Groot (yngwin)
0 siblings, 0 replies; only message in thread
From: Ben de Groot (yngwin) @ 2014-09-24 7:33 UTC (permalink / raw
To: gentoo-commits
yngwin 14/09/24 07:33:47
Modified: ChangeLog
Added: smplayer-14.9.0.ebuild
Log:
version bump
(Portage version: 2.2.13/cvs/Linux x86_64, signed Manifest commit with key 0x0F9C590B7FF324F6!)
Revision Changes Path
1.145 media-video/smplayer/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/smplayer/ChangeLog?rev=1.145&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/smplayer/ChangeLog?rev=1.145&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/smplayer/ChangeLog?r1=1.144&r2=1.145
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/smplayer/ChangeLog,v
retrieving revision 1.144
retrieving revision 1.145
diff -u -r1.144 -r1.145
--- ChangeLog 28 Apr 2014 18:11:01 -0000 1.144
+++ ChangeLog 24 Sep 2014 07:33:47 -0000 1.145
@@ -1,6 +1,11 @@
# ChangeLog for media-video/smplayer
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/ChangeLog,v 1.144 2014/04/28 18:11:01 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/ChangeLog,v 1.145 2014/09/24 07:33:47 yngwin Exp $
+
+*smplayer-14.9.0 (24 Sep 2014)
+
+ 24 Sep 2014; Ben de Groot <yngwin@gentoo.org> +smplayer-14.9.0.ebuild:
+ version bump
28 Apr 2014; Fabian Groffen <grobian@gentoo.org> smplayer-14.3.0.ebuild:
Fix for Prefix, by Matthias Maier in bug #507724
1.1 media-video/smplayer/smplayer-14.9.0.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/smplayer/smplayer-14.9.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/smplayer/smplayer-14.9.0.ebuild?rev=1.1&content-type=text/plain
Index: smplayer-14.9.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/smplayer-14.9.0.ebuild,v 1.1 2014/09/24 07:33:47 yngwin Exp $
EAPI=5
PLOCALES="ar_SY bg ca cs da de el_GR en_US es et eu fi fr gl he_IL hr hu it ja
ka ko ku lt mk ms_MY nl pl pt pt_BR ro_RO ru_RU sk sl_SI sr sv th tr uk_UA vi_VN
zh_CN zh_TW"
PLOCALE_BACKUP="en_US"
inherit eutils l10n qt4-r2
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
DESCRIPTION="Great Qt4 GUI front-end for mplayer"
HOMEPAGE="http://smplayer.sourceforge.net/"
LICENSE="GPL-2 BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux"
IUSE="debug"
DEPEND="dev-qt/qtcore:4
dev-qt/qtgui:4"
COMMON_USE="libass,png,X"
RDEPEND="${DEPEND}
|| (
media-video/mplayer[bidi,${COMMON_USE}]
media-video/mplayer2[${COMMON_USE}]
)"
src_prepare() {
# Upstream Makefile sucks
sed -i -e "/^PREFIX=/s:${EPREFIX}/usr/local:${EPREFIX}/usr:" \
-e "/^DOC_PATH=/s:packages/smplayer:${PF}:" \
-e '/\.\/get_svn_revision\.sh/,+2c\
cd src && $(DEFS) $(MAKE)' \
"${S}"/Makefile || die "sed failed"
# Turn debug message flooding off
if ! use debug ; then
sed -i 's:#\(DEFINES += NO_DEBUG_ON_CONSOLE\):\1:' \
"${S}"/src/smplayer.pro || die "sed failed"
fi
# Turn off online update checker, bug #479902
sed -e 's:DEFINES += UPDATE_CHECKER:#DEFINES += UPDATE_CHECKER:' \
-e 's:DEFINES += CHECK_UPGRADED:#DEFINES += CHECK_UPGRADED:' \
-i "${S}"/src/smplayer.pro || die "sed failed"
# l10n_find_plocales_changes "${S}/src/translations" "${PN}_" '.ts'
}
src_configure() {
cd "${S}"/src
echo "#define SVN_REVISION \"SVN-${MY_PV} (Gentoo)\"" > svn_revision.h
eqmake4
}
gen_translation() {
ebegin "Generating $1 translation"
lrelease ${PN}_${1}.ts
eend $? || die "failed to generate $1 translation"
}
src_compile() {
emake
cd "${S}"/src/translations
l10n_for_each_locale_do gen_translation
}
src_install() {
# remove unneeded copies of licenses
rm Copying* docs/{cs,en,hu,it,ja,pt,ru,zh_CN}/gpl.html || die
rm -r docs/{de,es,fr,nl,ro} || die
emake DESTDIR="${D}" install
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-09-24 7:33 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-09-24 7:33 [gentoo-commits] gentoo-x86 commit in media-video/smplayer: smplayer-14.9.0.ebuild ChangeLog Ben de Groot (yngwin)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox