[gentoo-commits] gentoo-x86 commit in dev-python/colander: colander-1.0_beta1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-python/colander: colander-1.0_beta1.ebuild ChangeLog

[Ian Delaney (idella4)]

idella4     14/08/21 01:30:14

  Modified:             ChangeLog
  Added:                colander-1.0_beta1.ebuild
  Log:
  bump; drop py2.6 pypy2_0 add py3.4, tidy
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.12                 dev-python/colander/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/colander/ChangeLog?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/colander/ChangeLog?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/colander/ChangeLog?r1=1.11&r2=1.12

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/colander/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog	31 Mar 2014 20:50:55 -0000	1.11
+++ ChangeLog	21 Aug 2014 01:30:14 -0000	1.12
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/colander
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/colander/ChangeLog,v 1.11 2014/03/31 20:50:55 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/colander/ChangeLog,v 1.12 2014/08/21 01:30:14 idella4 Exp $
+
+*colander-1.0_beta1 (21 Aug 2014)
+
+  21 Aug 2014; Ian Delaney <idella4@gentoo.org> +colander-1.0_beta1.ebuild:
+  bump; drop py2.6 pypy2_0 add py3.4, tidy
 
   31 Mar 2014; Michał Górny <mgorny@gentoo.org> colander-1.0_alpha1-r1.ebuild:
   Add support for the new PyPy slotting.



1.1                  dev-python/colander/colander-1.0_beta1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/colander/colander-1.0_beta1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/colander/colander-1.0_beta1.ebuild?rev=1.1&content-type=text/plain

Index: colander-1.0_beta1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/colander/colander-1.0_beta1.ebuild,v 1.1 2014/08/21 01:30:14 idella4 Exp $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} pypy )

inherit distutils-r1

DESCRIPTION="A simple schema-based serialization and deserialization library"
HOMEPAGE="http://docs.pylonsproject.org/projects/colander/en/latest/ http://pypi.python.org/pypi/colander"
MY_P=${P/_beta1/b1}
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"

S="${WORKDIR}/${MY_P}"

# MIT license is used by included (modified) iso8601.py code.
LICENSE="repoze MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc test"

# Depend on an ebuild of translationstring with Python 3 support.
RDEPEND=">=dev-python/translationstring-1.1[${PYTHON_USEDEP}]"

DEPEND="${RDEPEND}
	dev-python/setuptools[${PYTHON_USEDEP}]
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
	test? ( dev-python/nose[${PYTHON_USEDEP}] )"

# Include COPYRIGHT.txt because the license seems to require it.
DOCS=( CHANGES.txt COPYRIGHT.txt README.txt )

python_prepare_all() {
	# Remove pylons theme since it's not included in source
	sed -e "/# Add and use Pylons theme/,+37d" -i docs/conf.py || die

	distutils-r1_python_prepare_all
}

python_compile_all() {
	if use doc; then
		# https://github.com/Pylons/colander/issues/38
		emake -C docs html SPHINXOPTS=""
	fi
}

python_test() {
	nosetests || die "Tests fail with ${EPYTHON}"
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/_build/html/. )
	distutils-r1_python_install_all
}