[gentoo-commits] gentoo-x86 commit in kde-base/kdebase-startkde: kdebase-startkde-4.11.11.ebuild ChangeLog

["Johannes Huber (johu)" <johu@gentoo.org>]

johu        14/07/16 17:40:15

  Modified:             ChangeLog
  Added:                kdebase-startkde-4.11.11.ebuild
  Log:
  Version bump KDE SC 4.13.3
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xF3CFD2BD)

Revision  Changes    Path
1.374                kde-base/kdebase-startkde/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kdebase-startkde/ChangeLog?rev=1.374&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kdebase-startkde/ChangeLog?rev=1.374&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kdebase-startkde/ChangeLog?r1=1.373&r2=1.374

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kdebase-startkde/ChangeLog,v
retrieving revision 1.373
retrieving revision 1.374
diff -u -r1.373 -r1.374
--- ChangeLog	15 Jun 2014 17:50:53 -0000	1.373
+++ ChangeLog	16 Jul 2014 17:40:15 -0000	1.374
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/kdebase-startkde
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdebase-startkde/ChangeLog,v 1.373 2014/06/15 17:50:53 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdebase-startkde/ChangeLog,v 1.374 2014/07/16 17:40:15 johu Exp $
+
+*kdebase-startkde-4.11.11 (16 Jul 2014)
+
+  16 Jul 2014; Johannes Huber <johu@gentoo.org>
+  +kdebase-startkde-4.11.11.ebuild:
+  Version bump KDE Workspace 4.11.11
 
 *kdebase-startkde-4.11.10 (15 Jun 2014)
 



1.1                  kde-base/kdebase-startkde/kdebase-startkde-4.11.11.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kdebase-startkde/kdebase-startkde-4.11.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kdebase-startkde/kdebase-startkde-4.11.11.ebuild?rev=1.1&content-type=text/plain

Index: kdebase-startkde-4.11.11.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kdebase-startkde/kdebase-startkde-4.11.11.ebuild,v 1.1 2014/07/16 17:40:15 johu Exp $

EAPI=5

KMNAME="kde-workspace"
KMNOMODULE="true"
inherit kde4-meta prefix

DESCRIPTION="Startkde script, which starts a complete KDE session, and associated scripts"
KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="+wallpapers"

# The KDE apps called from the startkde script.
# These provide the most minimal KDE desktop.
RDEPEND="
	$(add_kdebase_dep kcminit)
	$(add_kdebase_dep kdebase-runtime-meta)
	wallpapers? ( $(add_kdebase_dep kde-wallpapers) )
	$(add_kdebase_dep kfmclient)
	$(add_kdebase_dep knotify)
	$(add_kdebase_dep kreadconfig)
	$(add_kdebase_dep krunner)
	$(add_kdebase_dep ksmserver)
	$(add_kdebase_dep ksplash)
	$(add_kdebase_dep kstartupconfig)
	$(add_kdebase_dep kwin)
	$(add_kdebase_dep phonon-kde)
	$(add_kdebase_dep plasma-apps)
	$(add_kdebase_dep plasma-workspace)
	$(add_kdebase_dep systemsettings)
	x11-apps/mkfontdir
	x11-apps/xmessage
	x11-apps/xprop
	x11-apps/xrandr
	x11-apps/xrdb
	x11-apps/xsetroot
	x11-apps/xset
"

KMEXTRACTONLY="
	ConfigureChecks.cmake
	kdm/
	startkde.cmake
"

PATCHES=("${FILESDIR}/gentoo-startkde4-4.patch")

src_prepare() {
	kde4-meta_src_prepare

	cp "${FILESDIR}/KDE-4" "${T}"

	# fix ${EPREFIX}
	eprefixify startkde.cmake "${T}/KDE-4"
}

src_install() {
	kde4-meta_src_install

	# startup and shutdown scripts
	insinto /etc/kde/startup
	doins "${FILESDIR}/agent-startup.sh"

	insinto /etc/kde/shutdown
	doins "${FILESDIR}/agent-shutdown.sh"

	# x11 session script
	exeinto /etc/X11/Sessions
	doexe "${T}/KDE-4"

	# freedesktop compliant session script
	sed -e "s:\${BIN_INSTALL_DIR}:${EPREFIX}/usr/bin:g" \
		"${S}/kdm/kfrontend/sessions/kde-plasma.desktop.cmake" > "${T}/KDE-4.desktop"
	insinto /usr/share/xsessions
	doins "${T}/KDE-4.desktop"
}

pkg_postinst () {
	kde4-meta_pkg_postinst

	echo
	elog "To enable gpg-agent and/or ssh-agent in KDE sessions,"
	elog "edit ${EPREFIX}/etc/kde/startup/agent-startup.sh and"
	elog "${EPREFIX}/etc/kde/shutdown/agent-shutdown.sh"
	echo
	elog "The name of the session script has changed."
	elog "If you currently have XSESSION=\"kde-$(get_kde_version)\" in your"
	elog "configuration files, you will need to change it to"
	elog "XSESSION=\"KDE-4\""
}