[gentoo-commits] gentoo-x86 commit in dev-vcs/git-cola: git-cola-2.0.5-r1.ebuild ChangeLog git-cola-2.0.3.ebuild git-cola-2.0.2.ebuild git-cola-2.0.1.ebuild git-cola-2.0.5.ebuild git-cola-2.0.0.ebuild

[gentoo-commits] gentoo-x86 commit in dev-vcs/git-cola: git-cola-2.0.5-r1.ebuild ChangeLog git-cola-2.0.3.ebuild git-cola-2.0.2.ebuild git-cola-2.0.1.ebuild git-cola-2.0.5.ebuild git-cola-2.0.0.ebuild

[Tiziano Mueller (dev-zero)]

dev-zero    14/08/10 07:13:52

  Modified:             ChangeLog
  Added:                git-cola-2.0.5-r1.ebuild
  Removed:              git-cola-2.0.3.ebuild git-cola-2.0.2.ebuild
                        git-cola-2.0.1.ebuild git-cola-2.0.5.ebuild
                        git-cola-2.0.0.ebuild
  Log:
  Fix shebang of rebase-helper (bug #519514), optimize python modules in non-standard location. Drop old.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x1A5D023975B0583D!)

Revision  Changes    Path
1.31                 dev-vcs/git-cola/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-vcs/git-cola/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	27 Jul 2014 08:26:35 -0000	1.30
+++ ChangeLog	10 Aug 2014 07:13:51 -0000	1.31
@@ -1,6 +1,14 @@
 # ChangeLog for dev-vcs/git-cola
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git-cola/ChangeLog,v 1.30 2014/07/27 08:26:35 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git-cola/ChangeLog,v 1.31 2014/08/10 07:13:51 dev-zero Exp $
+
+*git-cola-2.0.5-r1 (10 Aug 2014)
+
+  10 Aug 2014; Tiziano Müller <dev-zero@gentoo.org> +git-cola-2.0.5-r1.ebuild,
+  -git-cola-2.0.0.ebuild, -git-cola-2.0.1.ebuild, -git-cola-2.0.2.ebuild,
+  -git-cola-2.0.3.ebuild, -git-cola-2.0.5.ebuild:
+  Fix shebang of rebase-helper (bug #519514), optimize python modules in non-
+  standard location. Drop old.
 
 *git-cola-2.0.5 (27 Jul 2014)
 



1.1                  dev-vcs/git-cola/git-cola-2.0.5-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/git-cola-2.0.5-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/git-cola/git-cola-2.0.5-r1.ebuild?rev=1.1&content-type=text/plain

Index: git-cola-2.0.5-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git-cola/git-cola-2.0.5-r1.ebuild,v 1.1 2014/08/10 07:13:51 dev-zero Exp $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_3} )
DISTUTILS_SINGLE_IMPL=true

inherit distutils-r1 readme.gentoo virtualx

DESCRIPTION="The highly caffeinated git GUI"
HOMEPAGE="http://git-cola.github.com/"
SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc test"

RDEPEND="
	dev-python/jsonpickle[${PYTHON_USEDEP}]
	dev-python/pyinotify[${PYTHON_USEDEP}]
	dev-python/PyQt4[${PYTHON_USEDEP}]
	dev-vcs/git"
DEPEND="${RDEPEND}
	app-text/asciidoc
	app-text/xmlto
	sys-devel/gettext
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
	test? (
		dev-python/nose[${PYTHON_USEDEP}]
		sys-apps/net-tools
		)"

PATCHES=(
	"${FILESDIR}"/${PN}-1.9.3-disable-tests.patch
	"${FILESDIR}"/${PN}-1.9.1-system-ssh-askpass.patch
	)

pkg_pretend() {
	if use test && [[ -z "$(hostname -d)" ]] ; then
		die "Test will fail if no domain is set"
	fi
}

python_prepare_all() {
	rm share/git-cola/bin/*askpass* || die

	# unfinished translate framework
	rm test/i18n_test.py || die

	# don't install docs into wrong location
	sed -i \
		-e '/doc/d' \
		setup.py || die "sed failed"

	sed -i \
		-e  "s|'doc', 'git-cola'|'doc', '${PF}'|" \
		cola/resources.py || die "sed failed"

	distutils-r1_python_prepare_all
}

python_compile_all() {
	cd share/doc/${PN}/
	if use doc ; then
		emake all
	else
		sed \
			-e '/^install:/s:install-html::g' \
			-e '/^install:/s:install-man::g' \
			-i Makefile || die
	fi
}

src_install() {
	distutils-r1_src_install
}

python_install_all() {
	cd share/doc/${PN}/ || die
	emake \
		DESTDIR="${D}" \
		docdir="${EPREFIX}/usr/share/doc/${PF}" \
		prefix="${EPREFIX}/usr" \
		install

	python_fix_shebang "${D}/usr/share/git-cola/bin/git-xbase"
	python_optimize "${D}/usr/share/git-cola/lib/cola"

	if ! use doc ; then
		HTML_DOCS=( "${FILESDIR}"/index.html )
	fi

	distutils-r1_python_install_all
	readme.gentoo_create_doc
	docompress /usr/share/doc/${PF}/git-cola.txt
}

python_test() {
	PYTHONPATH="${S}:${S}/build/lib:${PYTHONPATH}" LC_ALL="C" \
		VIRTUALX_COMMAND="nosetests --verbose --with-doctest \
		--with-id --exclude=jsonpickle --exclude=json" \
		virtualmake
}