* [gentoo-commits] gentoo-x86 commit in net-wireless/gnuradio: gnuradio-3.7.4-r1.ebuild gnuradio-9999.ebuild ChangeLog gnuradio-3.7.4.ebuild
@ 2014-08-25 15:47 Richard Farina (zerochaos)
0 siblings, 0 replies; only message in thread
From: Richard Farina (zerochaos) @ 2014-08-25 15:47 UTC (permalink / raw
To: gentoo-commits
zerochaos 14/08/25 15:47:57
Modified: gnuradio-9999.ebuild ChangeLog
Added: gnuradio-3.7.4-r1.ebuild
Removed: gnuradio-3.7.4.ebuild
Log:
fix bug in qtgui where we included qwt5 but linked to qwt6, fix missing include for string.h
(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key DD11F94A)
Revision Changes Path
1.22 net-wireless/gnuradio/gnuradio-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/gnuradio-9999.ebuild?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/gnuradio-9999.ebuild?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/gnuradio-9999.ebuild?r1=1.21&r2=1.22
Index: gnuradio-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/gnuradio-9999.ebuild,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- gnuradio-9999.ebuild 24 Aug 2014 21:49:25 -0000 1.21
+++ gnuradio-9999.ebuild 25 Aug 2014 15:47:57 -0000 1.22
@@ -1,6 +1,6 @@
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/gnuradio-9999.ebuild,v 1.21 2014/08/24 21:49:25 zerochaos Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/gnuradio-9999.ebuild,v 1.22 2014/08/25 15:47:57 zerochaos Exp $
EAPI=5
PYTHON_COMPAT=( python2_7 )
@@ -153,7 +153,6 @@
-DSYSCONFDIR="${EPREFIX}"/etc \
-DPYTHON_EXECUTABLE="${PYTHON}"
)
- use qt4 && mycmakeargs+=( -DQWT_INCLUDE_DIRS="${EPREFIX}"/usr/include/qwt5 )
cmake-utils_src_configure
}
1.52 net-wireless/gnuradio/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/ChangeLog?rev=1.52&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/ChangeLog?rev=1.52&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/ChangeLog?r1=1.51&r2=1.52
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/ChangeLog,v
retrieving revision 1.51
retrieving revision 1.52
diff -u -r1.51 -r1.52
--- ChangeLog 24 Aug 2014 21:49:25 -0000 1.51
+++ ChangeLog 25 Aug 2014 15:47:57 -0000 1.52
@@ -1,6 +1,14 @@
# ChangeLog for net-wireless/gnuradio
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/ChangeLog,v 1.51 2014/08/24 21:49:25 zerochaos Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/ChangeLog,v 1.52 2014/08/25 15:47:57 zerochaos Exp $
+
+*gnuradio-3.7.4-r1 (25 Aug 2014)
+
+ 25 Aug 2014; Rick Farina <zerochaos@gentoo.org>
+ +files/gnuradio-3.7.4-include_stringh.patch, +gnuradio-3.7.4-r1.ebuild,
+ -files/include_stringh.patch, -gnuradio-3.7.4.ebuild, gnuradio-9999.ebuild:
+ fix bug in qtgui where we included qwt5 but linked to qwt6, fix missing
+ include for string.h
24 Aug 2014; Rick Farina <zerochaos@gentoo.org> +files/include_stringh.patch,
gnuradio-3.7.4.ebuild, gnuradio-9999.ebuild, metadata.xml:
1.1 net-wireless/gnuradio/gnuradio-3.7.4-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/gnuradio-3.7.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/gnuradio-3.7.4-r1.ebuild?rev=1.1&content-type=text/plain
Index: gnuradio-3.7.4-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/gnuradio-3.7.4-r1.ebuild,v 1.1 2014/08/25 15:47:57 zerochaos Exp $
EAPI=5
PYTHON_COMPAT=( python2_7 )
inherit cmake-utils fdo-mime python-single-r1
DESCRIPTION="Toolkit that provides signal processing blocks to implement software radios"
HOMEPAGE="http://gnuradio.org/"
LICENSE="GPL-3"
SLOT="0/${PV}"
if [[ ${PV} == "9999" ]] ; then
EGIT_REPO_URI="http://gnuradio.org/git/gnuradio.git"
inherit git-2
KEYWORDS=""
else
SRC_URI="http://gnuradio.org/releases/${PN}/${P}.tar.gz"
KEYWORDS="~amd64 ~arm ~x86"
fi
IUSE="alsa +analog +digital channels +ctrlport doc examples fcd +filter grc jack log oss pager performance-counters portaudio +qt4 sdl uhd +utils wavelet wxwidgets"
REQUIRED_USE="${PYTHON_REQUIRED_USE}
analog? ( filter )
digital? ( filter analog )
pager? ( filter analog )
qt4? ( filter )
uhd? ( filter analog )
fcd? ( || ( alsa oss ) )
wavelet? ( analog )
wxwidgets? ( filter analog )"
# bug #348206
# comedi? ( >=sci-electronics/comedilib-0.8 )
# boost-1.52.0 is blacklisted, bug #461578, upstream #513, boost #7669
RDEPEND="${PYTHON_DEPS}
>=dev-lang/orc-0.4.12
dev-libs/boost:0=[${PYTHON_USEDEP}]
!<=dev-libs/boost-1.52.0-r6:0/1.52
dev-python/numpy[${PYTHON_USEDEP}]
>=dev-util/cppunit-1.9.14
sci-libs/fftw:3.0=
alsa? (
media-libs/alsa-lib[${PYTHON_USEDEP}]
)
ctrlport? ( dev-libs/Ice[python,${PYTHON_USEDEP}] )
fcd? ( virtual/libusb:1 )
filter? ( sci-libs/scipy )
grc? (
dev-python/cheetah[${PYTHON_USEDEP}]
dev-python/lxml[${PYTHON_USEDEP}]
>=dev-python/pygtk-2.10:2[${PYTHON_USEDEP}]
)
jack? (
media-sound/jack-audio-connection-kit
)
log? ( dev-libs/log4cpp )
portaudio? (
>=media-libs/portaudio-19_pre
)
qt4? (
>=dev-python/PyQt4-4.4[X,opengl,${PYTHON_USEDEP}]
>=dev-python/pyqwt-5.2:5
>=dev-qt/qtcore-4.4
>=dev-qt/qtgui-4.4:4
>=x11-libs/qwt-5.2
)
sdl? ( >=media-libs/libsdl-1.2.0 )
uhd? ( >=net-wireless/uhd-3.4.3-r1:=[${PYTHON_USEDEP}] )
wavelet? (
>=sci-libs/gsl-1.10
)
wxwidgets? (
dev-python/lxml[${PYTHON_USEDEP}]
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/wxpython:2.8[${PYTHON_USEDEP}]
)
"
DEPEND="${RDEPEND}
dev-lang/swig
dev-python/cheetah[${PYTHON_USEDEP}]
virtual/pkgconfig
doc? (
>=app-doc/doxygen-1.5.7.1
dev-python/sphinx[${PYTHON_USEDEP}]
)
grc? (
x11-misc/xdg-utils
)
oss? (
virtual/os-headers
)
"
src_prepare() {
# Useless UI element would require qt3support, bug #365019
sed -i '/qPixmapFromMimeSource/d' "${S}"/gr-qtgui/lib/spectrumdisplayform.ui || die
epatch "${FILESDIR}"/${PN}-3.6.1-automagic-audio.patch
epatch "${FILESDIR}"/${P}-include_stringh.patch
}
src_configure() {
# TODO: docs are installed to /usr/share/doc/${PN} not /usr/share/doc/${PF}
# SYSCONFDIR/GR_PREFSDIR default to install below CMAKE_INSTALL_PREFIX
#this flag breaks everything, but more likely it's a sign we need to work on this
#-DENABLE_DEFAULT=OFF
mycmakeargs=(
$(cmake-utils_use_enable alsa GR_AUDIO_ALSA) \
$(cmake-utils_use_enable analog GR_ANALOG) \
$(cmake-utils_use_enable channels GR_CHANNELS) \
$(cmake-utils_use_enable ctrlport GR_CTRLPORT) \
$(cmake-utils_use_enable digital GR_DIGITAL) \
$(cmake-utils_use_enable doc DOXYGEN) \
$(cmake-utils_use_enable doc SPHINX) \
$(cmake-utils_use_enable fcd GR_FCD) \
$(cmake-utils_use_enable filter GR_FILTER) \
$(cmake-utils_use_enable grc GRC) \
$(cmake-utils_use_enable jack GR_AUDIO_JACK) \
$(cmake-utils_use_enable log GR_LOG) \
$(cmake-utils_use_enable oss GR_AUDIO_OSS) \
$(cmake-utils_use_enable pager GR_PAGER) \
$(cmake-utils_use_enable performance-counters ENABLE_PERFORMANCE_COUNTERS) \
$(cmake-utils_use_enable portaudio GR_AUDIO_PORTAUDIO) \
$(cmake-utils_use_enable uhd GR_UHD) \
$(cmake-utils_use_enable utils GR_UTILS) \
$(cmake-utils_use_enable wavelet GR_WAVELET) \
$(cmake-utils_use_enable wxwidgets GR_WXGUI) \
$(cmake-utils_use_enable qt4 GR_QTGUI) \
$(cmake-utils_use_enable sdl GR_VIDEO_SDL) \
-DENABLE_GR_CORE=ON \
-DSYSCONFDIR="${EPREFIX}"/etc \
-DPYTHON_EXECUTABLE="${PYTHON}"
)
cmake-utils_src_configure
}
src_install() {
cmake-utils_src_install
if use examples ; then
dodir /usr/share/doc/${PF}/
mv "${ED}"/usr/share/${PN}/examples "${ED}"/usr/share/doc/${PF}/ || die
else
# It seems that the examples are always installed
rm -rf "${ED}"/usr/share/${PN}/examples || die
fi
# We install the mimetypes to the correct locations from the ebuild
rm -rf "${ED}"/usr/share/${PN}/grc/freedesktop || die
rm -f "${ED}"/usr/libexec/${PN}/grc_setup_freedesktop || die
# Install icons, menu items and mime-types for GRC
if use grc ; then
local fd_path="${S}/grc/freedesktop"
insinto /usr/share/mime/packages
doins "${fd_path}/${PN}-grc.xml"
domenu "${fd_path}/"*.desktop
doicon "${fd_path}/"*.png
fi
python_fix_shebang "${ED}"
}
src_test()
{
ctest -E qtgui
}
pkg_postinst()
{
local GRC_ICON_SIZES="32 48 64 128 256"
if use grc ; then
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
for size in ${GRC_ICON_SIZES} ; do
xdg-icon-resource install --noupdate --context mimetypes --size ${size} \
"${EROOT}/usr/share/pixmaps/grc-icon-${size}.png" application-gnuradio-grc \
|| die "icon resource installation failed"
xdg-icon-resource install --noupdate --context apps --size ${size} \
"${EROOT}/usr/share/pixmaps/grc-icon-${size}.png" gnuradio-grc \
|| die "icon resource installation failed"
done
xdg-icon-resource forceupdate
fi
}
pkg_postrm()
{
local GRC_ICON_SIZES="32 48 64 128 256"
if use grc ; then
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
for size in ${GRC_ICON_SIZES} ; do
xdg-icon-resource uninstall --noupdate --context mimetypes --size ${size} \
application-gnuradio-grc || ewarn "icon uninstall failed"
xdg-icon-resource uninstall --noupdate --context apps --size ${size} \
gnuradio-grc || ewarn "icon uninstall failed"
done
xdg-icon-resource forceupdate
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-08-25 15:48 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-08-25 15:47 [gentoo-commits] gentoo-x86 commit in net-wireless/gnuradio: gnuradio-3.7.4-r1.ebuild gnuradio-9999.ebuild ChangeLog gnuradio-3.7.4.ebuild Richard Farina (zerochaos)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox