[gentoo-commits] gentoo-x86 commit in app-accessibility/speech-dispatcher: ChangeLog speech-dispatcher-0.8-r3.ebuild

[gentoo-commits] gentoo-x86 commit in app-accessibility/speech-dispatcher: ChangeLog speech-dispatcher-0.8-r3.ebuild

[Christopher Brannon (teiresias)]

teiresias    14/08/10 22:02:42

  Modified:             ChangeLog
  Added:                speech-dispatcher-0.8-r3.ebuild
  Log:
  Add python 3.4 support.
  
  Closes bug #517448.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x6521e06d)

Revision  Changes    Path
1.103                app-accessibility/speech-dispatcher/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/speech-dispatcher/ChangeLog?rev=1.103&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/speech-dispatcher/ChangeLog?rev=1.103&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/speech-dispatcher/ChangeLog?r1=1.102&r2=1.103

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-accessibility/speech-dispatcher/ChangeLog,v
retrieving revision 1.102
retrieving revision 1.103
diff -u -r1.102 -r1.103
--- ChangeLog	31 Mar 2014 20:26:38 -0000	1.102
+++ ChangeLog	10 Aug 2014 22:02:42 -0000	1.103
@@ -1,6 +1,14 @@
 # ChangeLog for app-accessibility/speech-dispatcher
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-accessibility/speech-dispatcher/ChangeLog,v 1.102 2014/03/31 20:26:38 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/speech-dispatcher/ChangeLog,v 1.103 2014/08/10 22:02:42 teiresias Exp $
+
+*speech-dispatcher-0.8-r3 (10 Aug 2014)
+
+  10 Aug 2014; Christopher Brannon <teiresias@gentoo.org>
+  +speech-dispatcher-0.8-r3.ebuild:
+  Add python 3.4 support.
+
+  Closes bug #517448.
 
   31 Mar 2014; Michał Górny <mgorny@gentoo.org>
   speech-dispatcher-0.7.1-r2.ebuild:



1.1                  app-accessibility/speech-dispatcher/speech-dispatcher-0.8-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/speech-dispatcher/speech-dispatcher-0.8-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/speech-dispatcher/speech-dispatcher-0.8-r3.ebuild?rev=1.1&content-type=text/plain

Index: speech-dispatcher-0.8-r3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-accessibility/speech-dispatcher/speech-dispatcher-0.8-r3.ebuild,v 1.1 2014/08/10 22:02:42 teiresias Exp $

EAPI=5

PYTHON_COMPAT=( python3_2 python3_3 python3_4 )

inherit eutils python-r1

DESCRIPTION="Speech synthesis interface"
HOMEPAGE="http://www.freebsoft.org/speechd"
SRC_URI="http://www.freebsoft.org/pub/projects/speechd/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="alsa ao +espeak flite nas pulseaudio python static-libs"

REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

COMMON_DEPEND="python? ( ${PYTHON_DEPS} )
	>=dev-libs/dotconf-1.3
	>=dev-libs/glib-2.28:2
	>=media-libs/libsndfile-1.0.2
	alsa? ( media-libs/alsa-lib )
	ao? ( media-libs/libao )
	espeak? ( app-accessibility/espeak )
	flite? ( app-accessibility/flite )
	nas? ( media-libs/nas )
	pulseaudio? ( media-sound/pulseaudio )"
DEPEND="${COMMON_DEPEND}
	>=dev-util/intltool-0.40.0
	virtual/pkgconfig"
	RDEPEND="${COMMON_DEPEND}"

src_configure() {
	local myeconfargs=(
		--disable-python
		$(use_enable static-libs static)
		$(use_with alsa)
		$(use_with ao libao)
		$(use_with espeak)
		$(use_with flite)
		$(use_with pulseaudio pulse)
		$(use_with nas)
	)
	econf ${myeconfargs[@]}
}

src_compile() {
	use python && python_copy_sources

	emake

	if use python; then
		building() {
			cd src/api/python || die
			emake \
				pyexecdir="$(python_get_sitedir)" \
				pythondir="$(python_get_sitedir)"
		}
		python_foreach_impl run_in_build_dir building
	fi
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc ANNOUNCE AUTHORS BUGS ChangeLog FAQ NEWS README*

	prune_libtool_files --all

	if use python; then
		installation() {
			cd src/api/python || die
			emake \
				DESTDIR="${D}" \
				pyexecdir="$(python_get_sitedir)" \
				pythondir="$(python_get_sitedir)" \
				install
		}
		python_foreach_impl run_in_build_dir installation
		python_replicate_script "${ED}"/usr/bin/spd-conf
	fi
}

pkg_postinst() {
	local editconfig="n"
	if ! use espeak; then
		ewarn "You have disabled espeak, which is speech-dispatcher's"
		ewarn "default speech synthesizer."
		ewarn
		editconfig="y"
	fi
	if ! use pulseaudio; then
		ewarn "You have disabled pulseaudio support."
		ewarn "pulseaudio is speech-dispatcher's default audio subsystem."
		ewarn
		editconfig="y"
	fi
	if [[ "${editconfig}" == "y" ]]; then
		ewarn "You must edit ${EROOT}etc/speech-dispatcher/speechd.conf"
		ewarn "and make sure the settings there match your system."
		ewarn
	fi
	elog "For festival support, you need to"
	elog "install app-accessibility/festival-freebsoft-utils."
}