[gentoo-commits] gentoo-x86 commit in dev-libs/mongo-c-driver: ChangeLog mongo-c-driver-0.98.0.ebuild

[gentoo-commits] gentoo-x86 commit in dev-libs/mongo-c-driver: ChangeLog mongo-c-driver-0.98.0.ebuild

[Alexys Jacob (ultrabug)]

ultrabug    14/07/23 16:15:27

  Modified:             ChangeLog
  Added:                mongo-c-driver-0.98.0.ebuild
  Log:
  version bump wrt #505280 thx to Johan Bergstrom
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key B658FA13)

Revision  Changes    Path
1.11                 dev-libs/mongo-c-driver/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/mongo-c-driver/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/mongo-c-driver/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/mongo-c-driver/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/mongo-c-driver/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	14 Jun 2014 09:57:35 -0000	1.10
+++ ChangeLog	23 Jul 2014 16:15:27 -0000	1.11
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/mongo-c-driver
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/mongo-c-driver/ChangeLog,v 1.10 2014/06/14 09:57:35 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/mongo-c-driver/ChangeLog,v 1.11 2014/07/23 16:15:27 ultrabug Exp $
+
+*mongo-c-driver-0.98.0 (23 Jul 2014)
+
+  23 Jul 2014; Ultrabug <ultrabug@gentoo.org> +mongo-c-driver-0.98.0.ebuild:
+  version bump wrt #505280 thx to Johan Bergström
 
   14 Jun 2014; Pawel Hajdan jr <phajdan.jr@gentoo.org>
   mongo-c-driver-0.7.1.ebuild:



1.1                  dev-libs/mongo-c-driver/mongo-c-driver-0.98.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/mongo-c-driver/mongo-c-driver-0.98.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/mongo-c-driver/mongo-c-driver-0.98.0.ebuild?rev=1.1&content-type=text/plain

Index: mongo-c-driver-0.98.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/mongo-c-driver/mongo-c-driver-0.98.0.ebuild,v 1.1 2014/07/23 16:15:27 ultrabug Exp $

EAPI=5

inherit autotools eutils

DESCRIPTION="A high-performance MongoDB driver for C"
HOMEPAGE="https://github.com/mongodb/mongo-c-driver"
SRC_URI="https://github.com/mongodb/${PN}/releases/download/${PV}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug examples sasl ssl static-libs test"

RDEPEND=">=dev-libs/libbson-0.98.0
	sasl? ( dev-libs/cyrus-sasl )
	ssl? ( dev-libs/openssl )"
DEPEND="${RDEPEND}
	test? ( dev-db/mongodb )"

DOCS=( NEWS README.rst TUTORIAL.md )

src_prepare() {
	# https://github.com/mongodb/mongo-c-driver/issues/54
	sed -i -e "s/PTHREAD_LIBS/PTHREAD_CFLAGS/g" src/Makefile.am \
		tests/Makefile.am || die
	eautoreconf
}

src_configure() {
	econf --disable-hardening \
		--disable-optimizations \
		--disable-examples \
		$(use_enable sasl) \
		$(use_enable ssl) \
		$(use_enable debug) \
		$(use_enable static-libs static)
}

src_install() {
	emake DESTDIR="${D}" install
	doman doc/*.3

	use static-libs || find "${D}" -name '*.la' -delete

	if use examples; then
		insinto /usr/share/${PF}/examples
		doins -r examples/*.c examples/aggregation examples/bulk
	fi
}

src_test() {
	# Avoid allocating too much disk space by using server.smallFiles = 1
	echo -e "storage:\n    smallFiles: true" > "${T}/mongod.conf"
	local PORT=27099
	mongod --port ${PORT} --bind_ip 127.0.0.1 --nounixsocket --fork \
		-f "${T}/mongod.conf" --dbpath="${T}" \
		--logpath="${T}/mongod.log" || die
	MONGOC_TEST_HOST="127.0.0.1:${PORT}" emake test
	kill `cat "${T}/mongod.lock"`
}