[gentoo-commits] gentoo-x86 commit in net-wireless/broadcom-sta: broadcom-sta-6.30.223.248.ebuild ChangeLog

["Manuel Rueger (mrueg)" <mrueg@gentoo.org>]

mrueg       14/07/15 23:59:48

  Modified:             ChangeLog
  Added:                broadcom-sta-6.30.223.248.ebuild
  Log:
  Version bump. Proxy commit for tomboy64@sina.cn. Fixes bug #517036
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key )

Revision  Changes    Path
1.60                 net-wireless/broadcom-sta/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/broadcom-sta/ChangeLog?rev=1.60&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/broadcom-sta/ChangeLog?rev=1.60&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/broadcom-sta/ChangeLog?r1=1.59&r2=1.60

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/broadcom-sta/ChangeLog,v
retrieving revision 1.59
retrieving revision 1.60
diff -u -r1.59 -r1.60
--- ChangeLog	23 Jun 2014 17:49:08 -0000	1.59
+++ ChangeLog	15 Jul 2014 23:59:47 -0000	1.60
@@ -1,6 +1,12 @@
 # ChangeLog for net-wireless/broadcom-sta
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/broadcom-sta/ChangeLog,v 1.59 2014/06/23 17:49:08 swift Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/broadcom-sta/ChangeLog,v 1.60 2014/07/15 23:59:47 mrueg Exp $
+
+*broadcom-sta-6.30.223.248 (15 Jul 2014)
+
+  15 Jul 2014; Manuel Rüger <mrueg@gentoo.org>
+  +broadcom-sta-6.30.223.248.ebuild:
+  Version bump. Proxy commit for tomboy64@sina.cn. Fixes bug #517036
 
 *broadcom-sta-6.30.223.141-r2 (23 Jun 2014)
 



1.1                  net-wireless/broadcom-sta/broadcom-sta-6.30.223.248.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/broadcom-sta/broadcom-sta-6.30.223.248.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/broadcom-sta/broadcom-sta-6.30.223.248.ebuild?rev=1.1&content-type=text/plain

Index: broadcom-sta-6.30.223.248.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/broadcom-sta/broadcom-sta-6.30.223.248.ebuild,v 1.1 2014/07/15 23:59:47 mrueg Exp $

EAPI=5
inherit eutils linux-info linux-mod

DESCRIPTION="Broadcom's IEEE 802.11a/b/g/n hybrid Linux device driver"
HOMEPAGE="http://www.broadcom.com/support/802.11/linux_sta.php"
SRC_BASE="http://www.broadcom.com/docs/linux_sta/hybrid-v35"
SRC_URI="x86? ( ${SRC_BASE}-nodebug-pcoem-${PV//\./_}.tar.gz )
	amd64? ( ${SRC_BASE}_64-nodebug-pcoem-${PV//\./_}.tar.gz )"

LICENSE="Broadcom"
KEYWORDS="-* ~amd64 ~x86"

RESTRICT="mirror"

DEPEND="virtual/linux-sources"
RDEPEND=""

S="${WORKDIR}"

MODULE_NAMES="wl(net/wireless)"
MODULESD_WL_ALIASES=("wlan0 wl")

pkg_setup() {
	# bug #300570
	# NOTE<lxnay>: module builds correctly anyway with b43 and SSB enabled
	# make checks non-fatal. The correct fix is blackisting ssb and, perhaps
	# b43 via udev rules. Moreover, previous fix broke binpkgs support.
	CONFIG_CHECK="~!B43 ~!SSB"
	CONFIG_CHECK2="LIB80211 ~!MAC80211 ~LIB80211_CRYPT_TKIP"
	ERROR_B43="B43: If you insist on building this, you must blacklist it!"
	ERROR_SSB="SSB: If you insist on building this, you must blacklist it!"
	ERROR_LIB80211="LIB80211: Please enable it. If you can't find it: enabling the driver for \"Intel PRO/Wireless 2100\" or \"Intel PRO/Wireless 2200BG\" (IPW2100 or IPW2200) should suffice."
	ERROR_MAC80211="MAC80211: If you insist on building this, you must blacklist it!"
	ERROR_PREEMPT_RCU="PREEMPT_RCU: Please do not set the Preemption Model to \"Preemptible Kernel\"; choose something else."
	ERROR_LIB80211_CRYPT_TKIP="LIB80211_CRYPT_TKIP: You will need this for WPA."
	if kernel_is ge 3 8 8; then
		CONFIG_CHECK="${CONFIG_CHECK} ${CONFIG_CHECK2} CFG80211 ~!PREEMPT_RCU ~!PREEMPT"
	elif kernel_is ge 2 6 32; then
		CONFIG_CHECK="${CONFIG_CHECK} ${CONFIG_CHECK2} CFG80211"
	elif kernel_is ge 2 6 31; then
		CONFIG_CHECK="${CONFIG_CHECK} ${CONFIG_CHECK2} WIRELESS_EXT ~!MAC80211"
	elif kernel_is ge 2 6 29; then
		CONFIG_CHECK="${CONFIG_CHECK} ${CONFIG_CHECK2} WIRELESS_EXT COMPAT_NET_DEV_OPS"
	else
		CONFIG_CHECK="${CONFIG_CHECK} IEEE80211 IEEE80211_CRYPT_TKIP"
	fi

	linux-mod_pkg_setup

	BUILD_PARAMS="-C ${KV_DIR} M=${S}"
	BUILD_TARGETS="wl.ko"
}

src_prepare() {
	epatch \
		"${FILESDIR}/${PN}-6.30.223.141-license.patch" \
		"${FILESDIR}/${PN}-6.30.223.141-makefile.patch" \
		"${FILESDIR}/${PN}-6.30.223.141-eth-to-wlan.patch" \
		"${FILESDIR}/${PN}-6.30.223.141-gcc.patch" \
		"${FILESDIR}/${PN}-6.30.223.141-linux-3.15.patch"

	epatch_user
}