* [gentoo-commits] gentoo-x86 commit in media-gfx/gimp: ChangeLog gimp-2.8.10.ebuild
@ 2013-12-02 23:29 Sebastian Pipping (sping)
0 siblings, 0 replies; 2+ messages in thread
From: Sebastian Pipping (sping) @ 2013-12-02 23:29 UTC (permalink / raw
To: gentoo-commits
sping 13/12/02 23:29:10
Modified: ChangeLog
Added: gimp-2.8.10.ebuild
Log:
media-gfx/gimp: 2.8.10 (bug #492842)
(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0x401A1600)
Revision Changes Path
1.419 media-gfx/gimp/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/ChangeLog?rev=1.419&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/ChangeLog?rev=1.419&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/ChangeLog?r1=1.418&r2=1.419
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v
retrieving revision 1.418
retrieving revision 1.419
diff -u -r1.418 -r1.419
--- ChangeLog 7 Nov 2013 20:29:32 -0000 1.418
+++ ChangeLog 2 Dec 2013 23:29:10 -0000 1.419
@@ -1,6 +1,11 @@
# ChangeLog for media-gfx/gimp
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v 1.418 2013/11/07 20:29:32 sping Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v 1.419 2013/12/02 23:29:10 sping Exp $
+
+*gimp-2.8.10 (02 Dec 2013)
+
+ 02 Dec 2013; Sebastian Pipping <sping@gentoo.org> +gimp-2.8.10.ebuild:
+ Bump to 2.8.10 (bug #492842)
*gimp-2.8.8-r1 (07 Nov 2013)
1.1 media-gfx/gimp/gimp-2.8.10.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/gimp-2.8.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/gimp-2.8.10.ebuild?rev=1.1&content-type=text/plain
Index: gimp-2.8.10.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/gimp-2.8.10.ebuild,v 1.1 2013/12/02 23:29:10 sping Exp $
EAPI="3"
PYTHON_DEPEND="python? 2:2.5"
inherit versionator autotools eutils gnome2 fdo-mime multilib python
DESCRIPTION="GNU Image Manipulation Program"
HOMEPAGE="http://www.gimp.org/"
SRC_URI="mirror://gimp/v$(get_version_component_range 1-2)/${P}.tar.bz2"
LICENSE="GPL-3 LGPL-3"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
LANGS="am ar ast az be bg br ca ca@valencia cs csb da de dz el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu id is it ja ka kk km kn ko lt lv mk ml ms my nb nds ne nl nn oc pa pl pt pt_BR ro ru rw si sk sl sr sr@latin sv ta te th tr tt uk vi xh yi zh_CN zh_HK zh_TW"
IUSE="alsa aalib altivec aqua bzip2 curl dbus debug doc exif gnome postscript jpeg jpeg2k lcms mmx mng pdf png python smp sse svg tiff udev webkit wmf xpm"
for lang in ${LANGS}; do
IUSE+=" linguas_${lang}"
done
RDEPEND=">=dev-libs/glib-2.30.2:2
>=dev-libs/atk-2.2.0
>=x11-libs/gtk+-2.24.10:2
>=x11-libs/gdk-pixbuf-2.24.1:2
>=x11-libs/cairo-1.10.2
>=x11-libs/pango-1.29.4
xpm? ( x11-libs/libXpm )
>=media-libs/freetype-2.1.7
>=media-libs/fontconfig-2.2.0
sys-libs/zlib
dev-libs/libxml2
dev-libs/libxslt
x11-themes/hicolor-icon-theme
>=media-libs/babl-0.1.10
>=media-libs/gegl-0.2.0
aalib? ( media-libs/aalib )
alsa? ( media-libs/alsa-lib )
curl? ( net-misc/curl )
dbus? ( dev-libs/dbus-glib )
gnome? ( gnome-base/gvfs )
webkit? ( >=net-libs/webkit-gtk-1.6.1:2 )
jpeg? ( virtual/jpeg:0 )
jpeg2k? ( media-libs/jasper )
exif? ( >=media-libs/libexif-0.6.15 )
lcms? ( >=media-libs/lcms-2.2:2 )
mng? ( media-libs/libmng )
pdf? ( >=app-text/poppler-0.12.4[cairo] )
png? ( >=media-libs/libpng-1.2.37:0 )
python? ( >=dev-python/pygtk-2.10.4:2 )
tiff? ( >=media-libs/tiff-3.5.7:0 )
svg? ( >=gnome-base/librsvg-2.36.0:2 )
wmf? ( >=media-libs/libwmf-0.2.8 )
x11-libs/libXcursor
sys-libs/zlib
bzip2? ( app-arch/bzip2 )
postscript? ( app-text/ghostscript-gpl )
udev? ( virtual/udev[gudev] )"
DEPEND="${RDEPEND}
sys-apps/findutils
virtual/pkgconfig
>=dev-util/intltool-0.40.1
>=sys-devel/gettext-0.17
doc? ( >=dev-util/gtk-doc-1 )
>=sys-devel/libtool-2.2
>=sys-devel/automake-1.11
dev-util/gtk-doc-am" # due to our call to eautoreconf below (bug #386453)
DOCS="AUTHORS ChangeLog* HACKING NEWS README*"
S="${WORKDIR}"/${P}
pkg_setup() {
G2CONF="--enable-default-binary \
--disable-silent-rules \
$(use_with !aqua x) \
$(use_with aalib aa) \
$(use_with alsa) \
$(use_enable altivec) \
$(use_with bzip2) \
$(use_with curl libcurl) \
$(use_with dbus) \
$(use_with gnome gvfs) \
$(use_with webkit) \
$(use_with jpeg libjpeg) \
$(use_with jpeg2k libjasper) \
$(use_with exif libexif) \
$(use_with lcms lcms lcms2) \
$(use_with postscript gs) \
$(use_enable mmx) \
$(use_with mng libmng) \
$(use_with pdf poppler) \
$(use_with png libpng) \
$(use_enable python) \
$(use_enable smp mp) \
$(use_enable sse) \
$(use_with svg librsvg) \
$(use_with tiff libtiff) \
$(use_with udev gudev) \
$(use_with wmf) \
--with-xmc \
$(use_with xpm libxpm) \
--without-xvfb-run"
if use python; then
python_set_active_version 2
python_pkg_setup
fi
}
src_prepare() {
epatch "${FILESDIR}"/${PN}-2.7.4-no-deprecation.patch # bug 395695, comment 9 and 16
eautoreconf # If you remove this: remove dev-util/gtk-doc-am from DEPEND, too
echo '#!/bin/sh' > py-compile
gnome2_src_prepare
}
_clean_up_locales() {
einfo "Cleaning up locales..."
for lang in ${LANGS}; do
use "linguas_${lang}" && {
einfo "- keeping ${lang}"
continue
}
rm -Rf "${ED}"/usr/share/locale/"${lang}" || die
done
}
src_install() {
gnome2_src_install
if use python; then
python_convert_shebangs -r $(python_get_version) "${ED}"
python_need_rebuild
fi
# Workaround for bug #321111 to give GIMP the least
# precedence on PDF documents by default
mv "${ED}"/usr/share/applications/{,zzz-}gimp.desktop || die
find "${ED}" -name '*.la' -delete || die
# Prevent dead symlink gimp-console.1 from downstream man page compression (bug #433527)
local gimp_app_version=$(get_version_component_range 1-2)
mv "${ED}"/usr/share/man/man1/gimp-console{-${gimp_app_version},}.1 || die
_clean_up_locales
}
pkg_postinst() {
gnome2_pkg_postinst
use python && python_mod_optimize /usr/$(get_libdir)/gimp/2.0/python \
/usr/$(get_libdir)/gimp/2.0/plug-ins
}
pkg_postrm() {
gnome2_pkg_postrm
use python && python_mod_cleanup /usr/$(get_libdir)/gimp/2.0/python \
/usr/$(get_libdir)/gimp/2.0/plug-ins
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-gfx/gimp: ChangeLog gimp-2.8.10.ebuild
@ 2014-09-01 18:40 Sebastian Pipping (sping)
0 siblings, 0 replies; 2+ messages in thread
From: Sebastian Pipping (sping) @ 2014-09-01 18:40 UTC (permalink / raw
To: gentoo-commits
sping 14/09/01 18:40:59
Modified: ChangeLog
Removed: gimp-2.8.10.ebuild
Log:
media-gfx/gimp: Cleanup
(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 0x401A1600)
Revision Changes Path
1.437 media-gfx/gimp/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/ChangeLog?rev=1.437&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/ChangeLog?rev=1.437&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/ChangeLog?r1=1.436&r2=1.437
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v
retrieving revision 1.436
retrieving revision 1.437
diff -u -r1.436 -r1.437
--- ChangeLog 1 Sep 2014 18:11:40 -0000 1.436
+++ ChangeLog 1 Sep 2014 18:40:59 -0000 1.437
@@ -1,6 +1,9 @@
# ChangeLog for media-gfx/gimp
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v 1.436 2014/09/01 18:11:40 sping Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v 1.437 2014/09/01 18:40:59 sping Exp $
+
+ 01 Sep 2014; Sebastian Pipping <sping@gentoo.org> -gimp-2.8.10.ebuild:
+ Remove old version
*gimp-2.8.14 (01 Sep 2014)
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2014-09-01 18:41 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-09-01 18:40 [gentoo-commits] gentoo-x86 commit in media-gfx/gimp: ChangeLog gimp-2.8.10.ebuild Sebastian Pipping (sping)
-- strict thread matches above, loose matches on Subject: below --
2013-12-02 23:29 Sebastian Pipping (sping)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox