[gentoo-commits] gentoo-x86 commit in x11-libs/qscintilla: qscintilla-2.8.4-r1.ebuild ChangeLog qscintilla-2.8.4.ebuild

[gentoo-commits] gentoo-x86 commit in x11-libs/qscintilla: qscintilla-2.8.4-r1.ebuild ChangeLog qscintilla-2.8.4.ebuild

[Davide Pesavento (pesa)]

pesa        14/09/21 13:39:23

  Modified:             ChangeLog
  Added:                qscintilla-2.8.4-r1.ebuild
  Removed:              qscintilla-2.8.4.ebuild
  Log:
  More complete fix for bug #466120. Thanks to Arfrever in comment #6.
  
  (Portage version: 2.2.13/cvs/Linux x86_64, signed Manifest commit with key 0xDADED6B2671CB57D!)

Revision  Changes    Path
1.103                x11-libs/qscintilla/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/ChangeLog?rev=1.103&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/ChangeLog?rev=1.103&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/ChangeLog?r1=1.102&r2=1.103

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/ChangeLog,v
retrieving revision 1.102
retrieving revision 1.103
diff -u -r1.102 -r1.103
--- ChangeLog	13 Sep 2014 01:07:02 -0000	1.102
+++ ChangeLog	21 Sep 2014 13:39:23 -0000	1.103
@@ -1,6 +1,12 @@
 # ChangeLog for x11-libs/qscintilla
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/ChangeLog,v 1.102 2014/09/13 01:07:02 pesa Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/ChangeLog,v 1.103 2014/09/21 13:39:23 pesa Exp $
+
+*qscintilla-2.8.4-r1 (21 Sep 2014)
+
+  21 Sep 2014; Davide Pesavento <pesa@gentoo.org> +qscintilla-2.8.4-r1.ebuild,
+  -files/qscintilla-2.8.4-designer.patch, -qscintilla-2.8.4.ebuild:
+  More complete fix for bug #466120. Thanks to Arfrever in comment #6.
 
 *qscintilla-2.8.4 (13 Sep 2014)
 



1.1                  x11-libs/qscintilla/qscintilla-2.8.4-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/qscintilla-2.8.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/qscintilla-2.8.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: qscintilla-2.8.4-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/qscintilla-2.8.4-r1.ebuild,v 1.1 2014/09/21 13:39:23 pesa Exp $

EAPI=5

inherit flag-o-matic qmake-utils

MY_P=QScintilla-gpl-${PV}

DESCRIPTION="A Qt port of Neil Hodgson's Scintilla C++ editor class"
HOMEPAGE="http://www.riverbankcomputing.co.uk/software/qscintilla/intro"
SRC_URI="mirror://sourceforge/pyqt/${MY_P}.tar.gz"

LICENSE="|| ( GPL-2 GPL-3 )"
SLOT="0/11"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="designer doc"

DEPEND="
	>=dev-qt/qtcore-4.8.5:4
	>=dev-qt/qtgui-4.8.5:4
	designer? ( >=dev-qt/designer-4.8.5:4 )
"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${MY_P}

src_unpack() {
	default

	# Sub-slot sanity check
	local subslot=${SLOT#*/}
	local version=$(sed -nre 's:.*VERSION\s*=\s*([0-9\.]+):\1:p' "${S}"/Qt4Qt5/qscintilla.pro)
	local major=${version%%.*}
	if [[ ${subslot} != ${major} ]]; then
		eerror
		eerror "Ebuild sub-slot (${subslot}) does not match QScintilla major version (${major})"
		eerror "Please update SLOT variable as follows:"
		eerror "    SLOT=\"${SLOT%%/*}/${major}\""
		eerror
		die "sub-slot sanity check failed"
	fi
}

src_configure() {
	pushd Qt4Qt5 > /dev/null
	eqmake4
	popd > /dev/null

	if use designer; then
		# prevent building against system version (bug 466120)
		append-cxxflags -I../Qt4Qt5
		append-ldflags -L../Qt4Qt5

		pushd designer-Qt4Qt5 > /dev/null
		eqmake4
		popd > /dev/null
	fi
}

src_compile() {
	pushd Qt4Qt5 > /dev/null
	emake
	popd > /dev/null

	if use designer; then
		pushd designer-Qt4Qt5 > /dev/null
		emake
		popd > /dev/null
	fi
}

src_install() {
	pushd Qt4Qt5 > /dev/null
	emake INSTALL_ROOT="${D}" install
	popd > /dev/null

	if use designer; then
		pushd designer-Qt4Qt5 > /dev/null
		emake INSTALL_ROOT="${D}" install
		popd > /dev/null
	fi

	dodoc NEWS

	if use doc; then
		docinto html
		dodoc -r doc/html-Qt4Qt5/*
	fi
}