[gentoo-commits] gentoo-x86 commit in dev-python/kombu: kombu-3.0.21.ebuild metadata.xml ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-python/kombu: kombu-3.0.21.ebuild metadata.xml ChangeLog

[Ian Delaney (idella4)]

idella4     14/07/17 02:33:34

  Modified:             metadata.xml ChangeLog
  Added:                kombu-3.0.21.ebuild
  Log:
  bump; add optional deps pyro:4, pyzmq
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.6                  dev-python/kombu/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/kombu/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/kombu/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/kombu/metadata.xml?r1=1.5&r2=1.6

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/kombu/metadata.xml,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- metadata.xml	31 Mar 2014 09:05:43 -0000	1.5
+++ metadata.xml	17 Jul 2014 02:33:34 -0000	1.6
@@ -8,7 +8,7 @@
 	</upstream>
 	<use>
 		<flag name="amqplib">Enable amqplib support</flag>
-		<flag name="sqs">enables Amazon SQS transport module for Kombu</flag>
-		<flag name="msgpack">enables MessagePack (de)serializer for Python</flag>
+		<flag name="sqs">Enables Amazon SQS transport module for Kombu</flag>
+		<flag name="msgpack">Enables MessagePack (de)serializer for Python</flag>
 	</use>
 </pkgmetadata>



1.39                 dev-python/kombu/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/kombu/ChangeLog?rev=1.39&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/kombu/ChangeLog?rev=1.39&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/kombu/ChangeLog?r1=1.38&r2=1.39

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/kombu/ChangeLog,v
retrieving revision 1.38
retrieving revision 1.39
diff -u -r1.38 -r1.39
--- ChangeLog	1 Jul 2014 04:04:36 -0000	1.38
+++ ChangeLog	17 Jul 2014 02:33:34 -0000	1.39
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/kombu
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/kombu/ChangeLog,v 1.38 2014/07/01 04:04:36 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/kombu/ChangeLog,v 1.39 2014/07/17 02:33:34 idella4 Exp $
+
+*kombu-3.0.21 (17 Jul 2014)
+
+  17 Jul 2014; Ian Delaney <idella4@gentoo.org> +kombu-3.0.21.ebuild,
+  metadata.xml:
+  bump; add optional deps pyro:4, pyzmq
 
   01 Jul 2014; Patrick Lauer <patrick@gentoo.org> -kombu-2.5.14.ebuild:
   Remove old version with unsatisfiable dependencies



1.1                  dev-python/kombu/kombu-3.0.21.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/kombu/kombu-3.0.21.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/kombu/kombu-3.0.21.ebuild?rev=1.1&content-type=text/plain

Index: kombu-3.0.21.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/kombu/kombu-3.0.21.ebuild,v 1.1 2014/07/17 02:33:34 idella4 Exp $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )

inherit distutils-r1

DESCRIPTION="AMQP Messaging Framework for Python"
HOMEPAGE="http://pypi.python.org/pypi/kombu https://github.com/celery/kombu"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="amqplib doc examples msgpack sqs test"

PY27_GEN_USEDEP=$(python_gen_usedep python2_7)
RDEPEND=">=dev-python/anyjson-0.3.3[${PYTHON_USEDEP}]
		>=dev-python/py-amqp-1.4.5[${PYTHON_USEDEP}]
		<dev-python/py-amqp-2.0[${PYTHON_USEDEP}]
		dev-python/pyro:4[${PYTHON_USEDEP}]
		$(python_gen_cond_dep '>=dev-python/pyzmq-13.1.0[${PYTHON_USEDEP}]' python2_7 python{3_3,3_4})
		amqplib? ( >=dev-python/amqplib-1.0.2[${PYTHON_USEDEP}] )
		sqs? ( >=dev-python/boto-2.13.3[${PY27_GEN_USEDEP}] )
		msgpack? ( >=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}] )"

DEPEND="${RDEPEND}
	>=dev-python/setuptools-0.7[${PYTHON_USEDEP}]
	test? ( dev-python/nose[${PYTHON_USEDEP}]
		dev-python/nose-cover3[${PYTHON_USEDEP}]
		>=dev-python/mock-0.7[${PYTHON_USEDEP}]
		dev-python/django[${PYTHON_USEDEP}]
		>=dev-python/redis-py-2.8.0[${PYTHON_USEDEP}]
		>=dev-python/pymongo-2.6.2[${PYTHON_USEDEP}]
		>=dev-python/unittest2-0.5.0[${PYTHON_USEDEP}] )
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}]
		dev-python/django[${PYTHON_USEDEP}]
		dev-python/beanstalkc[${PY27_GEN_USEDEP}]
		dev-python/couchdb-python[${PY27_GEN_USEDEP}]
		>=dev-python/sphinxcontrib-issuetracker-0.9[${PYTHON_USEDEP}] )"

# pyyaml is an optional package for tests,so also kazoo, refrain for now
# Req'd for test phase
DISTUTILS_IN_SOURCE_BUILD=1

PY27_REQUSE="$(python_gen_useflags 'python2.7')"
REQUIRED_USE="sqs? ( ${PY27_REQUSE} )
		doc? ( ${PY27_REQUSE} amqplib sqs )"	# 2 deps in doc build are only py2 capable

PATCHES=( "${FILESDIR}"/${PN}-NA-tests-fix.patch )

python_prepare_all() {
	https://github.com/celery/kombu/issues/246
	sed -e 's:kombu.transports:kombu.transport:' -i funtests/tests/test_django.py
	distutils-r1_python_prepare_all
}

python_compile_all() {
	# Doc build must be done by py2.7
	# Doc build misses and skips only content re librabbitmq which is not in portage
	if use doc; then
		emake -C docs html || die "kombu docs failed installation"
	fi
}

python_test() {
	export DJANGO_SETTINGS_MODULE="django.conf"
	if python_is_python3; then
		2to3 --no-diffs -w build/lib/kombu/transport/
		nosetests --py3where=build/lib kombu/tests || die "Tests failed under ${EPYTHON}"
	else
		nosetests "${S}"/kombu/tests || die "Tests failed under ${EPYTHON}"
		# funtests appears to be coded only for py2, a kind of 2nd tier. pypy fails 6.
		if [[ "${EPYTHON}" == python2.7 ]]; then
			pushd funtests > /dev/null
			esetup.py test
			popd > /dev/null
		fi
	fi
}

python_install_all() {
	use examples && local EXAMPLES=( examples/. )
	use doc && local HTML_DOCS=( docs/.build/html/. )
	distutils-r1_python_install_all
}