* [gentoo-commits] gentoo-x86 commit in kde-base/pykde4: pykde4-4.14.0-r1.ebuild ChangeLog
@ 2014-09-01 14:13 Michal Gorny (mgorny)
0 siblings, 0 replies; only message in thread
From: Michal Gorny (mgorny) @ 2014-09-01 14:13 UTC (permalink / raw
To: gentoo-commits
mgorny 14/09/01 14:13:52
Modified: ChangeLog
Added: pykde4-4.14.0-r1.ebuild
Log:
Support python-exec:2.
(Portage version: 2.2.11_p178/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)
Revision Changes Path
1.300 kde-base/pykde4/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/pykde4/ChangeLog?rev=1.300&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/pykde4/ChangeLog?rev=1.300&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/pykde4/ChangeLog?r1=1.299&r2=1.300
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/pykde4/ChangeLog,v
retrieving revision 1.299
retrieving revision 1.300
diff -u -r1.299 -r1.300
--- ChangeLog 28 Aug 2014 11:31:52 -0000 1.299
+++ ChangeLog 1 Sep 2014 14:13:51 -0000 1.300
@@ -1,6 +1,11 @@
# ChangeLog for kde-base/pykde4
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/pykde4/ChangeLog,v 1.299 2014/08/28 11:31:52 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/pykde4/ChangeLog,v 1.300 2014/09/01 14:13:51 mgorny Exp $
+
+*pykde4-4.14.0-r1 (01 Sep 2014)
+
+ 01 Sep 2014; Michał Górny <mgorny@gentoo.org> +pykde4-4.14.0-r1.ebuild:
+ Support python-exec:2.
28 Aug 2014; Michael Palimaka <kensington@gentoo.org>
+files/pykde4-4.14.0-arm-sip.patch, pykde4-4.14.0.ebuild:
1.1 kde-base/pykde4/pykde4-4.14.0-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/pykde4/pykde4-4.14.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/pykde4/pykde4-4.14.0-r1.ebuild?rev=1.1&content-type=text/plain
Index: pykde4-4.14.0-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/pykde4/pykde4-4.14.0-r1.ebuild,v 1.1 2014/09/01 14:13:51 mgorny Exp $
EAPI=5
PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} )
PYTHON_REQ_USE="threads"
OPENGL_REQUIRED="always"
inherit python-r1 portability kde4-base multilib eutils
DESCRIPTION="Python bindings for KDE4"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="akonadi debug doc examples nepomuk test"
HOMEPAGE="http://techbase.kde.org/Development/Languages/Python"
REQUIRED_USE="${PYTHON_REQUIRED_USE} test? ( nepomuk )"
RDEPEND="
${PYTHON_DEPS}
>=dev-python/PyQt4-4.11.1[${PYTHON_USEDEP},dbus,declarative,script,sql,svg,webkit,X]
>=dev-python/sip-4.16.2:=[${PYTHON_USEDEP}]
$(add_kdebase_dep kdelibs 'nepomuk?,opengl')
akonadi? ( $(add_kdebase_dep kdepimlibs) )
nepomuk? ( >=dev-libs/soprano-2.9.0 )
"
DEPEND="${RDEPEND}
dev-lang/python-exec:2[${PYTHON_USEDEP}]
sys-devel/libtool
"
pkg_setup() {
kde4-base_pkg_setup
have_python2=false
scan_python_versions() {
if [[ ${EPYTHON} == python2.* ]]; then
have_python2=true
fi
}
python_foreach_impl scan_python_versions
if ! ${have_python2}; then
ewarn "You do not have a Python 2 version selected."
ewarn "kpythonpluginfactory will not be built"
fi
}
src_prepare() {
kde4-base_src_prepare
if ! use examples; then
sed -e '/^ADD_SUBDIRECTORY(examples)/s/^/# DISABLED /' -i CMakeLists.txt \
|| die "Failed to disable examples"
fi
# See bug 322351
use arm && epatch "${FILESDIR}/${PN}-4.14.0-arm-sip.patch"
sed -e 's/kpythonpluginfactory /kpython${PYTHON_SHORT_VERSION}pluginfactory /g' \
-i kpythonpluginfactory/CMakeLists.txt || die
if ${have_python2}; then
mkdir -p "${WORKDIR}/wrapper" || die "failed to copy wrapper"
cp "${FILESDIR}/kpythonpluginfactorywrapper.c-r1" "${WORKDIR}/wrapper/kpythonpluginfactorywrapper.c" || die "failed to copy wrapper"
fi
python_copy_sources
}
src_configure() {
configuration() {
local mycmakeargs=(
-DWITH_PolkitQt=OFF
-DWITH_QScintilla=OFF
$(cmake-utils_use_with akonadi KdepimLibs)
$(cmake-utils_use_with nepomuk)
$(cmake-utils_use_with nepomuk Soprano)
-DPYTHON_EXECUTABLE=${PYTHON}
-DPYKDEUIC4_ALTINSTALL=TRUE
)
local CMAKE_BUILD_DIR=${S}_build-${PYTHON_ABI}
kde4-base_src_configure
}
python_foreach_impl run_in_build_dir configuration
}
echo_and_run() {
echo "$@"
"$@"
}
src_compile() {
compilation() {
local CMAKE_BUILD_DIR=${S}_build-${PYTHON_ABI}
kde4-base_src_compile
}
python_foreach_impl run_in_build_dir compilation
if ${have_python2}; then
pushd "${WORKDIR}/wrapper" > /dev/null
echo_and_run libtool --tag=CC --mode=compile $(tc-getCC) \
-shared \
${CFLAGS} ${CPPFLAGS} \
-DEPREFIX="\"${EPREFIX}\"" \
-DPLUGIN_DIR="\"/usr/$(get_libdir)/kde4\"" -c \
-o kpythonpluginfactorywrapper.lo \
kpythonpluginfactorywrapper.c
echo_and_run libtool --tag=CC --mode=link $(tc-getCC) \
-shared -module -avoid-version \
${CFLAGS} ${LDFLAGS} \
-o kpythonpluginfactory.la \
-rpath "${EPREFIX}/usr/$(get_libdir)/kde4" \
kpythonpluginfactorywrapper.lo \
$(dlopen_lib)
popd > /dev/null
fi
}
src_test() {
python_foreach_impl run_in_build_dir kde4-base_src_test
}
src_install() {
installation() {
emake DESTDIR="${D}" install
mkdir -p "${D%/}$(python_get_scriptdir)" || die
mv "${ED%/}/usr/bin/pykdeuic4-${EPYTHON/python/}" \
"${D%/}$(python_get_scriptdir)"/pykdeuic4 || die
python_fix_shebang "${D%/}$(python_get_scriptdir)"/pykdeuic4
python_optimize
}
python_foreach_impl run_in_build_dir installation
dosym ../lib/python-exec/python-exec2 /usr/bin/pykdeuic4
# As we don't call the eclass's src_install, we have to install the docs manually
DOCS=("${S}"/{AUTHORS,NEWS,README})
use doc && HTML_DOCS=("${S}/docs/html/")
einstalldocs
if ${have_python2}; then
pushd "${WORKDIR}/wrapper" > /dev/null
echo_and_run libtool --mode=install install kpythonpluginfactory.la "${ED}/usr/$(get_libdir)/kde4/kpythonpluginfactory.la"
rm "${ED}/usr/$(get_libdir)/kde4/kpythonpluginfactory.la"
popd > /dev/null
fi
}
pkg_postinst() {
kde4-base_pkg_postinst
if use examples; then
echo
elog "PyKDE4 examples have been installed to"
elog "${EPREFIX}/usr/share/apps/${PN}/examples"
echo
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-09-01 14:13 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-09-01 14:13 [gentoo-commits] gentoo-x86 commit in kde-base/pykde4: pykde4-4.14.0-r1.ebuild ChangeLog Michal Gorny (mgorny)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox