[gentoo-commits] gentoo-x86 commit in dev-libs/libgweather: libgweather-3.12.2-r1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-libs/libgweather: libgweather-3.12.2-r1.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       14/09/21 10:25:35

  Modified:             ChangeLog
  Added:                libgweather-3.12.2-r1.ebuild
  Log:
  Update api for Yr.no (#522718 by poncho and Evgeny Bobkin)
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.113                dev-libs/libgweather/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgweather/ChangeLog?rev=1.113&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgweather/ChangeLog?rev=1.113&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgweather/ChangeLog?r1=1.112&r2=1.113

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libgweather/ChangeLog,v
retrieving revision 1.112
retrieving revision 1.113
diff -u -r1.112 -r1.113
--- ChangeLog	2 Aug 2014 09:58:54 -0000	1.112
+++ ChangeLog	21 Sep 2014 10:25:35 -0000	1.113
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/libgweather
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgweather/ChangeLog,v 1.112 2014/08/02 09:58:54 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgweather/ChangeLog,v 1.113 2014/09/21 10:25:35 pacho Exp $
+
+*libgweather-3.12.2-r1 (21 Sep 2014)
+
+  21 Sep 2014; Pacho Ramos <pacho@gentoo.org>
+  +files/libgweather-3.12.2-yr_no-api.patch, +libgweather-3.12.2-r1.ebuild:
+  Update api for Yr.no (#522718 by poncho and Evgeny Bobkin)
 
   02 Aug 2014; Pacho Ramos <pacho@gentoo.org> -libgweather-3.12.1.ebuild,
   libgweather-3.10.2.ebuild, libgweather-3.12.2.ebuild:



1.1                  dev-libs/libgweather/libgweather-3.12.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgweather/libgweather-3.12.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgweather/libgweather-3.12.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: libgweather-3.12.2-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgweather/libgweather-3.12.2-r1.ebuild,v 1.1 2014/09/21 10:25:35 pacho Exp $

EAPI="5"
GCONF_DEBUG="no"
VALA_MIN_API_VERSION="0.18"
VALA_USE_DEPEND="vapigen"

inherit eutils gnome2 vala

DESCRIPTION="Library to access weather information from online services"
HOMEPAGE="https://wiki.gnome.org/Projects/LibGWeather"

LICENSE="GPL-2+"
SLOT="2/3-6" # subslot = 3-(libgweather-3 soname suffix)
IUSE="glade +introspection vala"
REQUIRED_USE="vala? ( introspection )"

KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"

COMMON_DEPEND="
	>=x11-libs/gtk+-3.5.6:3[introspection?]
	>=dev-libs/glib-2.35.1:2
	>=net-libs/libsoup-2.34:2.4
	>=dev-libs/libxml2-2.6.0
	>=sys-libs/timezone-data-2010k

	glade? ( >=dev-util/glade-3.16:3.10 )
	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
"
RDEPEND="${COMMON_DEPEND}
	!<gnome-base/gnome-applets-2.22.0
"
DEPEND="${COMMON_DEPEND}
	>=dev-util/gtk-doc-am-1.11
	>=dev-util/intltool-0.50
	>=sys-devel/gettext-0.18
	virtual/pkgconfig
	vala? ( $(vala_depend) )
"

src_prepare() {
	# Yr.no: update to version 1.9 of the online API (from 3.12 branch)
	epatch "${FILESDIR}"/${P}-yr_no-api.patch

	use vala && vala_src_prepare
	gnome2_src_prepare
}

src_configure() {
	DOCS="AUTHORS ChangeLog MAINTAINERS NEWS"
	gnome2_src_configure \
		--disable-static \
		$(use_enable glade glade-catalog) \
		$(use_enable introspection) \
		$(use_enable vala)
}