[gentoo-commits] gentoo-x86 commit in dev-games/tiled: tiled-0.10.1.ebuild ChangeLog tiled-0.9.0.ebuild

[gentoo-commits] gentoo-x86 commit in dev-games/tiled: tiled-0.10.1.ebuild ChangeLog tiled-0.9.0.ebuild

[Michael Palimaka (kensington)]

kensington    14/09/22 18:37:40

  Modified:             ChangeLog
  Added:                tiled-0.10.1.ebuild
  Removed:              tiled-0.9.0.ebuild
  Log:
  Version bump wrt bug #523464. Remove old.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

Revision  Changes    Path
1.7                  dev-games/tiled/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/tiled/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/tiled/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/tiled/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-games/tiled/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	10 Aug 2014 20:06:39 -0000	1.6
+++ ChangeLog	22 Sep 2014 18:37:40 -0000	1.7
@@ -1,6 +1,12 @@
 # ChangeLog for dev-games/tiled
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-games/tiled/ChangeLog,v 1.6 2014/08/10 20:06:39 slyfox Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-games/tiled/ChangeLog,v 1.7 2014/09/22 18:37:40 kensington Exp $
+
+*tiled-0.10.1 (22 Sep 2014)
+
+  22 Sep 2014; Michael Palimaka <kensington@gentoo.org> +tiled-0.10.1.ebuild,
+  -tiled-0.9.0.ebuild:
+  Version bump wrt bug #523464. Remove old.
 
   10 Aug 2014; Sergei Trofimovich <slyfox@gentoo.org> tiled-0.9.0.ebuild,
   tiled-0.9.1.ebuild:



1.1                  dev-games/tiled/tiled-0.10.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/tiled/tiled-0.10.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-games/tiled/tiled-0.10.1.ebuild?rev=1.1&content-type=text/plain

Index: tiled-0.10.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-games/tiled/tiled-0.10.1.ebuild,v 1.1 2014/09/22 18:37:40 kensington Exp $

EAPI=5

PLOCALES="cs de en es fr he it ja lv nl pt pt_BR ru zh zh_TW"
PYTHON_COMPAT=( python2_7 )
inherit multilib l10n python-single-r1 qt4-r2

DESCRIPTION="A general purpose tile map editor"
HOMEPAGE="http://www.mapeditor.org/"
SRC_URI="https://github.com/bjorn/tiled/archive/v${PV}/${P}.tar.gz"

LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="examples python"

REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

DEPEND=">=dev-qt/qtcore-4.7:4
	>=dev-qt/qtgui-4.7:4
	>=dev-qt/qtopengl-4.7:4
	sys-libs/zlib
	python? ( ${PYTHON_DEPS} )"
RDEPEND="${DEPEND}"

DOCS=( AUTHORS COPYING NEWS README.md )

pkg_setup() {
	use python && python-single-r1_pkg_setup
}

src_prepare() {
	rm -r src/zlib || die
	sed -e "s/^LANGUAGES =.*/LANGUAGES = $(l10n_get_locales)/" \
		-i translations/translations.pro || die
}

src_configure() {
	eqmake4 LIBDIR="/usr/$(get_libdir)" PREFIX="/usr" DISABLE_PYTHON_PLUGIN="$(usex !python)"
}

src_install() {
	qt4-r2_src_install

	if use examples ; then
		docompress -x /usr/share/doc/${PF}/examples
		dodoc -r examples
	fi
}