[gentoo-commits] gentoo-x86 commit in kde-base/kde-l10n: ChangeLog kde-l10n-4.13.3.ebuild

[gentoo-commits] gentoo-x86 commit in kde-base/kde-l10n: ChangeLog kde-l10n-4.13.3.ebuild

[Johannes Huber (johu)]

johu        14/07/16 17:40:02

  Modified:             ChangeLog
  Added:                kde-l10n-4.13.3.ebuild
  Log:
  Version bump KDE SC 4.13.3
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xF3CFD2BD)

Revision  Changes    Path
1.248                kde-base/kde-l10n/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kde-l10n/ChangeLog?rev=1.248&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kde-l10n/ChangeLog?rev=1.248&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kde-l10n/ChangeLog?r1=1.247&r2=1.248

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/ChangeLog,v
retrieving revision 1.247
retrieving revision 1.248
diff -u -r1.247 -r1.248
--- ChangeLog	19 Jun 2014 13:32:13 -0000	1.247
+++ ChangeLog	16 Jul 2014 17:40:01 -0000	1.248
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kde-l10n
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/ChangeLog,v 1.247 2014/06/19 13:32:13 creffett Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/ChangeLog,v 1.248 2014/07/16 17:40:01 johu Exp $
+
+*kde-l10n-4.13.3 (16 Jul 2014)
+
+  16 Jul 2014; Johannes Huber <johu@gentoo.org> +kde-l10n-4.13.3.ebuild:
+  Version bump KDE SC 4.13.3
 
   19 Jun 2014; Chris Reffett <creffett@gentoo.org> -kde-l10n-4.13.1.ebuild:
   Remove KDE SC 4.13.1



1.1                  kde-base/kde-l10n/kde-l10n-4.13.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kde-l10n/kde-l10n-4.13.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kde-l10n/kde-l10n-4.13.3.ebuild?rev=1.1&content-type=text/plain

Index: kde-l10n-4.13.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/kde-l10n-4.13.3.ebuild,v 1.1 2014/07/16 17:40:01 johu Exp $

EAPI=5

KDE_HANDBOOK="optional"
inherit kde4-base

DESCRIPTION="KDE internationalization package"
HOMEPAGE="http://l10n.kde.org"

DEPEND="
	sys-devel/gettext
"
RDEPEND="!<kde-base/konq-plugins-4.6"

KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
IUSE=""

# /usr/portage/distfiles $ ls -1 kde-l10n-*-${PV}.* |sed -e 's:-${PV}.tar.xz::' -e 's:kde-l10n-::' |tr '\n' ' '
MY_LANGS="ar bg bs ca ca@valencia cs da de el en_GB es et eu fi fr ga gl he hi
hr hu ia id is it ja kk km ko lt lv mr nb nds nl nn pa pl pt pt_BR ro ru sk sl
sr sv tr ug uk vi wa zh_CN zh_TW"

URI_BASE="${SRC_URI/-${PV}.tar.xz/}"
SRC_URI=""

for MY_LANG in ${MY_LANGS} ; do
	IUSE="${IUSE} linguas_${MY_LANG}"
	SRC_URI="${SRC_URI} linguas_${MY_LANG}? ( ${URI_BASE}/${PN}-${MY_LANG}-${PV}.tar.xz )"
done

S="${WORKDIR}"

src_unpack() {
	local LNG DIR
	if [[ -z ${A} ]]; then
		elog
		elog "You either have the LINGUAS variable unset, or it only"
		elog "contains languages not supported by ${P}."
		elog "You won't have any additional language support."
		elog
		elog "${P} supports these language codes:"
		elog "${MY_LANGS}"
		elog
	fi

	[[ -n ${A} ]] && unpack ${A}
	cd "${S}"

	# add all linguas to cmake
	if [[ -n ${A} ]]; then
		for LNG in ${LINGUAS}; do
			DIR="${PN}-${LNG}-${PV}"
			if [[ -d "${DIR}" ]] ; then
				echo "add_subdirectory( ${DIR} )" >> "${S}"/CMakeLists.txt
			fi
		done
	fi
}

src_prepare() {
	find "${S}" -name CMakeLists.txt -type f \
		-exec sed -i -e 's:^ *add_subdirectory( *kdepim-runtime *):# no kdepim-runtime:g' {} +
	find "${S}" -name CMakeLists.txt -type f \
		-exec sed -i -e 's:^ *add_subdirectory( *kdepim *):# no kdepim:g' {} +

	# quick workaround for bug 493278
	find "${S}" -name "akonadi_knut_resource*" -delete

	kde4-base_src_prepare
}

src_configure() {
	mycmakeargs=(
		$(cmake-utils_use_build handbook docs)
	)
	[[ -n ${A} ]] && kde4-base_src_configure
}

src_compile() {
	[[ -n ${A} ]] && kde4-base_src_compile
}

src_test() {
	[[ -n ${A} ]] && kde4-base_src_test
}

src_install() {
	[[ -n ${A} ]] && kde4-base_src_install
}