[gentoo-commits] gentoo-x86 commit in kde-base/gwenview: ChangeLog gwenview-4.13.3.ebuild

[gentoo-commits] gentoo-x86 commit in kde-base/gwenview: ChangeLog gwenview-4.13.3.ebuild

[Johannes Huber (johu)]

johu        14/07/16 17:40:28

  Modified:             ChangeLog
  Added:                gwenview-4.13.3.ebuild
  Log:
  Version bump KDE SC 4.13.3
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xF3CFD2BD)

Revision  Changes    Path
1.240                kde-base/gwenview/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/ChangeLog?rev=1.240&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/ChangeLog?rev=1.240&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/ChangeLog?r1=1.239&r2=1.240

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/gwenview/ChangeLog,v
retrieving revision 1.239
retrieving revision 1.240
diff -u -r1.239 -r1.240
--- ChangeLog	19 Jun 2014 13:32:03 -0000	1.239
+++ ChangeLog	16 Jul 2014 17:40:28 -0000	1.240
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/gwenview
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/gwenview/ChangeLog,v 1.239 2014/06/19 13:32:03 creffett Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/gwenview/ChangeLog,v 1.240 2014/07/16 17:40:28 johu Exp $
+
+*gwenview-4.13.3 (16 Jul 2014)
+
+  16 Jul 2014; Johannes Huber <johu@gentoo.org> +gwenview-4.13.3.ebuild:
+  Version bump KDE SC 4.13.3
 
   19 Jun 2014; Chris Reffett <creffett@gentoo.org> -gwenview-4.13.1.ebuild:
   Remove KDE SC 4.13.1



1.1                  kde-base/gwenview/gwenview-4.13.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/gwenview-4.13.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/gwenview/gwenview-4.13.3.ebuild?rev=1.1&content-type=text/plain

Index: gwenview-4.13.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/gwenview/gwenview-4.13.3.ebuild,v 1.1 2014/07/16 17:40:28 johu Exp $

EAPI=5

KDE_HANDBOOK="optional"
OPENGL_REQUIRED="always"
inherit kde4-base

DESCRIPTION="KDE image viewer"
HOMEPAGE="
	http://www.kde.org/applications/graphics/gwenview/
	http://gwenview.sourceforge.net/
"
KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug kipi semantic-desktop"

# tests fail, last checked 4.11.0
RESTRICT="test"

DEPEND="
	$(add_kdebase_dep libkdcraw)
	$(add_kdebase_dep libkonq)
	$(add_kdebase_dep kactivities)
	media-gfx/exiv2:=
	media-libs/lcms:2
	media-libs/libpng:0=
	virtual/jpeg:0
	x11-libs/libX11
	kipi? ( $(add_kdebase_dep libkipi) )
	semantic-desktop? ( $(add_kdebase_dep baloo) )
"
RDEPEND="${DEPEND}"

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_with kipi)
	)
	# Workaround for bug #479510
	if [[ -e ${EPREFIX}/usr/include/${CHOST}/jconfig.h ]]; then
		mycmakeargs+=( -DJCONFIG_H="${EPREFIX}/usr/include/${CHOST}/jconfig.h" )
	fi

	if use semantic-desktop; then
		mycmakeargs+=(-DGWENVIEW_SEMANTICINFO_BACKEND=Baloo)
	else
		mycmakeargs+=(-DGWENVIEW_SEMANTICINFO_BACKEND=None)
	fi

	kde4-base_src_configure
}

pkg_postinst() {
	kde4-base_pkg_postinst

	if ! has_version kde-base/svgpart:${SLOT} ; then
		elog "For SVG support, install kde-base/svgpart:${SLOT}"
	fi

	if use kipi && ! has_version media-plugins/kipi-plugins ; then
		elog "The plugins for the KIPI inteface can be found in media-plugins/kipi-plugins"
	fi
}