[gentoo-commits] gentoo-x86 commit in dev-python/celery: celery-3.1.14.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-python/celery: celery-3.1.14.ebuild ChangeLog

[Michael Weber (xmw)]

xmw         14/09/14 16:07:34

  Modified:             ChangeLog
  Added:                celery-3.1.14.ebuild
  Log:
  Version bump (non-maint commit)
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 62EEF090)

Revision  Changes    Path
1.41                 dev-python/celery/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/celery/ChangeLog?rev=1.41&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/celery/ChangeLog?rev=1.41&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/celery/ChangeLog?r1=1.40&r2=1.41

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/celery/ChangeLog,v
retrieving revision 1.40
retrieving revision 1.41
diff -u -r1.40 -r1.41
--- ChangeLog	10 Aug 2014 21:07:56 -0000	1.40
+++ ChangeLog	14 Sep 2014 16:07:34 -0000	1.41
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/celery
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/celery/ChangeLog,v 1.40 2014/08/10 21:07:56 slyfox Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/celery/ChangeLog,v 1.41 2014/09/14 16:07:34 xmw Exp $
+
+*celery-3.1.14 (14 Sep 2014)
+
+  14 Sep 2014; Michael Weber <xmw@gentoo.org> +celery-3.1.14.ebuild:
+  Version bump (non-maint commit)
 
   10 Aug 2014; Sergei Trofimovich <slyfox@gentoo.org> celery-3.1.11.ebuild,
   celery-3.1.12.ebuild, celery-3.1.13.ebuild:



1.1                  dev-python/celery/celery-3.1.14.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/celery/celery-3.1.14.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/celery/celery-3.1.14.ebuild?rev=1.1&content-type=text/plain

Index: celery-3.1.14.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/celery/celery-3.1.14.ebuild,v 1.1 2014/09/14 16:07:34 xmw Exp $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_3,3_4} )

inherit distutils-r1

DESCRIPTION="Celery is an open source asynchronous task queue/job queue based on distributed message passing"
HOMEPAGE="http://celeryproject.org/ http://pypi.python.org/pypi/celery"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples redis test"

PY2_USEDEP=$(python_gen_usedep python2_7)
RDEPEND="<dev-python/kombu-3.1[${PYTHON_USEDEP}]
		>=dev-python/kombu-3.0.21[${PYTHON_USEDEP}]
		>=dev-python/python-dateutil-1.5[${PYTHON_USEDEP}]
		>=dev-python/anyjson-0.3.3[${PYTHON_USEDEP}]
		dev-python/pyparsing[${PYTHON_USEDEP}]
		>=dev-python/billiard-3.3.0.18[${PYTHON_USEDEP}]
		<dev-python/billiard-3.4[${PYTHON_USEDEP}]
		dev-python/pytz[${PYTHON_USEDEP}]
		dev-python/greenlet[${PYTHON_USEDEP}]"

DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
	test? ( ${RDEPEND}
		dev-python/gevent[${PY2_USEDEP}]
		>=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
		dev-python/pyopenssl[${PYTHON_USEDEP}]
		dev-python/nose-cover3[${PYTHON_USEDEP}]
		dev-python/sqlalchemy[${PYTHON_USEDEP}]
		dev-python/pymongo[${PYTHON_USEDEP}]
		redis? ( dev-python/redis-py[${PYTHON_USEDEP}]
			>=dev-db/redis-2.8.0 )
	)
	doc? (
		dev-python/docutils[${PYTHON_USEDEP}]
		dev-python/sphinx[${PYTHON_USEDEP}]
		dev-python/jinja[${PYTHON_USEDEP}]
		dev-python/sqlalchemy[${PYTHON_USEDEP}] )"

PATCHES=( "${FILESDIR}"/celery-docs.patch
		"${FILESDIR}"/${PN}-3.1.11-test.patch )
# testsuite needs it own source
DISTUTILS_IN_SOURCE_BUILD=1

python_compile_all() {
	if use doc; then
		mkdir docs/.build || die
		emake -C docs html
	fi
}

python_test() {
	nosetests || die "Tests failed with ${EPYTHON}"
}

python_install_all() {
	# Main celeryd init.d and conf.d
	newinitd "${FILESDIR}/celery.initd-r1" celery
	newconfd "${FILESDIR}/celery.confd-r1" celery

	use examples && local EXAMPLES=( examples/. )

	use doc && local HTML_DOCS=( docs/.build/html/. )

	distutils-r1_python_install_all
}