[gentoo-commits] gentoo-x86 commit in sys-apps/findutils: findutils-4.5.14-r1.ebuild findutils-4.4.2-r2.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in sys-apps/findutils: findutils-4.5.14-r1.ebuild findutils-4.4.2-r2.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      14/09/08 23:14:34

  Modified:             ChangeLog
  Added:                findutils-4.5.14-r1.ebuild
                        findutils-4.4.2-r2.ebuild
  Log:
  Add USE=debug and sync the 4.4.x and 4.5.x versions.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.225                sys-apps/findutils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/findutils/ChangeLog?rev=1.225&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/findutils/ChangeLog?rev=1.225&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/findutils/ChangeLog?r1=1.224&r2=1.225

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/findutils/ChangeLog,v
retrieving revision 1.224
retrieving revision 1.225
diff -u -r1.224 -r1.225
--- ChangeLog	1 Aug 2014 23:02:32 -0000	1.224
+++ ChangeLog	8 Sep 2014 23:14:34 -0000	1.225
@@ -1,6 +1,13 @@
 # ChangeLog for sys-apps/findutils
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/findutils/ChangeLog,v 1.224 2014/08/01 23:02:32 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/findutils/ChangeLog,v 1.225 2014/09/08 23:14:34 vapier Exp $
+
+*findutils-4.4.2-r2 (08 Sep 2014)
+*findutils-4.5.14-r1 (08 Sep 2014)
+
+  08 Sep 2014; Mike Frysinger <vapier@gentoo.org> +findutils-4.4.2-r2.ebuild,
+  +findutils-4.5.14-r1.ebuild:
+  Add USE=debug and sync the 4.4.x and 4.5.x versions.
 
 *findutils-4.5.14 (01 Aug 2014)
 



1.1                  sys-apps/findutils/findutils-4.5.14-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/findutils/findutils-4.5.14-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/findutils/findutils-4.5.14-r1.ebuild?rev=1.1&content-type=text/plain

Index: findutils-4.5.14-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/findutils/findutils-4.5.14-r1.ebuild,v 1.1 2014/09/08 23:14:34 vapier Exp $

EAPI="4"

inherit eutils flag-o-matic toolchain-funcs

DESCRIPTION="GNU utilities for finding files"
HOMEPAGE="http://www.gnu.org/software/findutils/"
SRC_URI="mirror://gnu-alpha/${PN}/${P}.tar.gz"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="debug nls selinux static"

RDEPEND="selinux? ( sys-libs/libselinux )
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

src_prepare() {
	# Don't build or install locate because it conflicts with slocate,
	# which is a secure version of locate.  See bug 18729
	sed -i '/^SUBDIRS/s/locate//' Makefile.in
}

src_configure() {
	use static && append-ldflags -static

	program_prefix=$(usex userland_GNU '' g)
	econf \
		--with-packager="Gentoo" \
		--with-packager-version="${PVR}" \
		--with-packager-bug-reports="http://bugs.gentoo.org/" \
		--program-prefix=${program_prefix} \
		$(use_enable debug) \
		$(use_enable nls) \
		$(use_with selinux) \
		--libexecdir='$(libdir)'/find
}

src_install() {
	default

	# We don't need this, so punt it.
	rm "${ED}"/usr/bin/${program_prefix}oldfind \
		"${ED}"/usr/share/man/man1/${program_prefix}oldfind.1 || die
}



1.1                  sys-apps/findutils/findutils-4.4.2-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/findutils/findutils-4.4.2-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/findutils/findutils-4.4.2-r2.ebuild?rev=1.1&content-type=text/plain

Index: findutils-4.4.2-r2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/findutils/findutils-4.4.2-r2.ebuild,v 1.1 2014/09/08 23:14:34 vapier Exp $

EAPI="4"

inherit eutils flag-o-matic toolchain-funcs

SELINUX_PATCH="findutils-4.4.2-selinux.diff"

DESCRIPTION="GNU utilities for finding files"
HOMEPAGE="http://www.gnu.org/software/findutils/"
SRC_URI="mirror://gnu-alpha/${PN}/${P}.tar.gz
	mirror://gnu/${PN}/${P}.tar.gz"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="debug nls selinux static"

RDEPEND="selinux? ( sys-libs/libselinux )
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

src_prepare() {
	epatch "${FILESDIR}"/${P}-gnulib-date-x32.patch

	# Don't build or install locate because it conflicts with slocate,
	# which is a secure version of locate.  See bug 18729
	sed -i '/^SUBDIRS/s/locate//' Makefile.in

	use selinux && epatch "${FILESDIR}/${SELINUX_PATCH}"
}

src_configure() {
	use static && append-ldflags -static

	program_prefix=$(usex userland_GNU '' g)
	econf \
		--program-prefix=${program_prefix} \
		$(use_enable debug) \
		$(use_enable nls) \
		--libexecdir='$(libdir)'/find
}

src_compile() {
	emake AR="$(tc-getAR)"
}

src_install() {
	default

	# We don't need this, so punt it.
	rm "${ED}"/usr/bin/${program_prefix}oldfind || die
}