* [gentoo-commits] gentoo-x86 commit in x11-libs/libfm: libfm-9999.ebuild libfm-1.2.2.1.ebuild ChangeLog
@ 2014-09-06 8:41 Markos Chandras (hwoarang)
0 siblings, 0 replies; only message in thread
From: Markos Chandras (hwoarang) @ 2014-09-06 8:41 UTC (permalink / raw
To: gentoo-commits
hwoarang 14/09/06 08:41:06
Modified: libfm-9999.ebuild ChangeLog
Added: libfm-1.2.2.1.ebuild
Log:
Version bump. Bug #518134
(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 09BF4F54C2BA7F3C!)
Revision Changes Path
1.41 x11-libs/libfm/libfm-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libfm/libfm-9999.ebuild?rev=1.41&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libfm/libfm-9999.ebuild?rev=1.41&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libfm/libfm-9999.ebuild?r1=1.40&r2=1.41
Index: libfm-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/libfm/libfm-9999.ebuild,v
retrieving revision 1.40
retrieving revision 1.41
diff -u -r1.40 -r1.41
--- libfm-9999.ebuild 16 Mar 2014 10:32:42 -0000 1.40
+++ libfm-9999.ebuild 6 Sep 2014 08:41:06 -0000 1.41
@@ -1,6 +1,6 @@
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libfm/libfm-9999.ebuild,v 1.40 2014/03/16 10:32:42 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libfm/libfm-9999.ebuild,v 1.41 2014/09/06 08:41:06 hwoarang Exp $
EAPI=5
@@ -13,8 +13,8 @@
HOMEPAGE="http://pcmanfm.sourceforge.net/"
LICENSE="GPL-2"
-SLOT="0/4.0.0" #copy ABI_VERSION because it seems upstream change it randomly
-IUSE="+automount debug doc examples udisks vala"
+SLOT="0/4.2.0" #copy ABI_VERSION because it seems upstream change it randomly
+IUSE="+automount debug doc examples exif udisks vala"
KEYWORDS=""
COMMON_DEPEND=">=dev-libs/glib-2.18:2
@@ -29,7 +29,8 @@
gnome-base/gvfs[udev,gdu]
) )
!udisks? ( gnome-base/gvfs[udev] )
- )"
+ )
+ exif? ( media-libs/libexif )"
DEPEND="${COMMON_DEPEND}
vala? ( $(vala_depend) )
doc? (
@@ -85,6 +86,7 @@
--disable-dependency-tracking \
--disable-static \
$(use_enable examples demo) \
+ $(use_enable exif) \
$(use_enable debug) \
$(use_enable udisks) \
$(use_enable vala actions) \
1.101 x11-libs/libfm/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libfm/ChangeLog?rev=1.101&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libfm/ChangeLog?rev=1.101&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libfm/ChangeLog?r1=1.100&r2=1.101
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/libfm/ChangeLog,v
retrieving revision 1.100
retrieving revision 1.101
diff -u -r1.100 -r1.101
--- ChangeLog 16 Mar 2014 10:32:42 -0000 1.100
+++ ChangeLog 6 Sep 2014 08:41:06 -0000 1.101
@@ -1,6 +1,12 @@
# ChangeLog for x11-libs/libfm
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libfm/ChangeLog,v 1.100 2014/03/16 10:32:42 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libfm/ChangeLog,v 1.101 2014/09/06 08:41:06 hwoarang Exp $
+
+*libfm-1.2.2.1 (06 Sep 2014)
+
+ 06 Sep 2014; Markos Chandras <hwoarang@gentoo.org> +libfm-1.2.2.1.ebuild,
+ libfm-9999.ebuild:
+ Version bump. Bug #518134
16 Mar 2014; Markos Chandras <hwoarang@gentoo.org> libfm-1.2.0.ebuild,
libfm-9999.ebuild:
1.1 x11-libs/libfm/libfm-1.2.2.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libfm/libfm-1.2.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libfm/libfm-1.2.2.1.ebuild?rev=1.1&content-type=text/plain
Index: libfm-1.2.2.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/libfm/libfm-1.2.2.1.ebuild,v 1.1 2014/09/06 08:41:06 hwoarang Exp $
EAPI=5
inherit autotools fdo-mime vala
MY_PV=${PV/_/}
MY_P="${PN}-${MY_PV}"
DESCRIPTION="A library for file management"
HOMEPAGE="http://pcmanfm.sourceforge.net/"
SRC_URI="http://dev.gentoo.org/~hwoarang/distfiles/${MY_P}.tar.xz"
KEYWORDS="~alpha ~amd64 ~arm ~mips ~ppc ~x86 ~amd64-linux ~x86-linux"
LICENSE="GPL-2"
SLOT="0/4.2.0" #copy ABI_VERSION because it seems upstream change it randomly
IUSE="+automount debug doc examples exif udisks vala"
COMMON_DEPEND=">=dev-libs/glib-2.18:2
>=x11-libs/gtk+-2.16:2
>=lxde-base/menu-cache-0.3.2:="
RDEPEND="${COMMON_DEPEND}
!lxde-base/lxshortcut
x11-misc/shared-mime-info
automount? (
udisks? ( || (
gnome-base/gvfs[udev,udisks]
gnome-base/gvfs[udev,gdu]
) )
!udisks? ( gnome-base/gvfs[udev] )
)
exif? ( media-libs/libexif )"
DEPEND="${COMMON_DEPEND}
vala? ( $(vala_depend) )
doc? (
dev-util/gtk-doc
)
app-arch/xz-utils
>=dev-util/intltool-0.40
virtual/pkgconfig
sys-devel/gettext"
S="${WORKDIR}"/${MY_P}
REQUIRED_USE="udisks? ( automount )"
src_prepare() {
if ! use doc; then
sed -ie '/^SUBDIR.*=/s#docs##' "${S}"/Makefile.am || die "sed failed"
sed -ie '/^[[:space:]]*docs/d' configure.ac || die "sed failed"
fi
sed -i -e "s:-O0::" -e "/-DG_ENABLE_DEBUG/s: -g::" \
configure.ac || die "sed failed"
#disable unused translations. Bug #356029
for trans in app-chooser ask-rename exec-file file-prop preferred-apps \
progress;do
echo "data/ui/"${trans}.ui >> po/POTFILES.in
done
#Remove -Werror for automake-1.12. Bug #421101
sed -i "s:-Werror::" configure.ac || die
# subslot sanity check
local sub_slot=${SLOT#*/}
local libfm_major_abi=$(sed -rne '/ABI_VERSION/s:.*=::p' src/Makefile.am | tr ':' '.')
if [[ ${sub_slot} != ${libfm_major_abi} ]]; then
eerror "Ebuild sub-slot (${sub_slot}) does not match ABI_VERSION(${libfm_major_abi})"
eerror "Please update SLOT variable as follows:"
eerror " SLOT=\"${SLOT%%/*}/${libfm_major_abi}\""
eerror
die "sub-slot sanity check failed"
fi
eautoreconf
rm -r autom4te.cache || die
use vala && export VALAC="$(type -p valac-$(vala_best_api_version))"
}
src_configure() {
econf \
--sysconfdir="${EPREFIX}/etc" \
--disable-dependency-tracking \
--disable-static \
$(use_enable examples demo) \
$(use_enable exif) \
$(use_enable debug) \
$(use_enable udisks) \
$(use_enable vala actions) \
$(use_enable doc gtk-doc) \
--with-html-dir=/usr/share/doc/${PF}/html
}
src_install() {
default
find "${D}" -name '*.la' -exec rm -f '{}' +
# Sometimes a directory is created instead of a symlink. No idea why...
# It is wrong anyway. We expect a libfm-1.0 directory and then a libfm
# symlink to it.
if [[ -h ${D}/usr/include/${PN} || -d ${D}/usr/include/${PN} ]]; then
rm -r "${D}"/usr/include/${PN}
fi
}
pkg_preinst() {
# Resolve the symlink mess. Bug #439570
[[ -d "${ROOT}"/usr/include/${PN} ]] && \
rm -rf "${ROOT}"/usr/include/${PN}
if [[ -d "${D}"/usr/include/${PN}-1.0 ]]; then
cd "${D}"/usr/include
ln -s --force ${PN}-1.0 ${PN}
fi
}
pkg_postinst() {
fdo-mime_mime_database_update
}
pkg_postrm() {
fdo-mime_mime_database_update
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-09-06 8:41 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-09-06 8:41 [gentoo-commits] gentoo-x86 commit in x11-libs/libfm: libfm-9999.ebuild libfm-1.2.2.1.ebuild ChangeLog Markos Chandras (hwoarang)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox