[gentoo-commits] gentoo-x86 commit in net-misc/lldpd: ChangeLog metadata.xml lldpd-0.7.10.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/lldpd: ChangeLog metadata.xml lldpd-0.7.10.ebuild

[Patrick McLean (chutzpah)]

chutzpah    14/09/22 18:09:19

  Modified:             ChangeLog metadata.xml
  Added:                lldpd-0.7.10.ebuild
  Log:
  Version bump, add json-c USE flag and rename json to jansson. Import bash and zsh completions from upstream git. Import some bugfix patches from upstream.
  
  (Portage version: 2.2.13/cvs/Linux x86_64, signed Manifest commit with key 0xE3F69979BB4B8928DA78E3D17CBF44EF)

Revision  Changes    Path
1.18                 net-misc/lldpd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/lldpd/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	8 Jul 2014 23:17:39 -0000	1.17
+++ ChangeLog	22 Sep 2014 18:09:19 -0000	1.18
@@ -1,6 +1,16 @@
 # ChangeLog for net-misc/lldpd
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/lldpd/ChangeLog,v 1.17 2014/07/08 23:17:39 chutzpah Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/lldpd/ChangeLog,v 1.18 2014/09/22 18:09:19 chutzpah Exp $
+
+*lldpd-0.7.10 (22 Sep 2014)
+
+  22 Sep 2014; Patrick McLean <chutzpah@gentoo.org> +lldpd-0.7.10.ebuild,
+  +files/lldpd-0.7.10-completions.patch,
+  +files/lldpd-0.7.10-handle-read-errors.patch,
+  +files/lldpd-0.7.10-only-use-physical-for-chassis-id.patch,
+  +files/lldpd-0.7.10-zsh-completion-dir.patch, metadata.xml:
+  Version bump, add json-c USE flag and rename json to jansson. Import bash and
+  zsh completions from upstream git. Import some bugfix patches from upstream.
 
 *lldpd-0.7.9-r3 (08 Jul 2014)
 



1.5                  net-misc/lldpd/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/lldpd/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	21 Feb 2014 18:47:02 -0000	1.4
+++ metadata.xml	22 Sep 2014 18:09:19 -0000	1.5
@@ -25,7 +25,9 @@
 		<flag name='dot3'>Enable Dot3 extension (PHY stuff)</flag>
 		<flag name='edp'>Enable Extreme Discovery Protocol</flag>
 		<flag name='fdp'>Enable Foundry Discovery Protocol</flag>
+		<flag name='jansson'>Enable JSON output via Jansson</flag>
 		<flag name='json'>Enable JSON output via Jansson</flag>
+		<flag name='json-c'>Enable JSON output via json-c</flag>
 		<flag name='lldpmed'>Enable LLDP-MED extension</flag>
 		<flag name='seccomp'>Enable use of libseccomp for system call filtering</flag>
 		<flag name='sonmp'>Enable SynOptics Network Management</flag>



1.1                  net-misc/lldpd/lldpd-0.7.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/lldpd-0.7.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/lldpd-0.7.10.ebuild?rev=1.1&content-type=text/plain

Index: lldpd-0.7.10.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/lldpd/lldpd-0.7.10.ebuild,v 1.1 2014/09/22 18:09:19 chutzpah Exp $

EAPI=5

inherit eutils user systemd bash-completion-r1

DESCRIPTION="Implementation of IEEE 802.1ab (LLDP)"
HOMEPAGE="http://vincentbernat.github.com/lldpd/"
SRC_URI="http://media.luffy.cx/files/${PN}/${P}.tar.gz"

LICENSE="ISC"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cdp doc +dot1 +dot3 edp fdp graph jansson json-c +lldpmed seccomp sonmp
	snmp static-libs readline xml zsh-completion"

RDEPEND=">=dev-libs/libevent-2.0.5
		snmp? ( net-analyzer/net-snmp[extensible(+)] )
		xml? ( dev-libs/libxml2 )
		jansson? ( dev-libs/jansson )
		json-c? ( dev-libs/json-c )
		seccomp? ( sys-libs/libseccomp )
		zsh-completion? ( app-shells/zsh )"
DEPEND="${RDEPEND}
		virtual/pkgconfig
		doc? (
			graph? ( app-doc/doxygen[dot] )
			!graph? ( app-doc/doxygen )
		)"

REQUIRED_USE="graph? ( doc ) json-c? ( !jansson )"

PATCHES=(
	"${FILESDIR}"/${P}-completions.patch
	"${FILESDIR}"/${P}-handle-read-errors.patch
	"${FILESDIR}"/${P}-only-use-physical-for-chassis-id.patch
	"${FILESDIR}"/${P}-zsh-completion-dir.patch
)

pkg_setup() {
	ebegin "Creating lldpd user and group"
	enewgroup ${PN}
	enewuser ${PN} -1 -1 -1 ${PN}
	eend $?
}

src_prepare() {
	epatch "${PATCHES[@]}"
	epatch_user
}

src_configure() {
	econf \
		--without-embedded-libevent \
		--with-privsep-user=${PN} \
		--with-privsep-group=${PN} \
		--with-privsep-chroot=/run/${PN} \
		--with-lldpd-ctl-socket=/run/${PN}.socket \
		--with-lldpd-pid-file=/run/${PN}.pid \
		--docdir=/usr/share/doc/${PF} \
		$(use_enable graph doxygen-dot) \
		$(use_enable doc doxygen-man) \
		$(use_enable doc doxygen-pdf) \
		$(use_enable doc doxygen-html) \
		$(use_enable cdp) \
		$(use_enable dot1) \
		$(use_enable dot3) \
		$(use_enable edp) \
		$(use_enable fdp) \
		$(use_enable lldpmed) \
		$(use_enable sonmp) \
		$(use_enable static-libs static) \
		$(use_with json-c) \
		$(use_with jansson) \
		$(use_with readline) \
		$(use_with seccomp) \
		$(use_with snmp) \
		$(use_with xml)
}

src_compile() {
	emake
	use doc && emake doxygen-doc
}

src_install() {
	emake DESTDIR="${D}" install
	prune_libtool_files

	newinitd "${FILESDIR}"/${PN}-initd-3 ${PN}
	newconfd "${FILESDIR}"/${PN}-confd-1 ${PN}
	newbashcomp src/client/lldpcli.bash-completion lldpcli

	if use zsh-completion; then
		insinto /usr/share/zsh/site-functions
		doins src/client/_lldpcli
	fi

	use doc && dohtml -r doxygen/html/*

	keepdir /etc/${PN}.d

	systemd_dounit "${FILESDIR}"/${PN}.service
}