From: "Tom Wijsman (tomwij)" <tomwij@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] gentoo-x86 commit in mate-extra/caja-dropbox: caja-dropbox-1.8.0.ebuild ChangeLog
Date: Tue, 22 Jul 2014 19:04:55 +0000 (UTC) [thread overview]
Message-ID: <20140722190455.C97622004E@flycatcher.gentoo.org> (raw)
tomwij 14/07/22 19:04:55
Modified: ChangeLog
Added: caja-dropbox-1.8.0.ebuild
Log:
Version bump to 1.8.0; fixes bug #510464, reported by nihil39.
(Portage version: 2.2.10_p125/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)
Revision Changes Path
1.3 mate-extra/caja-dropbox/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-extra/caja-dropbox/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-extra/caja-dropbox/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-extra/caja-dropbox/ChangeLog?r1=1.2&r2=1.3
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mate-extra/caja-dropbox/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog 4 May 2014 14:54:15 -0000 1.2
+++ ChangeLog 22 Jul 2014 19:04:55 -0000 1.3
@@ -1,6 +1,12 @@
# ChangeLog for mate-extra/caja-dropbox
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mate-extra/caja-dropbox/ChangeLog,v 1.2 2014/05/04 14:54:15 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/mate-extra/caja-dropbox/ChangeLog,v 1.3 2014/07/22 19:04:55 tomwij Exp $
+
+*caja-dropbox-1.8.0 (22 Jul 2014)
+
+ 22 Jul 2014; Tom Wijsman <TomWij@gentoo.org> +caja-dropbox-1.8.0.ebuild,
+ +files/caja-dropbox-1.8.0-system-rst2man.patch:
+ Version bump to 1.8.0; fixes bug #510464, reported by nihil39.
04 May 2014; Agostino Sarubbo <ago@gentoo.org> caja-dropbox-0.7.1.ebuild:
Stable for amd64, wrt bug #509268
1.1 mate-extra/caja-dropbox/caja-dropbox-1.8.0.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-extra/caja-dropbox/caja-dropbox-1.8.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-extra/caja-dropbox/caja-dropbox-1.8.0.ebuild?rev=1.1&content-type=text/plain
Index: caja-dropbox-1.8.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mate-extra/caja-dropbox/caja-dropbox-1.8.0.ebuild,v 1.1 2014/07/22 19:04:55 tomwij Exp $
EAPI="5"
PYTHON_COMPAT=( python2_{6,7} )
GNOME2_LA_PUNT="yes"
inherit autotools eutils gnome2 python-single-r1 linux-info user versionator
MATE_BRANCH="1.8"
SRC_URI="http://pub.mate-desktop.org/releases/${MATE_BRANCH}/${P}.tar.xz"
DESCRIPTION="Store, Sync and Share Files Online"
HOMEPAGE="http://www.dropbox.com/"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="debug"
RDEPEND="
dev-libs/atk:0
>=dev-libs/glib-2.14:2
dev-python/pygtk:2[${PYTHON_USEDEP}]
|| ( >=mate-base/caja-1.8:0 >=mate-base/mate-file-manager-1.6:0 )
media-libs/fontconfig:1.0
media-libs/freetype:2
net-misc/dropbox:0
x11-libs/cairo:0
x11-libs/gdk-pixbuf:2
x11-libs/gtk+:2
x11-libs/libXinerama:0
x11-libs/pango:0"
DEPEND="${RDEPEND}
dev-python/docutils:0
virtual/pkgconfig:*"
G2CONF="${G2CONF} $(use_enable debug) --disable-static"
CONFIG_CHECK="~INOTIFY_USER"
pkg_setup () {
python-single-r1_pkg_setup
check_extra_config
enewgroup dropbox
}
src_prepare() {
gnome2_src_prepare
# Use system dropbox.
sed -e "s|~/[.]dropbox-dist|/opt/dropbox|" \
-e 's|\(DROPBOXD_PATH = \).*|\1"/opt/dropbox/dropboxd"|' \
-i caja-dropbox.in || die
# Use system rst2man.
epatch "${FILESDIR}"/${P}-system-rst2man.patch
AT_NOELIBTOOLIZE=yes eautoreconf
}
DOCS="AUTHORS ChangeLog NEWS README"
src_install () {
python_fix_shebang caja-dropbox.in
gnome2_src_install
local extensiondir="$(pkg-config --variable=extensiondir libcaja-extension)"
[ -z ${extensiondir} ] && die "pkg-config unable to get caja extensions dir"
# Strip $EPREFIX from $extensiondir as fowners/fperms act on $ED not $D.
extensiondir="${extensiondir#${EPREFIX}}"
use prefix || fowners root:dropbox "${extensiondir}"/libcaja-dropbox.so
fperms o-rwx "${extensiondir}"/libcaja-dropbox.so
}
pkg_postinst () {
gnome2_pkg_postinst
elog
elog "Add any users who wish to have access to the dropbox caja"
elog "plugin to the group 'dropbox'. You need to setup a drobox account"
elog "before using this plugin. Visit ${HOMEPAGE} for more information."
elog
}
next reply other threads:[~2014-07-22 19:04 UTC|newest]
Thread overview: 3+ messages / expand[flat|nested] mbox.gz Atom feed top
2014-07-22 19:04 Tom Wijsman (tomwij) [this message]
-- strict thread matches above, loose matches on Subject: below --
2015-04-08 18:13 [gentoo-commits] gentoo-x86 commit in mate-extra/caja-dropbox: caja-dropbox-1.8.0.ebuild ChangeLog Michal Gorny (mgorny)
2015-07-11 23:57 NP Hardass (np-hardass)
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20140722190455.C97622004E@flycatcher.gentoo.org \
--to=tomwij@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox