* [gentoo-commits] gentoo-x86 commit in app-admin/glance: glance-2014.1.2.ebuild ChangeLog glance-2014.1.1.ebuild
@ 2014-08-21 20:40 Matt Thode (prometheanfire)
0 siblings, 0 replies; only message in thread
From: Matt Thode (prometheanfire) @ 2014-08-21 20:40 UTC (permalink / raw
To: gentoo-commits
prometheanfire 14/08/21 20:40:15
Modified: ChangeLog
Added: glance-2014.1.2.ebuild
Removed: glance-2014.1.1.ebuild
Log:
bup and fix for bug 520352 CVE-2014-5356
(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x2471eb3e40ac5ac3)
Revision Changes Path
1.48 app-admin/glance/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/glance/ChangeLog?rev=1.48&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/glance/ChangeLog?rev=1.48&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/glance/ChangeLog?r1=1.47&r2=1.48
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/glance/ChangeLog,v
retrieving revision 1.47
retrieving revision 1.48
diff -u -r1.47 -r1.48
--- ChangeLog 1 Aug 2014 05:12:09 -0000 1.47
+++ ChangeLog 21 Aug 2014 20:40:15 -0000 1.48
@@ -1,6 +1,13 @@
# ChangeLog for app-admin/glance
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/glance/ChangeLog,v 1.47 2014/08/01 05:12:09 prometheanfire Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/glance/ChangeLog,v 1.48 2014/08/21 20:40:15 prometheanfire Exp $
+
+*glance-2014.1.2 (21 Aug 2014)
+
+ 21 Aug 2014; Matthew Thode <prometheanfire@gentoo.org>
+ +files/2014.1.2-CVE-2014-5356.patch, +glance-2014.1.2.ebuild,
+ -files/CVE-2014-0162-2013.2.3.patch, -glance-2014.1.1.ebuild:
+ bup and fix for bug 520352 CVE-2014-5356
01 Aug 2014; Matthew Thode <prometheanfire@gentoo.org> glance-9999.ebuild:
updating git master glance
1.1 app-admin/glance/glance-2014.1.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/glance/glance-2014.1.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/glance/glance-2014.1.2.ebuild?rev=1.1&content-type=text/plain
Index: glance-2014.1.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/glance/glance-2014.1.2.ebuild,v 1.1 2014/08/21 20:40:15 prometheanfire Exp $
EAPI=5
PYTHON_COMPAT=( python2_7 )
inherit distutils-r1 user
DESCRIPTION="Provides services for discovering, registering, and retrieving
virtual machine images with Openstack"
HOMEPAGE="https://launchpad.net/glance"
SRC_URI="http://launchpad.net/${PN}/icehouse/${PV}/+download/${P}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc mysql postgres +sqlite +swift test"
REQUIRED_USE="|| ( mysql postgres sqlite )"
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
>=dev-python/pbr-0.6.0[${PYTHON_USEDEP}]
<dev-python/pbr-1.0[${PYTHON_USEDEP}]
test? ( >=dev-python/hacking-0.8.0[${PYTHON_USEDEP}]
<dev-python/hacking-0.9[${PYTHON_USEDEP}]
>=dev-python/Babel-1.3[${PYTHON_USEDEP}]
>=dev-python/coverage-3.6[${PYTHON_USEDEP}]
>=dev-python/fixtures-0.3.14[${PYTHON_USEDEP}]
>=dev-python/mock-1.0[${PYTHON_USEDEP}]
>=dev-python/mox-0.5.3[${PYTHON_USEDEP}]
>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
<dev-python/sphinx-1.2[${PYTHON_USEDEP}]
>=dev-python/requests-1.1[${PYTHON_USEDEP}]
>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
>=dev-python/testtools-0.9.34[${PYTHON_USEDEP}]
>=dev-python/psutil-1.1.1[${PYTHON_USEDEP}]
dev-python/mysql-python[${PYTHON_USEDEP}]
dev-python/psycopg[${PYTHON_USEDEP}]
~dev-python/pysendfile-2.0.0[${PYTHON_USEDEP}]
dev-python/qpid-python[${PYTHON_USEDEP}]
>=dev-python/pyxattr-0.5.0[${PYTHON_USEDEP}]
dev-python/oslo-sphinx[${PYTHON_USEDEP}] )"
#note to self, wsgiref is a python builtin, no need to package it
#>=dev-python/wsgiref-0.1.2[${PYTHON_USEDEP}]
RDEPEND=">=dev-python/greenlet-0.3.2[${PYTHON_USEDEP}]
sqlite? (
>=dev-python/sqlalchemy-0.8.0[sqlite,${PYTHON_USEDEP}]
!~dev-python/sqlalchemy-0.9.5[sqlite,${PYTHON_USEDEP}]
<=dev-python/sqlalchemy-0.9.99[sqlite,${PYTHON_USEDEP}]
)
mysql? (
dev-python/mysql-python
>=dev-python/sqlalchemy-0.8.0[${PYTHON_USEDEP}]
!~dev-python/sqlalchemy-0.9.5[${PYTHON_USEDEP}]
<=dev-python/sqlalchemy-0.9.99[${PYTHON_USEDEP}]
)
postgres? (
dev-python/psycopg:2
>=dev-python/sqlalchemy-0.8.0[${PYTHON_USEDEP}]
!~dev-python/sqlalchemy-0.9.5[${PYTHON_USEDEP}]
<=dev-python/sqlalchemy-0.9.99[${PYTHON_USEDEP}]
)
>=dev-python/anyjson-0.3.3[${PYTHON_USEDEP}]
>=dev-python/eventlet-0.13.0[${PYTHON_USEDEP}]
>=dev-python/pastedeploy-1.5.0[${PYTHON_USEDEP}]
>=dev-python/routes-1.12.3[${PYTHON_USEDEP}]
>=dev-python/webob-1.2.3[${PYTHON_USEDEP}]
>=dev-python/boto-2.12.0[${PYTHON_USEDEP}]
!~dev-python/boto-2.13.0[${PYTHON_USEDEP}]
>=dev-python/sqlalchemy-migrate-0.9[${PYTHON_USEDEP}]
>=dev-python/httplib2-0.7.5[${PYTHON_USEDEP}]
>=dev-python/kombu-2.4.8[${PYTHON_USEDEP}]
>=dev-python/pycrypto-2.6[${PYTHON_USEDEP}]
>=dev-python/iso8601-0.1.9[${PYTHON_USEDEP}]
>=dev-python/oslo-config-1.2.1[${PYTHON_USEDEP}]
>=dev-python/stevedore-0.14[${PYTHON_USEDEP}]
swift? (
>=dev-python/python-swiftclient-1.6[${PYTHON_USEDEP}]
)
dev-python/paste[${PYTHON_USEDEP}]
>=dev-python/jsonschema-2.0.0[${PYTHON_USEDEP}]
<dev-python/jsonschema-3.0.0[${PYTHON_USEDEP}]
>=dev-python/python-cinderclient-1.0.6[${PYTHON_USEDEP}]
>=dev-python/python-keystoneclient-0.7.0[${PYTHON_USEDEP}]
>=dev-python/pyopenssl-0.11[${PYTHON_USEDEP}]
>=dev-python/six-1.5.2[${PYTHON_USEDEP}]
>=dev-python/oslo-messaging-1.3.0[${PYTHON_USEDEP}]
dev-python/oslo-vmware[${PYTHON_USEDEP}] "
PATCHES=( "${FILESDIR}/${PN}-2013.2-sphinx_mapping.patch" )
PATCHES=( "${FILESDIR}/2014.1.2-CVE-2014-5356.patch" )
pkg_setup() {
enewgroup glance
enewuser glance -1 -1 /var/lib/glance glance
}
python_compile_all() {
use doc && "${PYTHON}" setup.py build_sphinx
}
python_test() {
# https://bugs.launchpad.net/glance/+bug/1251105
# https://bugs.launchpad.net/glance/+bug/1242501
nosetests glance/ || die "tests failed under python2.7"
}
python_install() {
distutils-r1_python_install
for svc in api registry scrubber; do
newinitd "${FILESDIR}/glance.initd" glance-${svc}
done
diropts -m 0750 -o glance -g glance
dodir /var/log/glance /var/lib/glance/images /var/lib/glance/scrubber
keepdir /etc/glance
keepdir /var/log/glance
keepdir /var/lib/glance/images
keepdir /var/lib/glance/scrubber
insinto /etc/glance
insopts -m 0640 -o glance -g glance
doins "etc/glance-api-paste.ini"
doins "etc/glance-api.conf"
doins "etc/glance-cache.conf"
doins "etc/glance-registry-paste.ini"
doins "etc/glance-registry.conf"
doins "etc/glance-scrubber.conf"
doins "etc/logging.cnf.sample"
doins "etc/policy.json"
doins "etc/schema-image.json"
}
python_install_all() {
use doc && local HTML_DOCS=( doc/build/html/. )
distutils-r1_python_install_all
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-08-21 20:40 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-08-21 20:40 [gentoo-commits] gentoo-x86 commit in app-admin/glance: glance-2014.1.2.ebuild ChangeLog glance-2014.1.1.ebuild Matt Thode (prometheanfire)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox