[gentoo-commits] gentoo-x86 commit in app-editors/focuswriter: ChangeLog focuswriter-1.5.3.ebuild

[gentoo-commits] gentoo-x86 commit in app-editors/focuswriter: ChangeLog focuswriter-1.5.3.ebuild

[Sergey Popov (pinkbyte)]

pinkbyte    14/08/20 09:22:47

  Modified:             ChangeLog
  Added:                focuswriter-1.5.3.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

Revision  Changes    Path
1.21                 app-editors/focuswriter/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/focuswriter/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/focuswriter/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/focuswriter/ChangeLog?r1=1.20&r2=1.21

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/focuswriter/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog	31 Jul 2014 14:07:24 -0000	1.20
+++ ChangeLog	20 Aug 2014 09:22:47 -0000	1.21
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/focuswriter
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/focuswriter/ChangeLog,v 1.20 2014/07/31 14:07:24 pinkbyte Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/focuswriter/ChangeLog,v 1.21 2014/08/20 09:22:47 pinkbyte Exp $
+
+*focuswriter-1.5.3 (20 Aug 2014)
+
+  20 Aug 2014; Sergey Popov <pinkbyte@gentoo.org> +focuswriter-1.5.3.ebuild:
+  Version bump
 
 *focuswriter-1.5.2-r1 (31 Jul 2014)
 



1.1                  app-editors/focuswriter/focuswriter-1.5.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/focuswriter/focuswriter-1.5.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/focuswriter/focuswriter-1.5.3.ebuild?rev=1.1&content-type=text/plain

Index: focuswriter-1.5.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/focuswriter/focuswriter-1.5.3.ebuild,v 1.1 2014/08/20 09:22:47 pinkbyte Exp $

EAPI=5

PLOCALES="ar ca cs da de el en en_GB es_MX es fi fr he hu hy id it ja ko nl pl
pt_BR pt ro ru sk sr sv tr uk vi zh_CN zh_TW"
PLOCALE_BACKUP="en"
inherit fdo-mime gnome2-utils l10n readme.gentoo qt4-r2

DESCRIPTION="A fullscreen and distraction-free word processor"
HOMEPAGE="http://gottcode.org/focuswriter/"
SRC_URI="http://gottcode.org/${PN}/${P}-src.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

RDEPEND="app-text/hunspell
	dev-qt/qtcore:4
	dev-qt/qtgui:4
	dev-qt/qtsingleapplication[X]
	sys-libs/zlib"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

DOCS=( ChangeLog CREDITS NEWS README )
DOC_CONTENTS="Focuswriter has optional sound support if media-libs/sdl-mixer is
installed with wav useflag enabled."

PATCHES=( "${FILESDIR}/${PN}-1.5.2-unbundle-qtsingleapplication.patch" )

rm_loc() {
	sed -e "s|translations/${PN}_${1}.ts||"	-i ${PN}.pro || die 'sed failed'
	rm translations/${PN}_${1}.{ts,qm} || die "removing ${1} locale failed"
}

src_prepare() {
	l10n_for_each_disabled_locale_do rm_loc
	qt4-r2_src_prepare
}

src_configure() {
	eqmake4 PREFIX="${EPREFIX}/usr"
}

src_install() {
	readme.gentoo_create_doc
	qt4-r2_src_install
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	readme.gentoo_pkg_postinst
	gnome2_icon_cache_update
	fdo-mime_desktop_database_update
}

pkg_postrm() {
	gnome2_icon_cache_update
	fdo-mime_desktop_database_update
}