[gentoo-commits] gentoo-x86 commit in kde-base/qtruby: ChangeLog qtruby-4.14.1.ebuild

[gentoo-commits] gentoo-x86 commit in kde-base/qtruby: ChangeLog qtruby-4.14.1.ebuild

[Johannes Huber (johu)]

johu        14/09/16 18:17:30

  Modified:             ChangeLog
  Added:                qtruby-4.14.1.ebuild
  Log:
  Version bump KDE SC 4.14.1
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

Revision  Changes    Path
1.220                kde-base/qtruby/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/qtruby/ChangeLog?rev=1.220&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/qtruby/ChangeLog?rev=1.220&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/qtruby/ChangeLog?r1=1.219&r2=1.220

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/qtruby/ChangeLog,v
retrieving revision 1.219
retrieving revision 1.220
diff -u -r1.219 -r1.220
--- ChangeLog	20 Aug 2014 16:02:47 -0000	1.219
+++ ChangeLog	16 Sep 2014 18:17:30 -0000	1.220
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/qtruby
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/qtruby/ChangeLog,v 1.219 2014/08/20 16:02:47 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/qtruby/ChangeLog,v 1.220 2014/09/16 18:17:30 johu Exp $
+
+*qtruby-4.14.1 (16 Sep 2014)
+
+  16 Sep 2014; Johannes Huber <johu@gentoo.org> +qtruby-4.14.1.ebuild:
+  Version bump KDE SC 4.14.1
 
 *qtruby-4.14.0 (20 Aug 2014)
 



1.1                  kde-base/qtruby/qtruby-4.14.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/qtruby/qtruby-4.14.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/qtruby/qtruby-4.14.1.ebuild?rev=1.1&content-type=text/plain

Index: qtruby-4.14.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/qtruby/qtruby-4.14.1.ebuild,v 1.1 2014/09/16 18:17:30 johu Exp $

EAPI=5

OPENGL_REQUIRED="always"
DECLARATIVE_REQUIRED="optional"
KDE_REQUIRED="never"
USE_RUBY="ruby19"
# Only one ruby version is supported:
# 1) cmake bails when configuring twice or more - solved with CMAKE_IN_SOURCE_BUILD=1
# 2) the ebuild can only be installed for one ruby variant, otherwise the compiled
#    files with identical path+name will overwrite each other - difficult :(

inherit kde4-base ruby-ng

DESCRIPTION="Qt Ruby bindings"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug phonon qscintilla qwt webkit"
HOMEPAGE="http://techbase.kde.org/Development/Languages/Ruby"

DEPEND="
	$(add_kdebase_dep smokeqt 'declarative?,opengl,phonon?,qscintilla?,qwt?,webkit?')
"

RDEPEND="${DEPEND}
"

pkg_setup() {
	ruby-ng_pkg_setup
	kde4-base_pkg_setup
}

src_unpack() {
	local S="${WORKDIR}/${P}"
	kde4-base_src_unpack

	cd "${WORKDIR}"
	mkdir all
	mv ${P} all/ || die "Could not move sources"
}

all_ruby_prepare() {
	kde4-base_src_prepare
}

each_ruby_configure() {
	local CMAKE_USE_DIR=${S}
	local mycmakeargs=(
		-DRUBY_LIBRARY=$(ruby_get_libruby)
		-DRUBY_INCLUDE_PATH=$(ruby_get_hdrdir)
		-DRUBY_EXECUTABLE=${RUBY}
		$(cmake-utils_use_disable declarative QtDeclarative)
		$(cmake-utils_use_with phonon)
		$(cmake-utils_use_with qscintilla QScintilla)
		$(cmake-utils_use_with qwt Qwt5)
		$(cmake-utils_use_disable webkit QtWebKit)
	)
	kde4-base_src_configure
}

each_ruby_compile() {
	local CMAKE_USE_DIR=${S}
	kde4-base_src_compile
}

each_ruby_install() {
	local CMAKE_USE_DIR=${S}
	kde4-base_src_install
}