[gentoo-commits] gentoo-x86 commit in dev-python/qscintilla-python: qscintilla-python-2.8.3.ebuild ChangeLog qscintilla-python-2.8.ebuild

[gentoo-commits] gentoo-x86 commit in dev-python/qscintilla-python: qscintilla-python-2.8.3.ebuild ChangeLog qscintilla-python-2.8.ebuild

[Davide Pesavento (pesa)]

pesa        14/07/18 22:15:47

  Modified:             ChangeLog
  Added:                qscintilla-python-2.8.3.ebuild
  Removed:              qscintilla-python-2.8.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xDADED6B2671CB57D!)

Revision  Changes    Path
1.109                dev-python/qscintilla-python/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/qscintilla-python/ChangeLog?rev=1.109&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/qscintilla-python/ChangeLog?rev=1.109&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/qscintilla-python/ChangeLog?r1=1.108&r2=1.109

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/qscintilla-python/ChangeLog,v
retrieving revision 1.108
retrieving revision 1.109
diff -u -r1.108 -r1.109
--- ChangeLog	24 Dec 2013 19:24:56 -0000	1.108
+++ ChangeLog	18 Jul 2014 22:15:47 -0000	1.109
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/qscintilla-python
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/qscintilla-python/ChangeLog,v 1.108 2013/12/24 19:24:56 pesa Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/qscintilla-python/ChangeLog,v 1.109 2014/07/18 22:15:47 pesa Exp $
+
+*qscintilla-python-2.8.3 (18 Jul 2014)
+
+  18 Jul 2014; Davide Pesavento <pesa@gentoo.org>
+  +qscintilla-python-2.8.3.ebuild, -qscintilla-python-2.8.ebuild:
+  Version bump.
 
   24 Dec 2013; Davide Pesavento <pesa@gentoo.org>
   -files/qscintilla-python-2.5.1-disable_stripping.patch,



1.1                  dev-python/qscintilla-python/qscintilla-python-2.8.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/qscintilla-python/qscintilla-python-2.8.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/qscintilla-python/qscintilla-python-2.8.3.ebuild?rev=1.1&content-type=text/plain

Index: qscintilla-python-2.8.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/qscintilla-python/qscintilla-python-2.8.3.ebuild,v 1.1 2014/07/18 22:15:47 pesa Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )

inherit python-r1 qmake-utils

MY_P=QScintilla-gpl-${PV}

DESCRIPTION="Python bindings for Qscintilla"
HOMEPAGE="http://www.riverbankcomputing.co.uk/software/qscintilla/intro"
SRC_URI="mirror://sourceforge/pyqt/${MY_P}.tar.gz"

LICENSE="|| ( GPL-2 GPL-3 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="debug"

DEPEND="
	${PYTHON_DEPS}
	>=dev-python/sip-4.16:=[${PYTHON_USEDEP}]
	>=dev-python/PyQt4-4.11[X,${PYTHON_USEDEP}]
	dev-qt/qtcore:4
	dev-qt/qtgui:4
	~x11-libs/qscintilla-${PV}:=
"
RDEPEND="${DEPEND}"

REQUIRED_USE="${PYTHON_REQUIRED_USE}"

S=${WORKDIR}/${MY_P}/Python

src_prepare() {
	python_copy_sources
}

src_configure() {
	configuration() {
		local myconf=(
			"${PYTHON}" configure.py
			--destdir="$(python_get_sitedir)"/PyQt4
			--pyqt=PyQt4
			--sip-incdir="$(python_get_includedir)"
			--pyqt-sipdir="${EPREFIX}"/usr/share/sip
			--qsci-sipdir="${EPREFIX}"/usr/share/sip
			$(use debug && echo --debug)
			--no-timestamp
		)
		echo "${myconf[@]}"
		"${myconf[@]}" || die

		# Run eqmake4 to respect toolchain, build flags, and prevent stripping
		eqmake4
	}
	python_parallel_foreach_impl run_in_build_dir configuration
}

src_compile() {
	python_foreach_impl run_in_build_dir default
}

src_install() {
	installation() {
		emake INSTALL_ROOT="${D}" install
		python_optimize
	}
	python_foreach_impl run_in_build_dir installation
}