[gentoo-commits] gentoo-x86 commit in games-board/scid: ChangeLog scid-4.5.2.ebuild

[gentoo-commits] gentoo-x86 commit in games-board/scid: ChangeLog scid-4.5.2.ebuild

[Julian Ospald (hasufell)]

hasufell    14/09/01 00:36:56

  Modified:             ChangeLog
  Added:                scid-4.5.2.ebuild
  Log:
  version bump wrt #506534, convert to python-any-r1
  
  (Portage version: 2.2.12-r1/cvs/Linux x86_64, signed Manifest commit with key BDEED020)

Revision  Changes    Path
1.43                 games-board/scid/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/scid/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/scid/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/scid/ChangeLog?r1=1.42&r2=1.43

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-board/scid/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog	20 Mar 2014 22:20:55 -0000	1.42
+++ ChangeLog	1 Sep 2014 00:36:56 -0000	1.43
@@ -1,6 +1,12 @@
 # ChangeLog for games-board/scid
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-board/scid/ChangeLog,v 1.42 2014/03/20 22:20:55 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-board/scid/ChangeLog,v 1.43 2014/09/01 00:36:56 hasufell Exp $
+
+*scid-4.5.2 (01 Sep 2014)
+
+  01 Sep 2014; Julian Ospald <hasufell@gentoo.org> +scid-4.5.2.ebuild,
+  +files/scid-4.5.2-gentoo.patch:
+  version bump wrt #506534, convert to python-any-r1
 
   20 Mar 2014; Michael Sterrett <mr_bones_@gentoo.org>
   -files/scid-4.3-gentoo.patch, -files/scid-4.3-parallelmake.patch,



1.1                  games-board/scid/scid-4.5.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/scid/scid-4.5.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/scid/scid-4.5.2.ebuild?rev=1.1&content-type=text/plain

Index: scid-4.5.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-board/scid/scid-4.5.2.ebuild,v 1.1 2014/09/01 00:36:56 hasufell Exp $

EAPI=5
PYTHON_COMPAT=( python2_7 )
inherit eutils toolchain-funcs gnome2-utils python-any-r1 games

DESCRIPTION="a free chess database application"
HOMEPAGE="http://scid.sourceforge.net/"
SRC_URI="mirror://sourceforge/scid/Scid-${PV}.zip
	mirror://sourceforge/scid/spelling.zip
	mirror://sourceforge/scid/ratings.zip
	mirror://sourceforge/scid/photos.zip
	mirror://sourceforge/scid/scidlet40k.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

CDEPEND="dev-lang/tk
	>=sys-libs/zlib-1.1.3"
RDEPEND="${CDEPEND}
	!games-board/chessdb"
DEPEND="${CDEPEND}
	${PYTHON_DEPS}
	app-arch/unzip"

pkg_setup() {
	python-any-r1_pkg_setup
	games_pkg_setup
}

src_unpack() {
	default
	mv scid-code-* ${P} || die
}

src_prepare() {
	edos2unix engines/togaII1.2.1a/src/Makefile
	epatch "${FILESDIR}"/${P}-gentoo.patch
	sed -i \
		-e "s:@GENTOO_DATADIR@:${GAMES_DATADIR}/${PN}:" \
		tcl/start.tcl \
		src/scidlet.cpp \
		|| die "sed failed"
	gzip ../ratings.ssp
	python_fix_shebang .
}

src_configure() {
	# configure is not an autotools script
	./configure \
		COMPILE="$(tc-getCXX)" \
		LINK="$(tc-getCXX) ${CXXFLAGS} ${LDFLAGS}" \
		CC="$(tc-getCC)" \
		OPTIMIZE="${CXXFLAGS}" \
		TCL_INCLUDE="" \
		BINDIR="${GAMES_BINDIR}" \
		SHAREDIR="${GAMES_DATADIR}/${PN}" \
		|| die "configure failed"
}

src_compile() {
	emake all_scid
}

src_install() {
	emake DESTDIR="${D}" install_scid
	insinto "${GAMES_DATADIR}"/${PN}
	doins -r sounds

	dodoc ChangeLog TODO
	dohtml help/*.html

	newicon -s scalable svg/scid_app.svg ${PN}.svg
	make_desktop_entry scid Scid

	cd .. || die
	doins spelling.ssp ratings.ssp.gz *.spf
	newins scidlet40k.sbk scidlet.sbk

	prepgamesdirs
}

pkg_preinst() {
	games_pkg_preinst
	gnome2_icon_savelist
}

pkg_postinst() {
	games_pkg_postinst
	gnome2_icon_cache_update
	elog "To enable speech, emerge dev-tcltk/snack"
	elog "To enable some piece sets, emerge dev-tcltk/tkimg"
	elog "To enable Xfcc support, emerge dev-tcltk/tdom"
}

pkg_postrm() {
	gnome2_icon_cache_update
}