[gentoo-commits] gentoo-x86 commit in dev-python/subunit: subunit-0.0.19.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-python/subunit: subunit-0.0.19.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     14/09/01 04:10:56

  Modified:             ChangeLog
  Added:                subunit-0.0.19.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.12/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.50                 dev-python/subunit/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/subunit/ChangeLog?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/subunit/ChangeLog?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/subunit/ChangeLog?r1=1.49&r2=1.50

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/subunit/ChangeLog,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- ChangeLog	19 Jul 2014 19:48:21 -0000	1.49
+++ ChangeLog	1 Sep 2014 04:10:56 -0000	1.50
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/subunit
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/subunit/ChangeLog,v 1.49 2014/07/19 19:48:21 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/subunit/ChangeLog,v 1.50 2014/09/01 04:10:56 patrick Exp $
+
+*subunit-0.0.19 (01 Sep 2014)
+
+  01 Sep 2014; Patrick Lauer <patrick@gentoo.org> +subunit-0.0.19.ebuild:
+  Bump
 
   19 Jul 2014; Tobias Klausmann <klausman@gentoo.org> subunit-0.0.16.ebuild:
   Stable on alpha, bug #506620



1.1                  dev-python/subunit/subunit-0.0.19.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/subunit/subunit-0.0.19.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/subunit/subunit-0.0.19.ebuild?rev=1.1&content-type=text/plain

Index: subunit-0.0.19.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/subunit/subunit-0.0.19.ebuild,v 1.1 2014/09/01 04:10:56 patrick Exp $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy pypy2_0 )

inherit distutils-r1 eutils multilib-minimal

DESCRIPTION="A streaming protocol for test results"
HOMEPAGE="https://launchpad.net/subunit http://pypi.python.org/pypi/python-subunit"
SRC_URI="http://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.gz"

LICENSE="Apache-2.0 BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~x86 ~x86-fbsd"
#need to keyword the following in =dev-python/extras-0.0.3 then readd the keywords here
#ia64 s390 sh sparc amd64-fbsd
IUSE="static-libs"

RDEPEND=">=dev-python/testtools-0.9.34[${PYTHON_USEDEP}]
	dev-python/extras[${PYTHON_USEDEP}]"
#	test? ( dev-python/testscenarios[${PYTHON_USEDEP}] )
#requires keywording first; Bug #506510
DEPEND="${RDEPEND}
	dev-python/setuptools[${PYTHON_USEDEP}]
	dev-lang/perl
	>=dev-libs/check-0.9.11[${MULTILIB_USEDEP}]
	>=dev-util/cppunit-1.13.2[${MULTILIB_USEDEP}]
	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]"
#requires keywording first; Bug #506510
RESTRICT="test"

src_prepare() {
	sed -i -e 's/os.chdir(os.path.dirname(__file__))//' setup.py || die
	# needed for perl modules
	multilib_copy_sources
	distutils-r1_src_prepare
}

multilib_src_configure() {
	ECONF_SOURCE=${S} \
	econf \
		--enable-shared \
		$(use_enable static-libs static)
}

multilib_src_compile() {
	default
	multilib_is_native_abi && distutils-r1_src_compile
}

python_test() {
	local -x PATH="${PWD}/shell/share:${PATH}"
	local -x PYTHONPATH=python
	"${PYTHON}" -m testtools.run all_tests.test_suite || die "Testing failed with ${EPYTHON}"
}

multilib_src_test() {
	multilib_is_native_abi && distutils-r1_src_test
}

multilib_src_install() {
	local targets=(
		install-include_subunitHEADERS
		install-pcdataDATA
		install-exec-local
		install-libLTLIBRARIES
	)
	emake DESTDIR="${D}" "${targets[@]}"

	multilib_is_native_abi && distutils-r1_src_install
}

multilib_src_install_all() {
	einstalldocs
	prune_libtool_files
}